config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  18         ZFS_AC_KERNEL_BIO_FAILFAST
  19         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  20         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  21         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  22         ZFS_AC_KERNEL_BIO_RW_SYNC
  23         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  24         ZFS_AC_KERNEL_REQ_SYNC
  25         ZFS_AC_KERNEL_BLK_END_REQUEST
  26         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  27         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  29         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  30         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  31         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  32         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  33         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  34         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  35         ZFS_AC_KERNEL_BLK_RQ_BYTES
  36         ZFS_AC_KERNEL_BLK_RQ_POS
  37         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_RQ_IS_SYNC
  41         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  42         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  43         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  44         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  46         ZFS_AC_KERNEL_SHOW_OPTIONS
  47         ZFS_AC_KERNEL_FSYNC
  48         ZFS_AC_KERNEL_EVICT_INODE
  49         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  50         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  51         ZFS_AC_KERNEL_FALLOCATE
  52         ZFS_AC_KERNEL_TRUNCATE_RANGE
  53         ZFS_AC_KERNEL_CREATE_UMODE_T
  54         ZFS_AC_KERNEL_AUTOMOUNT
  55         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  56         ZFS_AC_KERNEL_COMMIT_METADATA
  57         ZFS_AC_KERNEL_CLEAR_INODE
  58         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  59         ZFS_AC_KERNEL_D_MAKE_ROOT
  60         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  61         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  62         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  63         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  64         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  65         ZFS_AC_KERNEL_MOUNT_NODEV
  66         ZFS_AC_KERNEL_SHRINK
  67         ZFS_AC_KERNEL_BDI
  68         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  69         ZFS_AC_KERNEL_SET_NLINK
  70         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  71         ZFS_AC_KERNEL_5ARG_SGET
  72
  73         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  74                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  75         ])
  76         AC_SUBST(KERNELMAKE_PARAMS)
  77
  78
  79         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  80         dnl # compiler options are added by the kernel build system.
  81         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  82         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  83         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  84
  85         AC_SUBST(KERNELCPPFLAGS)
  86 ])
  87
  88 dnl #
  89 dnl # Detect name used for Module.symvers file in kernel
  90 dnl #
  91 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  92         modpost=$LINUX/scripts/Makefile.modpost
  93         AC_MSG_CHECKING([kernel file name for module symbols])
  94         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
  95                 AS_IF([grep -q Modules.symvers $modpost], [
  96                         LINUX_SYMBOLS=Modules.symvers
  97                 ], [
  98                         LINUX_SYMBOLS=Module.symvers
  99                 ])
 100
 101                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 102                         AC_MSG_ERROR([
 103         *** Please make sure the kernel devel package for your distribution
 104         *** is installed.  If your building with a custom kernel make sure the
 105         *** kernel is configured, built, and the '--with-linux=PATH' configure
 106         *** option refers to the location of the kernel source.])
 107                 ])
 108         ], [
 109                 LINUX_SYMBOLS=NONE
 110         ])
 111         AC_MSG_RESULT($LINUX_SYMBOLS)
 112         AC_SUBST(LINUX_SYMBOLS)
 113 ])
 114
 115 dnl #
 116 dnl # Detect the kernel to be built against
 117 dnl #
 118 AC_DEFUN([ZFS_AC_KERNEL], [
 119         AC_ARG_WITH([linux],
 120                 AS_HELP_STRING([--with-linux=PATH],
 121                 [Path to kernel source]),
 122                 [kernelsrc="$withval"])
 123
 124         AC_ARG_WITH(linux-obj,
 125                 AS_HELP_STRING([--with-linux-obj=PATH],
 126                 [Path to kernel build objects]),
 127                 [kernelbuild="$withval"])
 128
 129         AC_MSG_CHECKING([kernel source directory])
 130         AS_IF([test -z "$kernelsrc"], [
 131                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 132                         headersdir="/lib/modules/$(uname -r)/source"
 133                         sourcelink=$(readlink -f "$headersdir")
 134                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 135                         headersdir="/lib/modules/$(uname -r)/build"
 136                         sourcelink=$(readlink -f "$headersdir")
 137                 ], [
 138                         sourcelink=$(ls -1d /usr/src/kernels/* \
 139                                      /usr/src/linux-* \
 140                                      2>/dev/null | grep -v obj | tail -1)
 141                 ])
 142
 143                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 144                         kernelsrc=`readlink -f ${sourcelink}`
 145                 ], [
 146                         AC_MSG_RESULT([Not found])
 147                         AC_MSG_ERROR([
 148         *** Please make sure the kernel devel package for your distribution
 149         *** is installed then try again.  If that fails you can specify the
 150         *** location of the kernel source with the '--with-linux=PATH' option.])
 151                 ])
 152         ], [
 153                 AS_IF([test "$kernelsrc" = "NONE"], [
 154                         kernsrcver=NONE
 155                 ])
 156         ])
 157
 158         AC_MSG_RESULT([$kernelsrc])
 159         AC_MSG_CHECKING([kernel build directory])
 160         AS_IF([test -z "$kernelbuild"], [
 161                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 162                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 163                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 164                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 165                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 166                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 167                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 168                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 169                 ], [
 170                         kernelbuild=${kernelsrc}
 171                 ])
 172         ])
 173         AC_MSG_RESULT([$kernelbuild])
 174
 175         AC_MSG_CHECKING([kernel source version])
 176         utsrelease1=$kernelbuild/include/linux/version.h
 177         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 178         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 179         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 180                 utsrelease=linux/version.h
 181         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 182                 utsrelease=linux/utsrelease.h
 183         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 184                 utsrelease=generated/utsrelease.h
 185         ])
 186
 187         AS_IF([test "$utsrelease"], [
 188                 kernsrcver=`(echo "#include <$utsrelease>";
 189                              echo "kernsrcver=UTS_RELEASE") |
 190                              cpp -I $kernelbuild/include |
 191                              grep "^kernsrcver=" | cut -d \" -f 2`
 192
 193                 AS_IF([test -z "$kernsrcver"], [
 194                         AC_MSG_RESULT([Not found])
 195                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 196                 ])
 197         ], [
 198                 AC_MSG_RESULT([Not found])
 199                 if test "x$enable_linux_builtin" != xyes; then
 200                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 201                 else
 202                         AC_MSG_ERROR([
 203         *** Cannot find UTS_RELEASE definition.
 204         *** Please run 'make prepare' inside the kernel source tree.])
 205                 fi
 206         ])
 207
 208         AC_MSG_RESULT([$kernsrcver])
 209
 210         LINUX=${kernelsrc}
 211         LINUX_OBJ=${kernelbuild}
 212         LINUX_VERSION=${kernsrcver}
 213
 214         AC_SUBST(LINUX)
 215         AC_SUBST(LINUX_OBJ)
 216         AC_SUBST(LINUX_VERSION)
 217
 218         ZFS_AC_MODULE_SYMVERS
 219 ])
 220
 221 dnl #
 222 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 223 dnl # does not exist this is likely because the SPL has been configured
 224 dnl # but not built.  The '--with-spl-timeout' option can be passed
 225 dnl # to pause here, waiting for the file to appear from a concurrently
 226 dnl # building SPL package.  If the file does not appear in time, a good
 227 dnl # guess is made as to what this file will be named based on what it
 228 dnl # is named in the kernel build products.  This file will first be
 229 dnl # used at link time so if the guess is wrong the build will fail
 230 dnl # then.  This unfortunately means the ZFS package does not contain a
 231 dnl # reliable mechanism to detect symbols exported by the SPL at
 232 dnl # configure time.
 233 dnl #
 234 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 235         AC_ARG_WITH([spl-timeout],
 236                 AS_HELP_STRING([--with-spl-timeout=SECS],
 237                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 238                 [timeout="$withval"], [timeout=0])
 239
 240         AC_MSG_CHECKING([spl file name for module symbols])
 241         SPL_SYMBOLS=NONE
 242
 243         while true; do
 244                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 245                         SPL_SYMBOLS=Module.symvers
 246                 ], [test -r $SPL_OBJ/Modules.symvers], [
 247                         SPL_SYMBOLS=Modules.symvers
 248                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 249                         SPL_SYMBOLS=Module.symvers
 250                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 251                         SPL_SYMBOLS=Modules.symvers
 252                 ])
 253
 254                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 255                         break;
 256                 ], [
 257                         sleep 1
 258                         timeout=$((timeout-1))
 259                 ])
 260         done
 261
 262         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 263                 SPL_SYMBOLS=$LINUX_SYMBOLS
 264         ])
 265
 266         AC_MSG_RESULT([$SPL_SYMBOLS])
 267         AC_SUBST(SPL_SYMBOLS)
 268 ])
 269
 270 dnl #
 271 dnl # Detect the SPL module to be built against
 272 dnl #
 273 AC_DEFUN([ZFS_AC_SPL], [
 274         AC_ARG_WITH([spl],
 275                 AS_HELP_STRING([--with-spl=PATH],
 276                 [Path to spl source]),
 277                 [splsrc="$withval"])
 278
 279         AC_ARG_WITH([spl-obj],
 280                 AS_HELP_STRING([--with-spl-obj=PATH],
 281                 [Path to spl build objects]),
 282                 [splbuild="$withval"])
 283
 284
 285         AC_MSG_CHECKING([spl source directory])
 286         AS_IF([test -z "$splsrc"], [
 287                 dnl #
 288                 dnl # Look in the standard development package location
 289                 dnl #
 290                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 291                             2>/dev/null | tail -1`
 292
 293                 dnl #
 294                 dnl # Look in the DKMS source location
 295                 dnl #
 296                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 297                         sourcelink=`ls -1d /var/lib/dkms/spl/*/build \
 298                                     2>/dev/null | tail -1`
 299                 ])
 300
 301                 dnl #
 302                 dnl # Look in the parent directory
 303                 dnl #
 304                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 305                         sourcelink=../spl
 306                 ])
 307
 308                 dnl #
 309                 dnl # Look in the kernel directory
 310                 dnl #
 311                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 312                         sourcelink="$LINUX"
 313                 ])
 314
 315                 AS_IF([test -e $sourcelink/spl_config.h], [
 316                         splsrc=`readlink -f ${sourcelink}`
 317                 ], [
 318                         AC_MSG_RESULT([Not found])
 319                         AC_MSG_ERROR([
 320         *** Please make sure the spl devel package for your distribution
 321         *** is installed then try again.  If that fails you can specify the
 322         *** location of the spl source with the '--with-spl=PATH' option.])
 323                 ])
 324         ], [
 325                 AS_IF([test "$splsrc" = "NONE"], [
 326                         splbuild=NONE
 327                         splsrcver=NONE
 328                 ])
 329         ])
 330
 331         AC_MSG_RESULT([$splsrc])
 332         AC_MSG_CHECKING([spl build directory])
 333         AS_IF([test -z "$splbuild"], [
 334                 splbuild=${splsrc}
 335         ])
 336         AC_MSG_RESULT([$splbuild])
 337
 338         AC_MSG_CHECKING([spl source version])
 339         AS_IF([test -r $splbuild/spl_config.h &&
 340                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 341
 342                 splsrcver=`(echo "#include <spl_config.h>";
 343                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 344                             cpp -I $splbuild |
 345                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 346         ])
 347
 348         AS_IF([test -z "$splsrcver"], [
 349                 AC_MSG_RESULT([Not found])
 350                 AC_MSG_ERROR([
 351         *** Cannot determine the version of the spl source.
 352         *** Please prepare the spl source before running this script])
 353         ])
 354
 355         AC_MSG_RESULT([$splsrcver])
 356
 357         SPL=${splsrc}
 358         SPL_OBJ=${splbuild}
 359         SPL_VERSION=${splsrcver}
 360
 361         AC_SUBST(SPL)
 362         AC_SUBST(SPL_OBJ)
 363         AC_SUBST(SPL_VERSION)
 364
 365         ZFS_AC_SPL_MODULE_SYMVERS
 366 ])
 367
 368 dnl #
 369 dnl # Basic toolchain sanity check.
 370 dnl #
 371 AC_DEFUN([ZFS_AC_TEST_MODULE],
 372         [AC_MSG_CHECKING([whether modules can be built])
 373         ZFS_LINUX_TRY_COMPILE([],[],[
 374                 AC_MSG_RESULT([yes])
 375         ],[
 376                 AC_MSG_RESULT([no])
 377                 if test "x$enable_linux_builtin" != xyes; then
 378                         AC_MSG_ERROR([*** Unable to build an empty module.])
 379                 else
 380                         AC_MSG_ERROR([
 381         *** Unable to build an empty module.
 382         *** Please run 'make scripts' inside the kernel source tree.])
 383                 fi
 384         ])
 385 ])
 386
 387 dnl #
 388 dnl # Certain kernel build options are not supported.  These must be
 389 dnl # detected at configure time and cause a build failure.  Otherwise
 390 dnl # modules may be successfully built that behave incorrectly.
 391 dnl #
 392 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 393
 394         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 395                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 396                         [Define to 1 if licensed under the GPL])
 397         ])
 398
 399         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 400 ])
 401
 402 dnl #
 403 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 404 dnl #
 405 dnl # This is typically only set for debug kernels because it comes with
 406 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 407 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 408 dnl # This will cause a failure at link time which we'd rather know about
 409 dnl # at compile time.
 410 dnl #
 411 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 412 dnl # with the upstream community we add a check to detect this case.
 413 dnl #
 414 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 415
 416         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 417                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 418                 tmp_flags="$EXTRA_KCFLAGS"
 419                 ZFS_LINUX_TRY_COMPILE([
 420                         #include <linux/module.h>
 421                         #include <linux/mutex.h>
 422
 423                         MODULE_LICENSE("$ZFS_META_LICENSE");
 424                 ],[
 425                         struct mutex lock;
 426
 427                         mutex_init(&lock);
 428                         mutex_lock(&lock);
 429                         mutex_unlock(&lock);
 430                 ],[
 431                         AC_MSG_RESULT(no)
 432                 ],[
 433                         AC_MSG_RESULT(yes)
 434                         AC_MSG_ERROR([
 435         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 436         *** with the CDDL license and will prevent the module linking stage
 437         *** from succeeding.  You must rebuild your kernel without this
 438         *** option enabled.])
 439                 ])
 440                 EXTRA_KCFLAGS="$tmp_flags"
 441         ], [])
 442 ])
 443
 444 dnl #
 445 dnl # ZFS_LINUX_CONFTEST
 446 dnl #
 447 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 448 cat confdefs.h - <<_ACEOF >conftest.c
 449 $1
 450 _ACEOF
 451 ])
 452
 453 dnl #
 454 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 455 dnl #
 456 m4_define([ZFS_LANG_PROGRAM], [
 457 $1
 458 int
 459 main (void)
 460 {
 461 dnl Do *not* indent the following line: there may be CPP directives.
 462 dnl Don't move the `;' right after for the same reason.
 463 $2
 464   ;
 465   return 0;
 466 }
 467 ])
 468
 469 dnl #
 470 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 471 dnl #
 472 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 473         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 474         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 475         echo "obj-m := conftest.o" >build/Makefile
 476         modpost_flag=''
 477         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 478         AS_IF(
 479                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 480                 [$4],
 481                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 482         )
 483         rm -Rf build
 484 ])
 485
 486 dnl #
 487 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 488 dnl #
 489 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 490         [ZFS_LINUX_COMPILE_IFELSE(
 491         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 492         [modules],
 493         [test -s build/conftest.o],
 494         [$3], [$4])
 495 ])
 496
 497 dnl #
 498 dnl # ZFS_LINUX_CONFIG
 499 dnl #
 500 AC_DEFUN([ZFS_LINUX_CONFIG],
 501         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 502         ZFS_LINUX_TRY_COMPILE([
 503                 #include <linux/module.h>
 504         ],[
 505                 #ifndef CONFIG_$1
 506                 #error CONFIG_$1 not #defined
 507                 #endif
 508         ],[
 509                 AC_MSG_RESULT([yes])
 510                 $2
 511         ],[
 512                 AC_MSG_RESULT([no])
 513                 $3
 514         ])
 515 ])
 516
 517 dnl #
 518 dnl # ZFS_CHECK_SYMBOL_EXPORT
 519 dnl # check symbol exported or not
 520 dnl #
 521 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 522         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 523                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 524         rc=$?
 525         if test $rc -ne 0; then
 526                 export=0
 527                 for file in $2; do
 528                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 529                                 "$LINUX/$file" 2>/dev/null
 530                         rc=$?
 531                         if test $rc -eq 0; then
 532                                 export=1
 533                                 break;
 534                         fi
 535                 done
 536                 if test $export -eq 0; then :
 537                         $4
 538                 else :
 539                         $3
 540                 fi
 541         else :
 542                 $3
 543         fi
 544 ])
 545
 546 dnl #
 547 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 548 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 549 dnl # is called if not compiling for builtin
 550 dnl #
 551 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 552         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 553         if test $rc -ne 0; then :
 554                 $6
 555         else
 556                 if test "x$enable_linux_builtin" != xyes; then
 557                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 558                 fi
 559                 if test $rc -ne 0; then :
 560                         $6
 561                 else :
 562                         $5
 563                 fi
 564         fi
 565 ])