config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  18         ZFS_AC_KERNEL_BIO_FAILFAST
  19         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  20         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  21         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  22         ZFS_AC_KERNEL_BIO_RW_SYNC
  23         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  24         ZFS_AC_KERNEL_REQ_SYNC
  25         ZFS_AC_KERNEL_BLK_END_REQUEST
  26         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  27         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  29         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  30         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  31         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  32         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  33         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  34         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  35         ZFS_AC_KERNEL_BLK_RQ_BYTES
  36         ZFS_AC_KERNEL_BLK_RQ_POS
  37         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_RQ_IS_SYNC
  41         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  42         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  43         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  44         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  46         ZFS_AC_KERNEL_SHOW_OPTIONS
  47         ZFS_AC_KERNEL_FSYNC
  48         ZFS_AC_KERNEL_EVICT_INODE
  49         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  50         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  51         ZFS_AC_KERNEL_FALLOCATE
  52         ZFS_AC_KERNEL_TRUNCATE_RANGE
  53         ZFS_AC_KERNEL_CREATE_UMODE_T
  54         ZFS_AC_KERNEL_AUTOMOUNT
  55         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  56         ZFS_AC_KERNEL_COMMIT_METADATA
  57         ZFS_AC_KERNEL_CLEAR_INODE
  58         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  59         ZFS_AC_KERNEL_D_MAKE_ROOT
  60         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  61         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  62         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  63         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  64         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  65         ZFS_AC_KERNEL_MOUNT_NODEV
  66         ZFS_AC_KERNEL_SHRINK
  67         ZFS_AC_KERNEL_BDI
  68         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  69         ZFS_AC_KERNEL_SET_NLINK
  70
  71         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  72                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  73         ])
  74         AC_SUBST(KERNELMAKE_PARAMS)
  75
  76
  77         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  78         dnl # compiler options are added by the kernel build system.
  79         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  80         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  81         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  82
  83         AC_SUBST(KERNELCPPFLAGS)
  84 ])
  85
  86 dnl #
  87 dnl # Detect name used for Module.symvers file in kernel
  88 dnl #
  89 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  90         modpost=$LINUX/scripts/Makefile.modpost
  91         AC_MSG_CHECKING([kernel file name for module symbols])
  92         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
  93                 AS_IF([grep -q Modules.symvers $modpost], [
  94                         LINUX_SYMBOLS=Modules.symvers
  95                 ], [
  96                         LINUX_SYMBOLS=Module.symvers
  97                 ])
  98
  99                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 100                         AC_MSG_ERROR([
 101         *** Please make sure the kernel devel package for your distribution
 102         *** is installed.  If your building with a custom kernel make sure the
 103         *** kernel is configured, built, and the '--with-linux=PATH' configure
 104         *** option refers to the location of the kernel source.])
 105                 ])
 106         ], [
 107                 LINUX_SYMBOLS=NONE
 108         ])
 109         AC_MSG_RESULT($LINUX_SYMBOLS)
 110         AC_SUBST(LINUX_SYMBOLS)
 111 ])
 112
 113 dnl #
 114 dnl # Detect the kernel to be built against
 115 dnl #
 116 AC_DEFUN([ZFS_AC_KERNEL], [
 117         AC_ARG_WITH([linux],
 118                 AS_HELP_STRING([--with-linux=PATH],
 119                 [Path to kernel source]),
 120                 [kernelsrc="$withval"])
 121
 122         AC_ARG_WITH(linux-obj,
 123                 AS_HELP_STRING([--with-linux-obj=PATH],
 124                 [Path to kernel build objects]),
 125                 [kernelbuild="$withval"])
 126
 127         AC_MSG_CHECKING([kernel source directory])
 128         AS_IF([test -z "$kernelsrc"], [
 129                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 130                         headersdir="/lib/modules/$(uname -r)/source"
 131                         sourcelink=$(readlink -f "$headersdir")
 132                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 133                         headersdir="/lib/modules/$(uname -r)/build"
 134                         sourcelink=$(readlink -f "$headersdir")
 135                 ], [
 136                         sourcelink=$(ls -1d /usr/src/kernels/* \
 137                                      /usr/src/linux-* \
 138                                      2>/dev/null | grep -v obj | tail -1)
 139                 ])
 140
 141                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 142                         kernelsrc=`readlink -f ${sourcelink}`
 143                 ], [
 144                         AC_MSG_RESULT([Not found])
 145                         AC_MSG_ERROR([
 146         *** Please make sure the kernel devel package for your distribution
 147         *** is installed then try again.  If that fails you can specify the
 148         *** location of the kernel source with the '--with-linux=PATH' option.])
 149                 ])
 150         ], [
 151                 AS_IF([test "$kernelsrc" = "NONE"], [
 152                         kernsrcver=NONE
 153                 ])
 154         ])
 155
 156         AC_MSG_RESULT([$kernelsrc])
 157         AC_MSG_CHECKING([kernel build directory])
 158         AS_IF([test -z "$kernelbuild"], [
 159                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 160                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 161                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 162                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 163                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 164                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 165                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 166                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 167                 ], [
 168                         kernelbuild=${kernelsrc}
 169                 ])
 170         ])
 171         AC_MSG_RESULT([$kernelbuild])
 172
 173         AC_MSG_CHECKING([kernel source version])
 174         utsrelease1=$kernelbuild/include/linux/version.h
 175         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 176         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 177         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 178                 utsrelease=linux/version.h
 179         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 180                 utsrelease=linux/utsrelease.h
 181         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 182                 utsrelease=generated/utsrelease.h
 183         ])
 184
 185         AS_IF([test "$utsrelease"], [
 186                 kernsrcver=`(echo "#include <$utsrelease>";
 187                              echo "kernsrcver=UTS_RELEASE") |
 188                              cpp -I $kernelbuild/include |
 189                              grep "^kernsrcver=" | cut -d \" -f 2`
 190
 191                 AS_IF([test -z "$kernsrcver"], [
 192                         AC_MSG_RESULT([Not found])
 193                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 194                 ])
 195         ], [
 196                 AC_MSG_RESULT([Not found])
 197                 if test "x$enable_linux_builtin" != xyes; then
 198                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 199                 else
 200                         AC_MSG_ERROR([
 201         *** Cannot find UTS_RELEASE definition.
 202         *** Please run 'make prepare' inside the kernel source tree.])
 203                 fi
 204         ])
 205
 206         AC_MSG_RESULT([$kernsrcver])
 207
 208         LINUX=${kernelsrc}
 209         LINUX_OBJ=${kernelbuild}
 210         LINUX_VERSION=${kernsrcver}
 211
 212         AC_SUBST(LINUX)
 213         AC_SUBST(LINUX_OBJ)
 214         AC_SUBST(LINUX_VERSION)
 215
 216         ZFS_AC_MODULE_SYMVERS
 217 ])
 218
 219 dnl #
 220 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 221 dnl # does not exist this is likely because the SPL has been configured
 222 dnl # but not built.  The '--with-spl-timeout' option can be passed
 223 dnl # to pause here, waiting for the file to appear from a concurrently
 224 dnl # building SPL package.  If the file does not appear in time, a good
 225 dnl # guess is made as to what this file will be named based on what it
 226 dnl # is named in the kernel build products.  This file will first be
 227 dnl # used at link time so if the guess is wrong the build will fail
 228 dnl # then.  This unfortunately means the ZFS package does not contain a
 229 dnl # reliable mechanism to detect symbols exported by the SPL at
 230 dnl # configure time.
 231 dnl #
 232 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 233         AC_ARG_WITH([spl-timeout],
 234                 AS_HELP_STRING([--with-spl-timeout=SECS],
 235                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 236                 [timeout="$withval"], [timeout=0])
 237
 238         AC_MSG_CHECKING([spl file name for module symbols])
 239         SPL_SYMBOLS=NONE
 240
 241         while true; do
 242                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 243                         SPL_SYMBOLS=Module.symvers
 244                 ], [test -r $SPL_OBJ/Modules.symvers], [
 245                         SPL_SYMBOLS=Modules.symvers
 246                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 247                         SPL_SYMBOLS=Module.symvers
 248                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 249                         SPL_SYMBOLS=Modules.symvers
 250                 ])
 251
 252                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 253                         break;
 254                 ], [
 255                         sleep 1
 256                         timeout=$((timeout-1))
 257                 ])
 258         done
 259
 260         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 261                 SPL_SYMBOLS=$LINUX_SYMBOLS
 262         ])
 263
 264         AC_MSG_RESULT([$SPL_SYMBOLS])
 265         AC_SUBST(SPL_SYMBOLS)
 266 ])
 267
 268 dnl #
 269 dnl # Detect the SPL module to be built against
 270 dnl #
 271 AC_DEFUN([ZFS_AC_SPL], [
 272         AC_ARG_WITH([spl],
 273                 AS_HELP_STRING([--with-spl=PATH],
 274                 [Path to spl source]),
 275                 [splsrc="$withval"])
 276
 277         AC_ARG_WITH([spl-obj],
 278                 AS_HELP_STRING([--with-spl-obj=PATH],
 279                 [Path to spl build objects]),
 280                 [splbuild="$withval"])
 281
 282
 283         AC_MSG_CHECKING([spl source directory])
 284         AS_IF([test -z "$splsrc"], [
 285                 dnl #
 286                 dnl # Look in the standard development package location
 287                 dnl #
 288                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 289                             2>/dev/null | tail -1`
 290
 291                 dnl #
 292                 dnl # Look in the DKMS source location
 293                 dnl #
 294                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 295                         sourcelink=`ls -1d /var/lib/dkms/spl/*/build \
 296                                     2>/dev/null | tail -1`
 297                 ])
 298
 299                 dnl #
 300                 dnl # Look in the parent directory
 301                 dnl #
 302                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 303                         sourcelink=../spl
 304                 ])
 305
 306                 dnl #
 307                 dnl # Look in the kernel directory
 308                 dnl #
 309                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 310                         sourcelink="$LINUX"
 311                 ])
 312
 313                 AS_IF([test -e $sourcelink/spl_config.h], [
 314                         splsrc=`readlink -f ${sourcelink}`
 315                 ], [
 316                         AC_MSG_RESULT([Not found])
 317                         AC_MSG_ERROR([
 318         *** Please make sure the spl devel package for your distribution
 319         *** is installed then try again.  If that fails you can specify the
 320         *** location of the spl source with the '--with-spl=PATH' option.])
 321                 ])
 322         ], [
 323                 AS_IF([test "$splsrc" = "NONE"], [
 324                         splbuild=NONE
 325                         splsrcver=NONE
 326                 ])
 327         ])
 328
 329         AC_MSG_RESULT([$splsrc])
 330         AC_MSG_CHECKING([spl build directory])
 331         AS_IF([test -z "$splbuild"], [
 332                 splbuild=${splsrc}
 333         ])
 334         AC_MSG_RESULT([$splbuild])
 335
 336         AC_MSG_CHECKING([spl source version])
 337         AS_IF([test -r $splbuild/spl_config.h &&
 338                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 339
 340                 splsrcver=`(echo "#include <spl_config.h>";
 341                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 342                             cpp -I $splbuild |
 343                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 344         ])
 345
 346         AS_IF([test -z "$splsrcver"], [
 347                 AC_MSG_RESULT([Not found])
 348                 AC_MSG_ERROR([
 349         *** Cannot determine the version of the spl source.
 350         *** Please prepare the spl source before running this script])
 351         ])
 352
 353         AC_MSG_RESULT([$splsrcver])
 354
 355         SPL=${splsrc}
 356         SPL_OBJ=${splbuild}
 357         SPL_VERSION=${splsrcver}
 358
 359         AC_SUBST(SPL)
 360         AC_SUBST(SPL_OBJ)
 361         AC_SUBST(SPL_VERSION)
 362
 363         ZFS_AC_SPL_MODULE_SYMVERS
 364 ])
 365
 366 dnl #
 367 dnl # Basic toolchain sanity check.
 368 dnl #
 369 AC_DEFUN([ZFS_AC_TEST_MODULE],
 370         [AC_MSG_CHECKING([whether modules can be built])
 371         ZFS_LINUX_TRY_COMPILE([],[],[
 372                 AC_MSG_RESULT([yes])
 373         ],[
 374                 AC_MSG_RESULT([no])
 375                 if test "x$enable_linux_builtin" != xyes; then
 376                         AC_MSG_ERROR([*** Unable to build an empty module.])
 377                 else
 378                         AC_MSG_ERROR([
 379         *** Unable to build an empty module.
 380         *** Please run 'make scripts' inside the kernel source tree.])
 381                 fi
 382         ])
 383 ])
 384
 385 dnl #
 386 dnl # Certain kernel build options are not supported.  These must be
 387 dnl # detected at configure time and cause a build failure.  Otherwise
 388 dnl # modules may be successfully built that behave incorrectly.
 389 dnl #
 390 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 391
 392         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 393                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 394                         [Define to 1 if licensed under the GPL])
 395         ])
 396
 397         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 398 ])
 399
 400 dnl #
 401 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 402 dnl #
 403 dnl # This is typically only set for debug kernels because it comes with
 404 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 405 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 406 dnl # This will cause a failure at link time which we'd rather know about
 407 dnl # at compile time.
 408 dnl #
 409 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 410 dnl # with the upstream community we add a check to detect this case.
 411 dnl #
 412 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 413
 414         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 415                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 416                 tmp_flags="$EXTRA_KCFLAGS"
 417                 ZFS_LINUX_TRY_COMPILE([
 418                         #include <linux/module.h>
 419                         #include <linux/mutex.h>
 420
 421                         MODULE_LICENSE("$ZFS_META_LICENSE");
 422                 ],[
 423                         struct mutex lock;
 424
 425                         mutex_init(&lock);
 426                         mutex_lock(&lock);
 427                         mutex_unlock(&lock);
 428                 ],[
 429                         AC_MSG_RESULT(no)
 430                 ],[
 431                         AC_MSG_RESULT(yes)
 432                         AC_MSG_ERROR([
 433         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 434         *** with the CDDL license and will prevent the module linking stage
 435         *** from succeeding.  You must rebuild your kernel without this
 436         *** option enabled.])
 437                 ])
 438                 EXTRA_KCFLAGS="$tmp_flags"
 439         ], [])
 440 ])
 441
 442 dnl #
 443 dnl # ZFS_LINUX_CONFTEST
 444 dnl #
 445 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 446 cat confdefs.h - <<_ACEOF >conftest.c
 447 $1
 448 _ACEOF
 449 ])
 450
 451 dnl #
 452 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 453 dnl #
 454 m4_define([ZFS_LANG_PROGRAM], [
 455 $1
 456 int
 457 main (void)
 458 {
 459 dnl Do *not* indent the following line: there may be CPP directives.
 460 dnl Don't move the `;' right after for the same reason.
 461 $2
 462   ;
 463   return 0;
 464 }
 465 ])
 466
 467 dnl #
 468 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 469 dnl #
 470 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 471         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 472         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 473         echo "obj-m := conftest.o" >build/Makefile
 474         modpost_flag=''
 475         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 476         AS_IF(
 477                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 478                 [$4],
 479                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 480         )
 481         rm -Rf build
 482 ])
 483
 484 dnl #
 485 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 486 dnl #
 487 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 488         [ZFS_LINUX_COMPILE_IFELSE(
 489         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 490         [modules],
 491         [test -s build/conftest.o],
 492         [$3], [$4])
 493 ])
 494
 495 dnl #
 496 dnl # ZFS_LINUX_CONFIG
 497 dnl #
 498 AC_DEFUN([ZFS_LINUX_CONFIG],
 499         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 500         ZFS_LINUX_TRY_COMPILE([
 501                 #include <linux/module.h>
 502         ],[
 503                 #ifndef CONFIG_$1
 504                 #error CONFIG_$1 not #defined
 505                 #endif
 506         ],[
 507                 AC_MSG_RESULT([yes])
 508                 $2
 509         ],[
 510                 AC_MSG_RESULT([no])
 511                 $3
 512         ])
 513 ])
 514
 515 dnl #
 516 dnl # ZFS_CHECK_SYMBOL_EXPORT
 517 dnl # check symbol exported or not
 518 dnl #
 519 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 520         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 521                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 522         rc=$?
 523         if test $rc -ne 0; then
 524                 export=0
 525                 for file in $2; do
 526                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 527                                 "$LINUX/$file" 2>/dev/null
 528                         rc=$?
 529                         if test $rc -eq 0; then
 530                                 export=1
 531                                 break;
 532                         fi
 533                 done
 534                 if test $export -eq 0; then :
 535                         $4
 536                 else :
 537                         $3
 538                 fi
 539         else :
 540                 $3
 541         fi
 542 ])
 543
 544 dnl #
 545 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 546 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 547 dnl # is called if not compiling for builtin
 548 dnl #
 549 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 550         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 551         if test $rc -ne 0; then :
 552                 $6
 553         else
 554                 if test "x$enable_linux_builtin" != xyes; then
 555                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 556                 fi
 557                 if test $rc -ne 0; then :
 558                         $6
 559                 else :
 560                         $5
 561                 fi
 562         fi
 563 ])