config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  18         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  19         ZFS_AC_KERNEL_BIO_FAILFAST
  20         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  21         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  22         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  23         ZFS_AC_KERNEL_BIO_RW_SYNC
  24         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  25         ZFS_AC_KERNEL_REQ_SYNC
  26         ZFS_AC_KERNEL_BLK_END_REQUEST
  27         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  30         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  31         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  32         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  33         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  34         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  35         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  36         ZFS_AC_KERNEL_BLK_RQ_BYTES
  37         ZFS_AC_KERNEL_BLK_RQ_POS
  38         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  39         ZFS_AC_KERNEL_GET_DISK_RO
  40         ZFS_AC_KERNEL_GET_GENDISK
  41         ZFS_AC_KERNEL_RQ_IS_SYNC
  42         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  43         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  44         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  45         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  46         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  47         ZFS_AC_KERNEL_SHOW_OPTIONS
  48         ZFS_AC_KERNEL_FSYNC
  49         ZFS_AC_KERNEL_EVICT_INODE
  50         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  51         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  52         ZFS_AC_KERNEL_FALLOCATE
  53         ZFS_AC_KERNEL_MKDIR_UMODE_T
  54         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  55         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  56         ZFS_AC_KERNEL_TRUNCATE_RANGE
  57         ZFS_AC_KERNEL_AUTOMOUNT
  58         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  59         ZFS_AC_KERNEL_COMMIT_METADATA
  60         ZFS_AC_KERNEL_CLEAR_INODE
  61         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  62         ZFS_AC_KERNEL_D_MAKE_ROOT
  63         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  64         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  65         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  66         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  67         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  68         ZFS_AC_KERNEL_MOUNT_NODEV
  69         ZFS_AC_KERNEL_SHRINK
  70         ZFS_AC_KERNEL_BDI
  71         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  72         ZFS_AC_KERNEL_SET_NLINK
  73         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  74         ZFS_AC_KERNEL_5ARG_SGET
  75
  76         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  77                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  78         ])
  79         AC_SUBST(KERNELMAKE_PARAMS)
  80
  81
  82         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  83         dnl # compiler options are added by the kernel build system.
  84         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  85         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  86         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  87
  88         AC_SUBST(KERNELCPPFLAGS)
  89 ])
  90
  91 dnl #
  92 dnl # Detect name used for Module.symvers file in kernel
  93 dnl #
  94 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  95         modpost=$LINUX/scripts/Makefile.modpost
  96         AC_MSG_CHECKING([kernel file name for module symbols])
  97         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
  98                 AS_IF([grep -q Modules.symvers $modpost], [
  99                         LINUX_SYMBOLS=Modules.symvers
 100                 ], [
 101                         LINUX_SYMBOLS=Module.symvers
 102                 ])
 103
 104                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 105                         AC_MSG_ERROR([
 106         *** Please make sure the kernel devel package for your distribution
 107         *** is installed.  If your building with a custom kernel make sure the
 108         *** kernel is configured, built, and the '--with-linux=PATH' configure
 109         *** option refers to the location of the kernel source.])
 110                 ])
 111         ], [
 112                 LINUX_SYMBOLS=NONE
 113         ])
 114         AC_MSG_RESULT($LINUX_SYMBOLS)
 115         AC_SUBST(LINUX_SYMBOLS)
 116 ])
 117
 118 dnl #
 119 dnl # Detect the kernel to be built against
 120 dnl #
 121 AC_DEFUN([ZFS_AC_KERNEL], [
 122         AC_ARG_WITH([linux],
 123                 AS_HELP_STRING([--with-linux=PATH],
 124                 [Path to kernel source]),
 125                 [kernelsrc="$withval"])
 126
 127         AC_ARG_WITH(linux-obj,
 128                 AS_HELP_STRING([--with-linux-obj=PATH],
 129                 [Path to kernel build objects]),
 130                 [kernelbuild="$withval"])
 131
 132         AC_MSG_CHECKING([kernel source directory])
 133         AS_IF([test -z "$kernelsrc"], [
 134                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 135                         headersdir="/lib/modules/$(uname -r)/source"
 136                         sourcelink=$(readlink -f "$headersdir")
 137                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 138                         headersdir="/lib/modules/$(uname -r)/build"
 139                         sourcelink=$(readlink -f "$headersdir")
 140                 ], [
 141                         sourcelink=$(ls -1d /usr/src/kernels/* \
 142                                      /usr/src/linux-* \
 143                                      2>/dev/null | grep -v obj | tail -1)
 144                 ])
 145
 146                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 147                         kernelsrc=`readlink -f ${sourcelink}`
 148                 ], [
 149                         AC_MSG_RESULT([Not found])
 150                         AC_MSG_ERROR([
 151         *** Please make sure the kernel devel package for your distribution
 152         *** is installed then try again.  If that fails you can specify the
 153         *** location of the kernel source with the '--with-linux=PATH' option.])
 154                 ])
 155         ], [
 156                 AS_IF([test "$kernelsrc" = "NONE"], [
 157                         kernsrcver=NONE
 158                 ])
 159         ])
 160
 161         AC_MSG_RESULT([$kernelsrc])
 162         AC_MSG_CHECKING([kernel build directory])
 163         AS_IF([test -z "$kernelbuild"], [
 164                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 165                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 166                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 167                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 168                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 169                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 170                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 171                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 172                 ], [
 173                         kernelbuild=${kernelsrc}
 174                 ])
 175         ])
 176         AC_MSG_RESULT([$kernelbuild])
 177
 178         AC_MSG_CHECKING([kernel source version])
 179         utsrelease1=$kernelbuild/include/linux/version.h
 180         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 181         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 182         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 183                 utsrelease=linux/version.h
 184         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 185                 utsrelease=linux/utsrelease.h
 186         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 187                 utsrelease=generated/utsrelease.h
 188         ])
 189
 190         AS_IF([test "$utsrelease"], [
 191                 kernsrcver=`(echo "#include <$utsrelease>";
 192                              echo "kernsrcver=UTS_RELEASE") |
 193                              cpp -I $kernelbuild/include |
 194                              grep "^kernsrcver=" | cut -d \" -f 2`
 195
 196                 AS_IF([test -z "$kernsrcver"], [
 197                         AC_MSG_RESULT([Not found])
 198                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 199                 ])
 200         ], [
 201                 AC_MSG_RESULT([Not found])
 202                 if test "x$enable_linux_builtin" != xyes; then
 203                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 204                 else
 205                         AC_MSG_ERROR([
 206         *** Cannot find UTS_RELEASE definition.
 207         *** Please run 'make prepare' inside the kernel source tree.])
 208                 fi
 209         ])
 210
 211         AC_MSG_RESULT([$kernsrcver])
 212
 213         LINUX=${kernelsrc}
 214         LINUX_OBJ=${kernelbuild}
 215         LINUX_VERSION=${kernsrcver}
 216
 217         AC_SUBST(LINUX)
 218         AC_SUBST(LINUX_OBJ)
 219         AC_SUBST(LINUX_VERSION)
 220
 221         ZFS_AC_MODULE_SYMVERS
 222 ])
 223
 224 dnl #
 225 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 226 dnl # does not exist this is likely because the SPL has been configured
 227 dnl # but not built.  The '--with-spl-timeout' option can be passed
 228 dnl # to pause here, waiting for the file to appear from a concurrently
 229 dnl # building SPL package.  If the file does not appear in time, a good
 230 dnl # guess is made as to what this file will be named based on what it
 231 dnl # is named in the kernel build products.  This file will first be
 232 dnl # used at link time so if the guess is wrong the build will fail
 233 dnl # then.  This unfortunately means the ZFS package does not contain a
 234 dnl # reliable mechanism to detect symbols exported by the SPL at
 235 dnl # configure time.
 236 dnl #
 237 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 238         AC_ARG_WITH([spl-timeout],
 239                 AS_HELP_STRING([--with-spl-timeout=SECS],
 240                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 241                 [timeout="$withval"], [timeout=0])
 242
 243         AC_MSG_CHECKING([spl file name for module symbols])
 244         SPL_SYMBOLS=NONE
 245
 246         while true; do
 247                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 248                         SPL_SYMBOLS=Module.symvers
 249                 ], [test -r $SPL_OBJ/Modules.symvers], [
 250                         SPL_SYMBOLS=Modules.symvers
 251                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 252                         SPL_SYMBOLS=Module.symvers
 253                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 254                         SPL_SYMBOLS=Modules.symvers
 255                 ])
 256
 257                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 258                         break;
 259                 ], [
 260                         sleep 1
 261                         timeout=$((timeout-1))
 262                 ])
 263         done
 264
 265         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 266                 SPL_SYMBOLS=$LINUX_SYMBOLS
 267         ])
 268
 269         AC_MSG_RESULT([$SPL_SYMBOLS])
 270         AC_SUBST(SPL_SYMBOLS)
 271 ])
 272
 273 dnl #
 274 dnl # Detect the SPL module to be built against
 275 dnl #
 276 AC_DEFUN([ZFS_AC_SPL], [
 277         AC_ARG_WITH([spl],
 278                 AS_HELP_STRING([--with-spl=PATH],
 279                 [Path to spl source]),
 280                 [splsrc="$withval"])
 281
 282         AC_ARG_WITH([spl-obj],
 283                 AS_HELP_STRING([--with-spl-obj=PATH],
 284                 [Path to spl build objects]),
 285                 [splbuild="$withval"])
 286
 287
 288         AC_MSG_CHECKING([spl source directory])
 289         AS_IF([test -z "$splsrc"], [
 290                 dnl #
 291                 dnl # Look in the standard development package location
 292                 dnl #
 293                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 294                             2>/dev/null | tail -1`
 295
 296                 dnl #
 297                 dnl # Look in the DKMS source location
 298                 dnl #
 299                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 300                         sourcelink=`ls -1d /var/lib/dkms/spl/*/build \
 301                                     2>/dev/null | tail -1`
 302                 ])
 303
 304                 dnl #
 305                 dnl # Look in the parent directory
 306                 dnl #
 307                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 308                         sourcelink=../spl
 309                 ])
 310
 311                 dnl #
 312                 dnl # Look in the kernel directory
 313                 dnl #
 314                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 315                         sourcelink="$LINUX"
 316                 ])
 317
 318                 AS_IF([test -e $sourcelink/spl_config.h], [
 319                         splsrc=`readlink -f ${sourcelink}`
 320                 ], [
 321                         AC_MSG_RESULT([Not found])
 322                         AC_MSG_ERROR([
 323         *** Please make sure the spl devel package for your distribution
 324         *** is installed then try again.  If that fails you can specify the
 325         *** location of the spl source with the '--with-spl=PATH' option.])
 326                 ])
 327         ], [
 328                 AS_IF([test "$splsrc" = "NONE"], [
 329                         splbuild=NONE
 330                         splsrcver=NONE
 331                 ])
 332         ])
 333
 334         AC_MSG_RESULT([$splsrc])
 335         AC_MSG_CHECKING([spl build directory])
 336         AS_IF([test -z "$splbuild"], [
 337                 splbuild=${splsrc}
 338         ])
 339         AC_MSG_RESULT([$splbuild])
 340
 341         AC_MSG_CHECKING([spl source version])
 342         AS_IF([test -r $splbuild/spl_config.h &&
 343                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 344
 345                 splsrcver=`(echo "#include <spl_config.h>";
 346                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 347                             cpp -I $splbuild |
 348                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 349         ])
 350
 351         AS_IF([test -z "$splsrcver"], [
 352                 AC_MSG_RESULT([Not found])
 353                 AC_MSG_ERROR([
 354         *** Cannot determine the version of the spl source.
 355         *** Please prepare the spl source before running this script])
 356         ])
 357
 358         AC_MSG_RESULT([$splsrcver])
 359
 360         SPL=${splsrc}
 361         SPL_OBJ=${splbuild}
 362         SPL_VERSION=${splsrcver}
 363
 364         AC_SUBST(SPL)
 365         AC_SUBST(SPL_OBJ)
 366         AC_SUBST(SPL_VERSION)
 367
 368         ZFS_AC_SPL_MODULE_SYMVERS
 369 ])
 370
 371 dnl #
 372 dnl # Basic toolchain sanity check.
 373 dnl #
 374 AC_DEFUN([ZFS_AC_TEST_MODULE],
 375         [AC_MSG_CHECKING([whether modules can be built])
 376         ZFS_LINUX_TRY_COMPILE([],[],[
 377                 AC_MSG_RESULT([yes])
 378         ],[
 379                 AC_MSG_RESULT([no])
 380                 if test "x$enable_linux_builtin" != xyes; then
 381                         AC_MSG_ERROR([*** Unable to build an empty module.])
 382                 else
 383                         AC_MSG_ERROR([
 384         *** Unable to build an empty module.
 385         *** Please run 'make scripts' inside the kernel source tree.])
 386                 fi
 387         ])
 388 ])
 389
 390 dnl #
 391 dnl # Certain kernel build options are not supported.  These must be
 392 dnl # detected at configure time and cause a build failure.  Otherwise
 393 dnl # modules may be successfully built that behave incorrectly.
 394 dnl #
 395 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 396
 397         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 398                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 399                         [Define to 1 if licensed under the GPL])
 400         ])
 401
 402         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 403 ])
 404
 405 dnl #
 406 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 407 dnl #
 408 dnl # This is typically only set for debug kernels because it comes with
 409 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 410 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 411 dnl # This will cause a failure at link time which we'd rather know about
 412 dnl # at compile time.
 413 dnl #
 414 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 415 dnl # with the upstream community we add a check to detect this case.
 416 dnl #
 417 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 418
 419         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 420                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 421                 tmp_flags="$EXTRA_KCFLAGS"
 422                 ZFS_LINUX_TRY_COMPILE([
 423                         #include <linux/module.h>
 424                         #include <linux/mutex.h>
 425
 426                         MODULE_LICENSE("$ZFS_META_LICENSE");
 427                 ],[
 428                         struct mutex lock;
 429
 430                         mutex_init(&lock);
 431                         mutex_lock(&lock);
 432                         mutex_unlock(&lock);
 433                 ],[
 434                         AC_MSG_RESULT(no)
 435                 ],[
 436                         AC_MSG_RESULT(yes)
 437                         AC_MSG_ERROR([
 438         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 439         *** with the CDDL license and will prevent the module linking stage
 440         *** from succeeding.  You must rebuild your kernel without this
 441         *** option enabled.])
 442                 ])
 443                 EXTRA_KCFLAGS="$tmp_flags"
 444         ], [])
 445 ])
 446
 447 dnl #
 448 dnl # ZFS_LINUX_CONFTEST
 449 dnl #
 450 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 451 cat confdefs.h - <<_ACEOF >conftest.c
 452 $1
 453 _ACEOF
 454 ])
 455
 456 dnl #
 457 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 458 dnl #
 459 m4_define([ZFS_LANG_PROGRAM], [
 460 $1
 461 int
 462 main (void)
 463 {
 464 dnl Do *not* indent the following line: there may be CPP directives.
 465 dnl Don't move the `;' right after for the same reason.
 466 $2
 467   ;
 468   return 0;
 469 }
 470 ])
 471
 472 dnl #
 473 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 474 dnl #
 475 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 476         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 477         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 478         echo "obj-m := conftest.o" >build/Makefile
 479         modpost_flag=''
 480         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 481         AS_IF(
 482                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 483                 [$4],
 484                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 485         )
 486         rm -Rf build
 487 ])
 488
 489 dnl #
 490 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 491 dnl #
 492 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 493         [ZFS_LINUX_COMPILE_IFELSE(
 494         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 495         [modules],
 496         [test -s build/conftest.o],
 497         [$3], [$4])
 498 ])
 499
 500 dnl #
 501 dnl # ZFS_LINUX_CONFIG
 502 dnl #
 503 AC_DEFUN([ZFS_LINUX_CONFIG],
 504         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 505         ZFS_LINUX_TRY_COMPILE([
 506                 #include <linux/module.h>
 507         ],[
 508                 #ifndef CONFIG_$1
 509                 #error CONFIG_$1 not #defined
 510                 #endif
 511         ],[
 512                 AC_MSG_RESULT([yes])
 513                 $2
 514         ],[
 515                 AC_MSG_RESULT([no])
 516                 $3
 517         ])
 518 ])
 519
 520 dnl #
 521 dnl # ZFS_CHECK_SYMBOL_EXPORT
 522 dnl # check symbol exported or not
 523 dnl #
 524 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 525         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 526                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 527         rc=$?
 528         if test $rc -ne 0; then
 529                 export=0
 530                 for file in $2; do
 531                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 532                                 "$LINUX/$file" 2>/dev/null
 533                         rc=$?
 534                         if test $rc -eq 0; then
 535                                 export=1
 536                                 break;
 537                         fi
 538                 done
 539                 if test $export -eq 0; then :
 540                         $4
 541                 else :
 542                         $3
 543                 fi
 544         else :
 545                 $3
 546         fi
 547 ])
 548
 549 dnl #
 550 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 551 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 552 dnl # is called if not compiling for builtin
 553 dnl #
 554 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 555         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 556         if test $rc -ne 0; then :
 557                 $6
 558         else
 559                 if test "x$enable_linux_builtin" != xyes; then
 560                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 561                 fi
 562                 if test $rc -ne 0; then :
 563                         $6
 564                 else :
 565                         $5
 566                 fi
 567         fi
 568 ])