config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_KERNEL_CONFIG
   8         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
   9         ZFS_AC_KERNEL_TYPE_FMODE_T
  10         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  11         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  12         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  13         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  14         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  15         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  16         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  17         ZFS_AC_KERNEL_BIO_FAILFAST
  18         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  19         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  20         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  21         ZFS_AC_KERNEL_BIO_RW_SYNC
  22         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  23         ZFS_AC_KERNEL_REQ_SYNC
  24         ZFS_AC_KERNEL_BLK_END_REQUEST
  25         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  26         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  27         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  28         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  29         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  30         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  31         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  32         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  33         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  34         ZFS_AC_KERNEL_BLK_RQ_BYTES
  35         ZFS_AC_KERNEL_BLK_RQ_POS
  36         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  37         ZFS_AC_KERNEL_GET_DISK_RO
  38         ZFS_AC_KERNEL_GET_GENDISK
  39         ZFS_AC_KERNEL_RQ_IS_SYNC
  40         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  41         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  42         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  43         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  44         ZFS_AC_KERNEL_SHOW_OPTIONS
  45         ZFS_AC_KERNEL_FSYNC
  46         ZFS_AC_KERNEL_EVICT_INODE
  47         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  48         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  49         ZFS_AC_KERNEL_FALLOCATE
  50         ZFS_AC_KERNEL_CREATE_UMODE_T
  51         ZFS_AC_KERNEL_AUTOMOUNT
  52         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  53         ZFS_AC_KERNEL_D_MAKE_ROOT
  54         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  55         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  56         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  57         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  58         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  59         ZFS_AC_KERNEL_MOUNT_NODEV
  60         ZFS_AC_KERNEL_SHRINK
  61         ZFS_AC_KERNEL_BDI
  62         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  63         ZFS_AC_KERNEL_SET_NLINK
  64
  65         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  66                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  67         ])
  68         AC_SUBST(KERNELMAKE_PARAMS)
  69
  70
  71         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  72         dnl # compiler options are added by the kernel build system.
  73         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  74         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  75         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  76
  77         AC_SUBST(KERNELCPPFLAGS)
  78 ])
  79
  80 dnl #
  81 dnl # Detect name used for Module.symvers file in kernel
  82 dnl #
  83 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  84         modpost=$LINUX/scripts/Makefile.modpost
  85         AC_MSG_CHECKING([kernel file name for module symbols])
  86         AS_IF([test -f "$modpost"], [
  87                 AS_IF([grep -q Modules.symvers $modpost], [
  88                         LINUX_SYMBOLS=Modules.symvers
  89                 ], [
  90                         LINUX_SYMBOLS=Module.symvers
  91                 ])
  92
  93                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
  94                         AC_MSG_ERROR([
  95         *** Please make sure the kernel devel package for your distribution
  96         *** is installed.  If your building with a custom kernel make sure the
  97         *** kernel is configured, built, and the '--with-linux=PATH' configure
  98         *** option refers to the location of the kernel source.])
  99                 ])
 100         ], [
 101                 LINUX_SYMBOLS=NONE
 102         ])
 103         AC_MSG_RESULT($LINUX_SYMBOLS)
 104         AC_SUBST(LINUX_SYMBOLS)
 105 ])
 106
 107 dnl #
 108 dnl # Detect the kernel to be built against
 109 dnl #
 110 AC_DEFUN([ZFS_AC_KERNEL], [
 111         AC_ARG_WITH([linux],
 112                 AS_HELP_STRING([--with-linux=PATH],
 113                 [Path to kernel source]),
 114                 [kernelsrc="$withval"])
 115
 116         AC_ARG_WITH(linux-obj,
 117                 AS_HELP_STRING([--with-linux-obj=PATH],
 118                 [Path to kernel build objects]),
 119                 [kernelbuild="$withval"])
 120
 121         AC_MSG_CHECKING([kernel source directory])
 122         AS_IF([test -z "$kernelsrc"], [
 123                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 124                         headersdir="/lib/modules/$(uname -r)/source"
 125                         sourcelink=$(readlink -f "$headersdir")
 126                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 127                         headersdir="/lib/modules/$(uname -r)/build"
 128                         sourcelink=$(readlink -f "$headersdir")
 129                 ], [
 130                         sourcelink=$(ls -1d /usr/src/kernels/* \
 131                                      /usr/src/linux-* \
 132                                      2>/dev/null | grep -v obj | tail -1)
 133                 ])
 134
 135                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 136                         kernelsrc=`readlink -f ${sourcelink}`
 137                 ], [
 138                         AC_MSG_RESULT([Not found])
 139                         AC_MSG_ERROR([
 140         *** Please make sure the kernel devel package for your distribution
 141         *** is installed then try again.  If that fails you can specify the
 142         *** location of the kernel source with the '--with-linux=PATH' option.])
 143                 ])
 144         ], [
 145                 AS_IF([test "$kernelsrc" = "NONE"], [
 146                         kernsrcver=NONE
 147                 ])
 148         ])
 149
 150         AC_MSG_RESULT([$kernelsrc])
 151         AC_MSG_CHECKING([kernel build directory])
 152         AS_IF([test -z "$kernelbuild"], [
 153                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 154                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 155                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 156                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 157                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 158                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 159                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 160                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 161                 ], [
 162                         kernelbuild=${kernelsrc}
 163                 ])
 164         ])
 165         AC_MSG_RESULT([$kernelbuild])
 166
 167         AC_MSG_CHECKING([kernel source version])
 168         utsrelease1=$kernelbuild/include/linux/version.h
 169         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 170         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 171         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 172                 utsrelease=linux/version.h
 173         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 174                 utsrelease=linux/utsrelease.h
 175         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 176                 utsrelease=generated/utsrelease.h
 177         ])
 178
 179         AS_IF([test "$utsrelease"], [
 180                 kernsrcver=`(echo "#include <$utsrelease>";
 181                              echo "kernsrcver=UTS_RELEASE") |
 182                              cpp -I $kernelbuild/include |
 183                              grep "^kernsrcver=" | cut -d \" -f 2`
 184
 185                 AS_IF([test -z "$kernsrcver"], [
 186                         AC_MSG_RESULT([Not found])
 187                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 188                 ])
 189         ], [
 190                 AC_MSG_RESULT([Not found])
 191                 AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 192         ])
 193
 194         AC_MSG_RESULT([$kernsrcver])
 195
 196         LINUX=${kernelsrc}
 197         LINUX_OBJ=${kernelbuild}
 198         LINUX_VERSION=${kernsrcver}
 199
 200         AC_SUBST(LINUX)
 201         AC_SUBST(LINUX_OBJ)
 202         AC_SUBST(LINUX_VERSION)
 203
 204         ZFS_AC_MODULE_SYMVERS
 205 ])
 206
 207 dnl #
 208 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 209 dnl # does not exist this is likely because the SPL has been configured
 210 dnl # but not built.  To allow recursive builds a good guess is made as to
 211 dnl # what this file will be named based on what it is named in the kernel
 212 dnl # build products.  This file will first be used at link time so if
 213 dnl # the guess is wrong the build will fail then.  This unfortunately
 214 dnl # means the ZFS package does not contain a reliable mechanism to
 215 dnl # detect symbols exported by the SPL at configure time.
 216 dnl #
 217 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 218         AC_MSG_CHECKING([spl file name for module symbols])
 219         AS_IF([test -r $SPL_OBJ/Module.symvers], [
 220                 SPL_SYMBOLS=Module.symvers
 221         ], [test -r $SPL_OBJ/Modules.symvers], [
 222                 SPL_SYMBOLS=Modules.symvers
 223         ], [test -r $SPL_OBJ/module/Module.symvers], [
 224                 SPL_SYMBOLS=Module.symvers
 225         ], [test -r $SPL_OBJ/module/Modules.symvers], [
 226                 SPL_SYMBOLS=Modules.symvers
 227         ], [
 228                 SPL_SYMBOLS=$LINUX_SYMBOLS
 229         ])
 230
 231         AC_MSG_RESULT([$SPL_SYMBOLS])
 232         AC_SUBST(SPL_SYMBOLS)
 233 ])
 234
 235 dnl #
 236 dnl # Detect the SPL module to be built against
 237 dnl #
 238 AC_DEFUN([ZFS_AC_SPL], [
 239         AC_ARG_WITH([spl],
 240                 AS_HELP_STRING([--with-spl=PATH],
 241                 [Path to spl source]),
 242                 [splsrc="$withval"])
 243
 244         AC_ARG_WITH([spl-obj],
 245                 AS_HELP_STRING([--with-spl-obj=PATH],
 246                 [Path to spl build objects]),
 247                 [splbuild="$withval"])
 248
 249
 250         AC_MSG_CHECKING([spl source directory])
 251         AS_IF([test -z "$splsrc"], [
 252                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 253                             2>/dev/null | tail -1`
 254
 255                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink], [
 256                         sourcelink=../spl
 257                 ])
 258
 259                 AS_IF([test -e $sourcelink], [
 260                         splsrc=`readlink -f ${sourcelink}`
 261                 ], [
 262                         AC_MSG_RESULT([Not found])
 263                         AC_MSG_ERROR([
 264         *** Please make sure the spl devel package for your distribution
 265         *** is installed then try again.  If that fails you can specify the
 266         *** location of the spl source with the '--with-spl=PATH' option.])
 267                 ])
 268         ], [
 269                 AS_IF([test "$splsrc" = "NONE"], [
 270                         splbuild=NONE
 271                         splsrcver=NONE
 272                 ])
 273         ])
 274
 275         AC_MSG_RESULT([$splsrc])
 276         AC_MSG_CHECKING([spl build directory])
 277         AS_IF([test -z "$splbuild"], [
 278                 splbuild=${splsrc}
 279         ])
 280         AC_MSG_RESULT([$splbuild])
 281
 282         AC_MSG_CHECKING([spl source version])
 283         AS_IF([test -r $splbuild/spl_config.h &&
 284                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 285
 286                 splsrcver=`(echo "#include <spl_config.h>";
 287                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 288                             cpp -I $splbuild |
 289                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 290         ])
 291
 292         AS_IF([test -z "$splsrcver"], [
 293                 AC_MSG_RESULT([Not found])
 294                 AC_MSG_ERROR([
 295         *** Cannot determine the version of the spl source.
 296         *** Please prepare the spl source before running this script])
 297         ])
 298
 299         AC_MSG_RESULT([$splsrcver])
 300
 301         SPL=${splsrc}
 302         SPL_OBJ=${splbuild}
 303         SPL_VERSION=${splsrcver}
 304
 305         AC_SUBST(SPL)
 306         AC_SUBST(SPL_OBJ)
 307         AC_SUBST(SPL_VERSION)
 308
 309         ZFS_AC_SPL_MODULE_SYMVERS
 310 ])
 311
 312 dnl #
 313 dnl # Certain kernel build options are not supported.  These must be
 314 dnl # detected at configure time and cause a build failure.  Otherwise
 315 dnl # modules may be successfully built that behave incorrectly.
 316 dnl #
 317 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 318
 319         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 320                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 321                         [Define to 1 if licensed under the GPL])
 322         ])
 323
 324         ZFS_AC_KERNEL_CONFIG_PREEMPT
 325         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 326 ])
 327
 328 dnl #
 329 dnl # Check CONFIG_PREEMPT
 330 dnl #
 331 dnl # Premptible kernels will be supported in the future.  But at the
 332 dnl # moment there are a few places in the code which need to be updated
 333 dnl # to accomidate them.  Until that work occurs we should detect this
 334 dnl # at configure time and fail with a sensible message.  Otherwise,
 335 dnl # people will be able to build successfully, however they will have
 336 dnl # stability problems.  See https://github.com/zfsonlinux/zfs/issues/83
 337 dnl #
 338 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_PREEMPT], [
 339
 340         ZFS_LINUX_CONFIG([PREEMPT],
 341                 AC_MSG_ERROR([
 342         *** Kernel built with CONFIG_PREEMPT which is not supported.
 343         *** You must rebuild your kernel without this option.]), [])
 344 ])
 345
 346 dnl #
 347 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 348 dnl #
 349 dnl # This is typically only set for debug kernels because it comes with
 350 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 351 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 352 dnl # This will cause a failure at link time which we'd rather know about
 353 dnl # at compile time.
 354 dnl #
 355 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 356 dnl # with the upstream community we add a check to detect this case.
 357 dnl #
 358 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 359
 360         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 361                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 362                 tmp_flags="$EXTRA_KCFLAGS"
 363                 ZFS_LINUX_TRY_COMPILE([
 364                         #include <linux/module.h>
 365                         #include <linux/mutex.h>
 366
 367                         MODULE_LICENSE("$ZFS_META_LICENSE");
 368                 ],[
 369                         struct mutex lock;
 370
 371                         mutex_init(&lock);
 372                         mutex_lock(&lock);
 373                         mutex_unlock(&lock);
 374                 ],[
 375                         AC_MSG_RESULT(no)
 376                 ],[
 377                         AC_MSG_RESULT(yes)
 378                         AC_MSG_ERROR([
 379         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 380         *** with the CDDL license and will prevent the module linking stage
 381         *** from succeeding.  You must rebuild your kernel without this
 382         *** option enabled.])
 383                 ])
 384                 EXTRA_KCFLAGS="$tmp_flags"
 385         ], [])
 386 ])
 387
 388 dnl #
 389 dnl # ZFS_LINUX_CONFTEST
 390 dnl #
 391 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 392 cat confdefs.h - <<_ACEOF >conftest.c
 393 $1
 394 _ACEOF
 395 ])
 396
 397 dnl #
 398 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 399 dnl #
 400 m4_define([ZFS_LANG_PROGRAM], [
 401 $1
 402 int
 403 main (void)
 404 {
 405 dnl Do *not* indent the following line: there may be CPP directives.
 406 dnl Don't move the `;' right after for the same reason.
 407 $2
 408   ;
 409   return 0;
 410 }
 411 ])
 412
 413 dnl #
 414 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 415 dnl #
 416 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 417         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 418         rm -Rf build && mkdir -p build
 419         echo "obj-m := conftest.o" >build/Makefile
 420         AS_IF(
 421                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 422                 [$4],
 423                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 424         )
 425         rm -Rf build
 426 ])
 427
 428 dnl #
 429 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 430 dnl #
 431 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 432         [ZFS_LINUX_COMPILE_IFELSE(
 433         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 434         [modules],
 435         [test -s build/conftest.o],
 436         [$3], [$4])
 437 ])
 438
 439 dnl #
 440 dnl # ZFS_LINUX_CONFIG
 441 dnl #
 442 AC_DEFUN([ZFS_LINUX_CONFIG],
 443         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 444         ZFS_LINUX_TRY_COMPILE([
 445                 #include <linux/module.h>
 446         ],[
 447                 #ifndef CONFIG_$1
 448                 #error CONFIG_$1 not #defined
 449                 #endif
 450         ],[
 451                 AC_MSG_RESULT([yes])
 452                 $2
 453         ],[
 454                 AC_MSG_RESULT([no])
 455                 $3
 456         ])
 457 ])
 458
 459 dnl #
 460 dnl # ZFS_CHECK_SYMBOL_EXPORT
 461 dnl # check symbol exported or not
 462 dnl #
 463 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT],
 464         [AC_MSG_CHECKING([whether symbol $1 is exported])
 465         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 466                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 467         rc=$?
 468         AS_IF([test $rc -ne 0], [
 469                 export=0
 470                 for file in $2; do
 471                         grep -q -E "EXPORT_SYMBOL.*($1)" "$LINUX/$file" 2>/dev/null
 472                         rc=$?
 473                         AS_IF([test $rc -eq 0], [
 474                                 export=1
 475                                 break;
 476                         ])
 477                 done
 478                 AS_IF([test $export -eq 0], [
 479                         AC_MSG_RESULT([no])
 480                         $4
 481                 ], [
 482                         AC_MSG_RESULT([yes])
 483                         $3
 484                 ])
 485         ], [
 486                 AC_MSG_RESULT([yes])
 487                 $3
 488         ])
 489 ])