config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  18         ZFS_AC_KERNEL_BIO_FAILFAST
  19         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  20         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  21         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  22         ZFS_AC_KERNEL_BIO_RW_SYNC
  23         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  24         ZFS_AC_KERNEL_REQ_SYNC
  25         ZFS_AC_KERNEL_BLK_END_REQUEST
  26         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  27         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  29         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  30         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  31         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  32         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  33         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  34         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  35         ZFS_AC_KERNEL_BLK_RQ_BYTES
  36         ZFS_AC_KERNEL_BLK_RQ_POS
  37         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_RQ_IS_SYNC
  41         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  42         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  43         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  44         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  46         ZFS_AC_KERNEL_SHOW_OPTIONS
  47         ZFS_AC_KERNEL_FSYNC
  48         ZFS_AC_KERNEL_EVICT_INODE
  49         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  50         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  51         ZFS_AC_KERNEL_FALLOCATE
  52         ZFS_AC_KERNEL_TRUNCATE_RANGE
  53         ZFS_AC_KERNEL_CREATE_UMODE_T
  54         ZFS_AC_KERNEL_AUTOMOUNT
  55         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  56         ZFS_AC_KERNEL_CLEAR_INODE
  57         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  58         ZFS_AC_KERNEL_D_MAKE_ROOT
  59         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  60         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  61         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  62         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  63         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  64         ZFS_AC_KERNEL_MOUNT_NODEV
  65         ZFS_AC_KERNEL_SHRINK
  66         ZFS_AC_KERNEL_BDI
  67         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  68         ZFS_AC_KERNEL_SET_NLINK
  69
  70         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  71                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  72         ])
  73         AC_SUBST(KERNELMAKE_PARAMS)
  74
  75
  76         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  77         dnl # compiler options are added by the kernel build system.
  78         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  79         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  80         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  81
  82         AC_SUBST(KERNELCPPFLAGS)
  83 ])
  84
  85 dnl #
  86 dnl # Detect name used for Module.symvers file in kernel
  87 dnl #
  88 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  89         modpost=$LINUX/scripts/Makefile.modpost
  90         AC_MSG_CHECKING([kernel file name for module symbols])
  91         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
  92                 AS_IF([grep -q Modules.symvers $modpost], [
  93                         LINUX_SYMBOLS=Modules.symvers
  94                 ], [
  95                         LINUX_SYMBOLS=Module.symvers
  96                 ])
  97
  98                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
  99                         AC_MSG_ERROR([
 100         *** Please make sure the kernel devel package for your distribution
 101         *** is installed.  If your building with a custom kernel make sure the
 102         *** kernel is configured, built, and the '--with-linux=PATH' configure
 103         *** option refers to the location of the kernel source.])
 104                 ])
 105         ], [
 106                 LINUX_SYMBOLS=NONE
 107         ])
 108         AC_MSG_RESULT($LINUX_SYMBOLS)
 109         AC_SUBST(LINUX_SYMBOLS)
 110 ])
 111
 112 dnl #
 113 dnl # Detect the kernel to be built against
 114 dnl #
 115 AC_DEFUN([ZFS_AC_KERNEL], [
 116         AC_ARG_WITH([linux],
 117                 AS_HELP_STRING([--with-linux=PATH],
 118                 [Path to kernel source]),
 119                 [kernelsrc="$withval"])
 120
 121         AC_ARG_WITH(linux-obj,
 122                 AS_HELP_STRING([--with-linux-obj=PATH],
 123                 [Path to kernel build objects]),
 124                 [kernelbuild="$withval"])
 125
 126         AC_MSG_CHECKING([kernel source directory])
 127         AS_IF([test -z "$kernelsrc"], [
 128                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 129                         headersdir="/lib/modules/$(uname -r)/source"
 130                         sourcelink=$(readlink -f "$headersdir")
 131                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 132                         headersdir="/lib/modules/$(uname -r)/build"
 133                         sourcelink=$(readlink -f "$headersdir")
 134                 ], [
 135                         sourcelink=$(ls -1d /usr/src/kernels/* \
 136                                      /usr/src/linux-* \
 137                                      2>/dev/null | grep -v obj | tail -1)
 138                 ])
 139
 140                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 141                         kernelsrc=`readlink -f ${sourcelink}`
 142                 ], [
 143                         AC_MSG_RESULT([Not found])
 144                         AC_MSG_ERROR([
 145         *** Please make sure the kernel devel package for your distribution
 146         *** is installed then try again.  If that fails you can specify the
 147         *** location of the kernel source with the '--with-linux=PATH' option.])
 148                 ])
 149         ], [
 150                 AS_IF([test "$kernelsrc" = "NONE"], [
 151                         kernsrcver=NONE
 152                 ])
 153         ])
 154
 155         AC_MSG_RESULT([$kernelsrc])
 156         AC_MSG_CHECKING([kernel build directory])
 157         AS_IF([test -z "$kernelbuild"], [
 158                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 159                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 160                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 161                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 162                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 163                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 164                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 165                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 166                 ], [
 167                         kernelbuild=${kernelsrc}
 168                 ])
 169         ])
 170         AC_MSG_RESULT([$kernelbuild])
 171
 172         AC_MSG_CHECKING([kernel source version])
 173         utsrelease1=$kernelbuild/include/linux/version.h
 174         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 175         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 176         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 177                 utsrelease=linux/version.h
 178         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 179                 utsrelease=linux/utsrelease.h
 180         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 181                 utsrelease=generated/utsrelease.h
 182         ])
 183
 184         AS_IF([test "$utsrelease"], [
 185                 kernsrcver=`(echo "#include <$utsrelease>";
 186                              echo "kernsrcver=UTS_RELEASE") |
 187                              cpp -I $kernelbuild/include |
 188                              grep "^kernsrcver=" | cut -d \" -f 2`
 189
 190                 AS_IF([test -z "$kernsrcver"], [
 191                         AC_MSG_RESULT([Not found])
 192                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 193                 ])
 194         ], [
 195                 AC_MSG_RESULT([Not found])
 196                 if test "x$enable_linux_builtin" != xyes; then
 197                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 198                 else
 199                         AC_MSG_ERROR([
 200         *** Cannot find UTS_RELEASE definition.
 201         *** Please run 'make prepare' inside the kernel source tree.])
 202                 fi
 203         ])
 204
 205         AC_MSG_RESULT([$kernsrcver])
 206
 207         LINUX=${kernelsrc}
 208         LINUX_OBJ=${kernelbuild}
 209         LINUX_VERSION=${kernsrcver}
 210
 211         AC_SUBST(LINUX)
 212         AC_SUBST(LINUX_OBJ)
 213         AC_SUBST(LINUX_VERSION)
 214
 215         ZFS_AC_MODULE_SYMVERS
 216 ])
 217
 218 dnl #
 219 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 220 dnl # does not exist this is likely because the SPL has been configured
 221 dnl # but not built.  The '--with-spl-timeout' option can be passed
 222 dnl # to pause here, waiting for the file to appear from a concurrently
 223 dnl # building SPL package.  If the file does not appear in time, a good
 224 dnl # guess is made as to what this file will be named based on what it
 225 dnl # is named in the kernel build products.  This file will first be
 226 dnl # used at link time so if the guess is wrong the build will fail
 227 dnl # then.  This unfortunately means the ZFS package does not contain a
 228 dnl # reliable mechanism to detect symbols exported by the SPL at
 229 dnl # configure time.
 230 dnl #
 231 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 232         AC_ARG_WITH([spl-timeout],
 233                 AS_HELP_STRING([--with-spl-timeout=SECS],
 234                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 235                 [timeout="$withval"], [timeout=0])
 236
 237         AC_MSG_CHECKING([spl file name for module symbols])
 238         SPL_SYMBOLS=NONE
 239
 240         while true; do
 241                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 242                         SPL_SYMBOLS=Module.symvers
 243                 ], [test -r $SPL_OBJ/Modules.symvers], [
 244                         SPL_SYMBOLS=Modules.symvers
 245                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 246                         SPL_SYMBOLS=Module.symvers
 247                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 248                         SPL_SYMBOLS=Modules.symvers
 249                 ])
 250
 251                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 252                         break;
 253                 ], [
 254                         sleep 1
 255                         timeout=$((timeout-1))
 256                 ])
 257         done
 258
 259         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 260                 SPL_SYMBOLS=$LINUX_SYMBOLS
 261         ])
 262
 263         AC_MSG_RESULT([$SPL_SYMBOLS])
 264         AC_SUBST(SPL_SYMBOLS)
 265 ])
 266
 267 dnl #
 268 dnl # Detect the SPL module to be built against
 269 dnl #
 270 AC_DEFUN([ZFS_AC_SPL], [
 271         AC_ARG_WITH([spl],
 272                 AS_HELP_STRING([--with-spl=PATH],
 273                 [Path to spl source]),
 274                 [splsrc="$withval"])
 275
 276         AC_ARG_WITH([spl-obj],
 277                 AS_HELP_STRING([--with-spl-obj=PATH],
 278                 [Path to spl build objects]),
 279                 [splbuild="$withval"])
 280
 281
 282         AC_MSG_CHECKING([spl source directory])
 283         AS_IF([test -z "$splsrc"], [
 284                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 285                             2>/dev/null | tail -1`
 286
 287                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink], [
 288                         sourcelink=../spl
 289                 ])
 290
 291                 AS_IF([test -e $sourcelink], [
 292                         splsrc=`readlink -f ${sourcelink}`
 293                 ], [
 294                         AC_MSG_RESULT([Not found])
 295                         AC_MSG_ERROR([
 296         *** Please make sure the spl devel package for your distribution
 297         *** is installed then try again.  If that fails you can specify the
 298         *** location of the spl source with the '--with-spl=PATH' option.])
 299                 ])
 300         ], [
 301                 AS_IF([test "$splsrc" = "NONE"], [
 302                         splbuild=NONE
 303                         splsrcver=NONE
 304                 ])
 305         ])
 306
 307         AC_MSG_RESULT([$splsrc])
 308         AC_MSG_CHECKING([spl build directory])
 309         AS_IF([test -z "$splbuild"], [
 310                 splbuild=${splsrc}
 311         ])
 312         AC_MSG_RESULT([$splbuild])
 313
 314         AC_MSG_CHECKING([spl source version])
 315         AS_IF([test -r $splbuild/spl_config.h &&
 316                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 317
 318                 splsrcver=`(echo "#include <spl_config.h>";
 319                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 320                             cpp -I $splbuild |
 321                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 322         ])
 323
 324         AS_IF([test -z "$splsrcver"], [
 325                 AC_MSG_RESULT([Not found])
 326                 AC_MSG_ERROR([
 327         *** Cannot determine the version of the spl source.
 328         *** Please prepare the spl source before running this script])
 329         ])
 330
 331         AC_MSG_RESULT([$splsrcver])
 332
 333         SPL=${splsrc}
 334         SPL_OBJ=${splbuild}
 335         SPL_VERSION=${splsrcver}
 336
 337         AC_SUBST(SPL)
 338         AC_SUBST(SPL_OBJ)
 339         AC_SUBST(SPL_VERSION)
 340
 341         ZFS_AC_SPL_MODULE_SYMVERS
 342 ])
 343
 344 dnl #
 345 dnl # Basic toolchain sanity check.
 346 dnl #
 347 AC_DEFUN([ZFS_AC_TEST_MODULE],
 348         [AC_MSG_CHECKING([whether modules can be built])
 349         ZFS_LINUX_TRY_COMPILE([],[],[
 350                 AC_MSG_RESULT([yes])
 351         ],[
 352                 AC_MSG_RESULT([no])
 353                 if test "x$enable_linux_builtin" != xyes; then
 354                         AC_MSG_ERROR([*** Unable to build an empty module.])
 355                 else
 356                         AC_MSG_ERROR([
 357         *** Unable to build an empty module.
 358         *** Please run 'make scripts' inside the kernel source tree.])
 359                 fi
 360         ])
 361 ])
 362
 363 dnl #
 364 dnl # Certain kernel build options are not supported.  These must be
 365 dnl # detected at configure time and cause a build failure.  Otherwise
 366 dnl # modules may be successfully built that behave incorrectly.
 367 dnl #
 368 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 369
 370         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 371                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 372                         [Define to 1 if licensed under the GPL])
 373         ])
 374
 375         ZFS_AC_KERNEL_CONFIG_PREEMPT
 376         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 377 ])
 378
 379 dnl #
 380 dnl # Check CONFIG_PREEMPT
 381 dnl #
 382 dnl # Premptible kernels will be supported in the future.  But at the
 383 dnl # moment there are a few places in the code which need to be updated
 384 dnl # to accomidate them.  Until that work occurs we should detect this
 385 dnl # at configure time and fail with a sensible message.  Otherwise,
 386 dnl # people will be able to build successfully, however they will have
 387 dnl # stability problems.  See https://github.com/zfsonlinux/zfs/issues/83
 388 dnl #
 389 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_PREEMPT], [
 390
 391         ZFS_LINUX_CONFIG([PREEMPT],
 392                 AC_MSG_ERROR([
 393         *** Kernel built with CONFIG_PREEMPT which is not supported.
 394         *** You must rebuild your kernel without this option.]), [])
 395 ])
 396
 397 dnl #
 398 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 399 dnl #
 400 dnl # This is typically only set for debug kernels because it comes with
 401 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 402 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 403 dnl # This will cause a failure at link time which we'd rather know about
 404 dnl # at compile time.
 405 dnl #
 406 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 407 dnl # with the upstream community we add a check to detect this case.
 408 dnl #
 409 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 410
 411         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 412                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 413                 tmp_flags="$EXTRA_KCFLAGS"
 414                 ZFS_LINUX_TRY_COMPILE([
 415                         #include <linux/module.h>
 416                         #include <linux/mutex.h>
 417
 418                         MODULE_LICENSE("$ZFS_META_LICENSE");
 419                 ],[
 420                         struct mutex lock;
 421
 422                         mutex_init(&lock);
 423                         mutex_lock(&lock);
 424                         mutex_unlock(&lock);
 425                 ],[
 426                         AC_MSG_RESULT(no)
 427                 ],[
 428                         AC_MSG_RESULT(yes)
 429                         AC_MSG_ERROR([
 430         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 431         *** with the CDDL license and will prevent the module linking stage
 432         *** from succeeding.  You must rebuild your kernel without this
 433         *** option enabled.])
 434                 ])
 435                 EXTRA_KCFLAGS="$tmp_flags"
 436         ], [])
 437 ])
 438
 439 dnl #
 440 dnl # ZFS_LINUX_CONFTEST
 441 dnl #
 442 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 443 cat confdefs.h - <<_ACEOF >conftest.c
 444 $1
 445 _ACEOF
 446 ])
 447
 448 dnl #
 449 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 450 dnl #
 451 m4_define([ZFS_LANG_PROGRAM], [
 452 $1
 453 int
 454 main (void)
 455 {
 456 dnl Do *not* indent the following line: there may be CPP directives.
 457 dnl Don't move the `;' right after for the same reason.
 458 $2
 459   ;
 460   return 0;
 461 }
 462 ])
 463
 464 dnl #
 465 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 466 dnl #
 467 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 468         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 469         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 470         echo "obj-m := conftest.o" >build/Makefile
 471         modpost_flag=''
 472         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 473         AS_IF(
 474                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 475                 [$4],
 476                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 477         )
 478         rm -Rf build
 479 ])
 480
 481 dnl #
 482 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 483 dnl #
 484 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 485         [ZFS_LINUX_COMPILE_IFELSE(
 486         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 487         [modules],
 488         [test -s build/conftest.o],
 489         [$3], [$4])
 490 ])
 491
 492 dnl #
 493 dnl # ZFS_LINUX_CONFIG
 494 dnl #
 495 AC_DEFUN([ZFS_LINUX_CONFIG],
 496         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 497         ZFS_LINUX_TRY_COMPILE([
 498                 #include <linux/module.h>
 499         ],[
 500                 #ifndef CONFIG_$1
 501                 #error CONFIG_$1 not #defined
 502                 #endif
 503         ],[
 504                 AC_MSG_RESULT([yes])
 505                 $2
 506         ],[
 507                 AC_MSG_RESULT([no])
 508                 $3
 509         ])
 510 ])
 511
 512 dnl #
 513 dnl # ZFS_CHECK_SYMBOL_EXPORT
 514 dnl # check symbol exported or not
 515 dnl #
 516 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 517         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 518                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 519         rc=$?
 520         if test $rc -ne 0; then
 521                 export=0
 522                 for file in $2; do
 523                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 524                                 "$LINUX/$file" 2>/dev/null
 525                         rc=$?
 526                         if test $rc -eq 0; then
 527                                 export=1
 528                                 break;
 529                         fi
 530                 done
 531                 if test $export -eq 0; then :
 532                         $4
 533                 else :
 534                         $3
 535                 fi
 536         else :
 537                 $3
 538         fi
 539 ])
 540
 541 dnl #
 542 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 543 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 544 dnl # is called if not compiling for builtin
 545 dnl #
 546 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 547         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 548         if test $rc -ne 0; then :
 549                 $6
 550         else
 551                 if test "x$enable_linux_builtin" != xyes; then
 552                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 553                 fi
 554                 if test $rc -ne 0; then :
 555                         $6
 556                 else :
 557                         $5
 558                 fi
 559         fi
 560 ])