config/kernel-mkdir-umode-t.m4

   1 dnl #
   2 dnl # 3.3 API change
   3 dnl # The VFS .create, .mkdir and .mknod callbacks were updated to take a
   4 dnl # umode_t type rather than an int.  The expectation is that any backport
   5 dnl # would also change all three prototypes.  However, if it turns out that
   6 dnl # some distribution doesn't backport the whole thing this could be
   7 dnl # broken apart in to three seperate checks.
   8 dnl #
   9 AC_DEFUN([ZFS_AC_KERNEL_MKDIR_UMODE_T], [
  10         AC_MSG_CHECKING([whether iops->create()/mkdir()/mknod() take umode_t])
  11         ZFS_LINUX_TRY_COMPILE([
  12                 #include <linux/fs.h>
  13         ],[
  14                 int (*mkdir) (struct inode *,struct dentry *,umode_t) = NULL;
  15                 struct inode_operations iops __attribute__ ((unused)) = {
  16                         .mkdir = mkdir,
  17                 };
  18         ],[
  19                 AC_MSG_RESULT(yes)
  20                 AC_DEFINE(HAVE_MKDIR_UMODE_T, 1,
  21                     [iops->create()/mkdir()/mknod() take umode_t])
  22         ],[
  23                 AC_MSG_RESULT(no)
  24         ])
  25 ])