config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_LOOKUP_BDEV
  16         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  17         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  18         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  19         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  20         ZFS_AC_KERNEL_BIO_FAILFAST
  21         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  22         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  23         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  24         ZFS_AC_KERNEL_BIO_RW_SYNC
  25         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  26         ZFS_AC_KERNEL_REQ_SYNC
  27         ZFS_AC_KERNEL_BLK_END_REQUEST
  28         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  30         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  31         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  32         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  33         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  34         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  35         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  36         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  37         ZFS_AC_KERNEL_BLK_RQ_BYTES
  38         ZFS_AC_KERNEL_BLK_RQ_POS
  39         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  40         ZFS_AC_KERNEL_GET_DISK_RO
  41         ZFS_AC_KERNEL_GET_GENDISK
  42         ZFS_AC_KERNEL_RQ_IS_SYNC
  43         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  44         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  45         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  46         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  47         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  48         ZFS_AC_KERNEL_SHOW_OPTIONS
  49         ZFS_AC_KERNEL_FSYNC
  50         ZFS_AC_KERNEL_EVICT_INODE
  51         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  52         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  53         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  54         ZFS_AC_KERNEL_FALLOCATE
  55         ZFS_AC_KERNEL_MKDIR_UMODE_T
  56         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  57         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  58         ZFS_AC_KERNEL_TRUNCATE_RANGE
  59         ZFS_AC_KERNEL_AUTOMOUNT
  60         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  61         ZFS_AC_KERNEL_COMMIT_METADATA
  62         ZFS_AC_KERNEL_CLEAR_INODE
  63         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  64         ZFS_AC_KERNEL_D_MAKE_ROOT
  65         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  66         ZFS_AC_KERNEL_D_SET_D_OP
  67         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  68         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  69         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  70         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  71         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  72         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  73         ZFS_AC_KERNEL_MOUNT_NODEV
  74         ZFS_AC_KERNEL_SHRINK
  75         ZFS_AC_KERNEL_S_D_OP
  76         ZFS_AC_KERNEL_BDI
  77         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  78         ZFS_AC_KERNEL_SET_NLINK
  79         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  80         ZFS_AC_KERNEL_5ARG_SGET
  81
  82         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  83                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  84         ])
  85         AC_SUBST(KERNELMAKE_PARAMS)
  86
  87
  88         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  89         dnl # compiler options are added by the kernel build system.
  90         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  91         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  92         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  93
  94         AC_SUBST(KERNELCPPFLAGS)
  95 ])
  96
  97 dnl #
  98 dnl # Detect name used for Module.symvers file in kernel
  99 dnl #
 100 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 101         modpost=$LINUX/scripts/Makefile.modpost
 102         AC_MSG_CHECKING([kernel file name for module symbols])
 103         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 104                 AS_IF([grep -q Modules.symvers $modpost], [
 105                         LINUX_SYMBOLS=Modules.symvers
 106                 ], [
 107                         LINUX_SYMBOLS=Module.symvers
 108                 ])
 109
 110                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 111                         AC_MSG_ERROR([
 112         *** Please make sure the kernel devel package for your distribution
 113         *** is installed.  If your building with a custom kernel make sure the
 114         *** kernel is configured, built, and the '--with-linux=PATH' configure
 115         *** option refers to the location of the kernel source.])
 116                 ])
 117         ], [
 118                 LINUX_SYMBOLS=NONE
 119         ])
 120         AC_MSG_RESULT($LINUX_SYMBOLS)
 121         AC_SUBST(LINUX_SYMBOLS)
 122 ])
 123
 124 dnl #
 125 dnl # Detect the kernel to be built against
 126 dnl #
 127 AC_DEFUN([ZFS_AC_KERNEL], [
 128         AC_ARG_WITH([linux],
 129                 AS_HELP_STRING([--with-linux=PATH],
 130                 [Path to kernel source]),
 131                 [kernelsrc="$withval"])
 132
 133         AC_ARG_WITH(linux-obj,
 134                 AS_HELP_STRING([--with-linux-obj=PATH],
 135                 [Path to kernel build objects]),
 136                 [kernelbuild="$withval"])
 137
 138         AC_MSG_CHECKING([kernel source directory])
 139         AS_IF([test -z "$kernelsrc"], [
 140                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 141                         headersdir="/lib/modules/$(uname -r)/source"
 142                         sourcelink=$(readlink -f "$headersdir")
 143                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 144                         headersdir="/lib/modules/$(uname -r)/build"
 145                         sourcelink=$(readlink -f "$headersdir")
 146                 ], [
 147                         sourcelink=$(ls -1d /usr/src/kernels/* \
 148                                      /usr/src/linux-* \
 149                                      2>/dev/null | grep -v obj | tail -1)
 150                 ])
 151
 152                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 153                         kernelsrc=`readlink -f ${sourcelink}`
 154                 ], [
 155                         kernelsrc="[Not found]"
 156                 ])
 157         ], [
 158                 AS_IF([test "$kernelsrc" = "NONE"], [
 159                         kernsrcver=NONE
 160                 ])
 161         ])
 162
 163         AC_MSG_RESULT([$kernelsrc])
 164         AS_IF([test ! -d "$kernelsrc"], [
 165                 AC_MSG_ERROR([
 166         *** Please make sure the kernel devel package for your distribution
 167         *** is installed then try again.  If that fails you can specify the
 168         *** location of the kernel source with the '--with-linux=PATH' option.])
 169         ])
 170
 171         AC_MSG_CHECKING([kernel build directory])
 172         AS_IF([test -z "$kernelbuild"], [
 173                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 174                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 175                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 176                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 177                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 178                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 179                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 180                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 181                 ], [
 182                         kernelbuild=${kernelsrc}
 183                 ])
 184         ])
 185         AC_MSG_RESULT([$kernelbuild])
 186
 187         AC_MSG_CHECKING([kernel source version])
 188         utsrelease1=$kernelbuild/include/linux/version.h
 189         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 190         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 191         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 192                 utsrelease=linux/version.h
 193         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 194                 utsrelease=linux/utsrelease.h
 195         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 196                 utsrelease=generated/utsrelease.h
 197         ])
 198
 199         AS_IF([test "$utsrelease"], [
 200                 kernsrcver=`(echo "#include <$utsrelease>";
 201                              echo "kernsrcver=UTS_RELEASE") |
 202                              cpp -I $kernelbuild/include |
 203                              grep "^kernsrcver=" | cut -d \" -f 2`
 204
 205                 AS_IF([test -z "$kernsrcver"], [
 206                         AC_MSG_RESULT([Not found])
 207                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 208                 ])
 209         ], [
 210                 AC_MSG_RESULT([Not found])
 211                 if test "x$enable_linux_builtin" != xyes; then
 212                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 213                 else
 214                         AC_MSG_ERROR([
 215         *** Cannot find UTS_RELEASE definition.
 216         *** Please run 'make prepare' inside the kernel source tree.])
 217                 fi
 218         ])
 219
 220         AC_MSG_RESULT([$kernsrcver])
 221
 222         LINUX=${kernelsrc}
 223         LINUX_OBJ=${kernelbuild}
 224         LINUX_VERSION=${kernsrcver}
 225
 226         AC_SUBST(LINUX)
 227         AC_SUBST(LINUX_OBJ)
 228         AC_SUBST(LINUX_VERSION)
 229
 230         ZFS_AC_MODULE_SYMVERS
 231 ])
 232
 233 dnl #
 234 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 235 dnl # does not exist this is likely because the SPL has been configured
 236 dnl # but not built.  The '--with-spl-timeout' option can be passed
 237 dnl # to pause here, waiting for the file to appear from a concurrently
 238 dnl # building SPL package.  If the file does not appear in time, a good
 239 dnl # guess is made as to what this file will be named based on what it
 240 dnl # is named in the kernel build products.  This file will first be
 241 dnl # used at link time so if the guess is wrong the build will fail
 242 dnl # then.  This unfortunately means the ZFS package does not contain a
 243 dnl # reliable mechanism to detect symbols exported by the SPL at
 244 dnl # configure time.
 245 dnl #
 246 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 247         AC_ARG_WITH([spl-timeout],
 248                 AS_HELP_STRING([--with-spl-timeout=SECS],
 249                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 250                 [timeout="$withval"], [timeout=0])
 251
 252         AC_MSG_CHECKING([spl file name for module symbols])
 253         SPL_SYMBOLS=NONE
 254
 255         while true; do
 256                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 257                         SPL_SYMBOLS=Module.symvers
 258                 ], [test -r $SPL_OBJ/Modules.symvers], [
 259                         SPL_SYMBOLS=Modules.symvers
 260                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 261                         SPL_SYMBOLS=Module.symvers
 262                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 263                         SPL_SYMBOLS=Modules.symvers
 264                 ])
 265
 266                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 267                         break;
 268                 ], [
 269                         sleep 1
 270                         timeout=$((timeout-1))
 271                 ])
 272         done
 273
 274         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 275                 SPL_SYMBOLS=$LINUX_SYMBOLS
 276         ])
 277
 278         AC_MSG_RESULT([$SPL_SYMBOLS])
 279         AC_SUBST(SPL_SYMBOLS)
 280 ])
 281
 282 dnl #
 283 dnl # Detect the SPL module to be built against
 284 dnl #
 285 AC_DEFUN([ZFS_AC_SPL], [
 286         AC_ARG_WITH([spl],
 287                 AS_HELP_STRING([--with-spl=PATH],
 288                 [Path to spl source]),
 289                 [splsrc="$withval"])
 290
 291         AC_ARG_WITH([spl-obj],
 292                 AS_HELP_STRING([--with-spl-obj=PATH],
 293                 [Path to spl build objects]),
 294                 [splbuild="$withval"])
 295
 296
 297         AC_MSG_CHECKING([spl source directory])
 298         AS_IF([test -z "$splsrc"], [
 299                 dnl #
 300                 dnl # Look in the standard development package location
 301                 dnl #
 302                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 303                             2>/dev/null | tail -1`
 304
 305                 dnl #
 306                 dnl # Look in the DKMS source location
 307                 dnl #
 308                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 309                         sourcelink=`ls -1d /var/lib/dkms/spl/*/build \
 310                                     2>/dev/null | tail -1`
 311                 ])
 312
 313                 dnl #
 314                 dnl # Look in the parent directory
 315                 dnl #
 316                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 317                         sourcelink=../spl
 318                 ])
 319
 320                 dnl #
 321                 dnl # Look in the kernel directory
 322                 dnl #
 323                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 324                         sourcelink="$LINUX"
 325                 ])
 326
 327                 AS_IF([test -e $sourcelink/spl_config.h], [
 328                         splsrc=`readlink -f ${sourcelink}`
 329                 ], [
 330                         AC_MSG_RESULT([Not found])
 331                         AC_MSG_ERROR([
 332         *** Please make sure the spl devel package for your distribution
 333         *** is installed then try again.  If that fails you can specify the
 334         *** location of the spl source with the '--with-spl=PATH' option.])
 335                 ])
 336         ], [
 337                 AS_IF([test "$splsrc" = "NONE"], [
 338                         splbuild=NONE
 339                         splsrcver=NONE
 340                 ])
 341         ])
 342
 343         AC_MSG_RESULT([$splsrc])
 344         AC_MSG_CHECKING([spl build directory])
 345         AS_IF([test -z "$splbuild"], [
 346                 splbuild=${splsrc}
 347         ])
 348         AC_MSG_RESULT([$splbuild])
 349
 350         AC_MSG_CHECKING([spl source version])
 351         AS_IF([test -r $splbuild/spl_config.h &&
 352                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 353
 354                 splsrcver=`(echo "#include <spl_config.h>";
 355                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 356                             cpp -I $splbuild |
 357                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 358         ])
 359
 360         AS_IF([test -z "$splsrcver"], [
 361                 AC_MSG_RESULT([Not found])
 362                 AC_MSG_ERROR([
 363         *** Cannot determine the version of the spl source.
 364         *** Please prepare the spl source before running this script])
 365         ])
 366
 367         AC_MSG_RESULT([$splsrcver])
 368
 369         SPL=${splsrc}
 370         SPL_OBJ=${splbuild}
 371         SPL_VERSION=${splsrcver}
 372
 373         AC_SUBST(SPL)
 374         AC_SUBST(SPL_OBJ)
 375         AC_SUBST(SPL_VERSION)
 376
 377         ZFS_AC_SPL_MODULE_SYMVERS
 378 ])
 379
 380 dnl #
 381 dnl # Basic toolchain sanity check.
 382 dnl #
 383 AC_DEFUN([ZFS_AC_TEST_MODULE],
 384         [AC_MSG_CHECKING([whether modules can be built])
 385         ZFS_LINUX_TRY_COMPILE([],[],[
 386                 AC_MSG_RESULT([yes])
 387         ],[
 388                 AC_MSG_RESULT([no])
 389                 if test "x$enable_linux_builtin" != xyes; then
 390                         AC_MSG_ERROR([*** Unable to build an empty module.])
 391                 else
 392                         AC_MSG_ERROR([
 393         *** Unable to build an empty module.
 394         *** Please run 'make scripts' inside the kernel source tree.])
 395                 fi
 396         ])
 397 ])
 398
 399 dnl #
 400 dnl # Certain kernel build options are not supported.  These must be
 401 dnl # detected at configure time and cause a build failure.  Otherwise
 402 dnl # modules may be successfully built that behave incorrectly.
 403 dnl #
 404 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 405
 406         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 407                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 408                         [Define to 1 if licensed under the GPL])
 409         ])
 410
 411         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 412 ])
 413
 414 dnl #
 415 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 416 dnl #
 417 dnl # This is typically only set for debug kernels because it comes with
 418 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 419 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 420 dnl # This will cause a failure at link time which we'd rather know about
 421 dnl # at compile time.
 422 dnl #
 423 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 424 dnl # with the upstream community we add a check to detect this case.
 425 dnl #
 426 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 427
 428         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 429                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 430                 tmp_flags="$EXTRA_KCFLAGS"
 431                 ZFS_LINUX_TRY_COMPILE([
 432                         #include <linux/module.h>
 433                         #include <linux/mutex.h>
 434
 435                         MODULE_LICENSE("$ZFS_META_LICENSE");
 436                 ],[
 437                         struct mutex lock;
 438
 439                         mutex_init(&lock);
 440                         mutex_lock(&lock);
 441                         mutex_unlock(&lock);
 442                 ],[
 443                         AC_MSG_RESULT(no)
 444                 ],[
 445                         AC_MSG_RESULT(yes)
 446                         AC_MSG_ERROR([
 447         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 448         *** with the CDDL license and will prevent the module linking stage
 449         *** from succeeding.  You must rebuild your kernel without this
 450         *** option enabled.])
 451                 ])
 452                 EXTRA_KCFLAGS="$tmp_flags"
 453         ], [])
 454 ])
 455
 456 dnl #
 457 dnl # ZFS_LINUX_CONFTEST
 458 dnl #
 459 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 460 cat confdefs.h - <<_ACEOF >conftest.c
 461 $1
 462 _ACEOF
 463 ])
 464
 465 dnl #
 466 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 467 dnl #
 468 m4_define([ZFS_LANG_PROGRAM], [
 469 $1
 470 int
 471 main (void)
 472 {
 473 dnl Do *not* indent the following line: there may be CPP directives.
 474 dnl Don't move the `;' right after for the same reason.
 475 $2
 476   ;
 477   return 0;
 478 }
 479 ])
 480
 481 dnl #
 482 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 483 dnl #
 484 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 485         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 486         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 487         echo "obj-m := conftest.o" >build/Makefile
 488         modpost_flag=''
 489         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 490         AS_IF(
 491                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 492                 [$4],
 493                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 494         )
 495         rm -Rf build
 496 ])
 497
 498 dnl #
 499 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 500 dnl #
 501 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 502         [ZFS_LINUX_COMPILE_IFELSE(
 503         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 504         [modules],
 505         [test -s build/conftest.o],
 506         [$3], [$4])
 507 ])
 508
 509 dnl #
 510 dnl # ZFS_LINUX_CONFIG
 511 dnl #
 512 AC_DEFUN([ZFS_LINUX_CONFIG],
 513         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 514         ZFS_LINUX_TRY_COMPILE([
 515                 #include <linux/module.h>
 516         ],[
 517                 #ifndef CONFIG_$1
 518                 #error CONFIG_$1 not #defined
 519                 #endif
 520         ],[
 521                 AC_MSG_RESULT([yes])
 522                 $2
 523         ],[
 524                 AC_MSG_RESULT([no])
 525                 $3
 526         ])
 527 ])
 528
 529 dnl #
 530 dnl # ZFS_CHECK_SYMBOL_EXPORT
 531 dnl # check symbol exported or not
 532 dnl #
 533 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 534         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 535                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 536         rc=$?
 537         if test $rc -ne 0; then
 538                 export=0
 539                 for file in $2; do
 540                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 541                                 "$LINUX/$file" 2>/dev/null
 542                         rc=$?
 543                         if test $rc -eq 0; then
 544                                 export=1
 545                                 break;
 546                         fi
 547                 done
 548                 if test $export -eq 0; then :
 549                         $4
 550                 else :
 551                         $3
 552                 fi
 553         else :
 554                 $3
 555         fi
 556 ])
 557
 558 dnl #
 559 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 560 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 561 dnl # is called if not compiling for builtin
 562 dnl #
 563 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 564         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 565         if test $rc -ne 0; then :
 566                 $6
 567         else
 568                 if test "x$enable_linux_builtin" != xyes; then
 569                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 570                 fi
 571                 if test $rc -ne 0; then :
 572                         $6
 573                 else :
 574                         $5
 575                 fi
 576         fi
 577 ])