config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_LOOKUP_BDEV
  16         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  17         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  18         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  19         ZFS_AC_KERNEL_BIO_FAILFAST
  20         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  21         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  22         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  23         ZFS_AC_KERNEL_BIO_RW_SYNC
  24         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  25         ZFS_AC_KERNEL_REQ_SYNC
  26         ZFS_AC_KERNEL_BLK_END_REQUEST
  27         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  30         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  31         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  32         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  33         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  34         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  35         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  36         ZFS_AC_KERNEL_BLK_RQ_BYTES
  37         ZFS_AC_KERNEL_BLK_RQ_POS
  38         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  39         ZFS_AC_KERNEL_GET_DISK_RO
  40         ZFS_AC_KERNEL_GET_GENDISK
  41         ZFS_AC_KERNEL_RQ_IS_SYNC
  42         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  43         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  44         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  45         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  46         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  47         ZFS_AC_KERNEL_SHOW_OPTIONS
  48         ZFS_AC_KERNEL_FSYNC
  49         ZFS_AC_KERNEL_EVICT_INODE
  50         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  51         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  52         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  53         ZFS_AC_KERNEL_FALLOCATE
  54         ZFS_AC_KERNEL_MKDIR_UMODE_T
  55         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  56         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  57         ZFS_AC_KERNEL_TRUNCATE_RANGE
  58         ZFS_AC_KERNEL_AUTOMOUNT
  59         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  60         ZFS_AC_KERNEL_COMMIT_METADATA
  61         ZFS_AC_KERNEL_CLEAR_INODE
  62         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  63         ZFS_AC_KERNEL_D_MAKE_ROOT
  64         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  65         ZFS_AC_KERNEL_D_SET_D_OP
  66         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  67         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  68         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  69         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  70         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  71         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  72         ZFS_AC_KERNEL_MOUNT_NODEV
  73         ZFS_AC_KERNEL_SHRINK
  74         ZFS_AC_KERNEL_S_D_OP
  75         ZFS_AC_KERNEL_BDI
  76         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  77         ZFS_AC_KERNEL_SET_NLINK
  78         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  79         ZFS_AC_KERNEL_5ARG_SGET
  80
  81         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  82                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  83         ])
  84         AC_SUBST(KERNELMAKE_PARAMS)
  85
  86
  87         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  88         dnl # compiler options are added by the kernel build system.
  89         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  90         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  91         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  92
  93         AC_SUBST(KERNELCPPFLAGS)
  94 ])
  95
  96 dnl #
  97 dnl # Detect name used for Module.symvers file in kernel
  98 dnl #
  99 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 100         modpost=$LINUX/scripts/Makefile.modpost
 101         AC_MSG_CHECKING([kernel file name for module symbols])
 102         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 103                 AS_IF([grep -q Modules.symvers $modpost], [
 104                         LINUX_SYMBOLS=Modules.symvers
 105                 ], [
 106                         LINUX_SYMBOLS=Module.symvers
 107                 ])
 108
 109                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 110                         AC_MSG_ERROR([
 111         *** Please make sure the kernel devel package for your distribution
 112         *** is installed.  If your building with a custom kernel make sure the
 113         *** kernel is configured, built, and the '--with-linux=PATH' configure
 114         *** option refers to the location of the kernel source.])
 115                 ])
 116         ], [
 117                 LINUX_SYMBOLS=NONE
 118         ])
 119         AC_MSG_RESULT($LINUX_SYMBOLS)
 120         AC_SUBST(LINUX_SYMBOLS)
 121 ])
 122
 123 dnl #
 124 dnl # Detect the kernel to be built against
 125 dnl #
 126 AC_DEFUN([ZFS_AC_KERNEL], [
 127         AC_ARG_WITH([linux],
 128                 AS_HELP_STRING([--with-linux=PATH],
 129                 [Path to kernel source]),
 130                 [kernelsrc="$withval"])
 131
 132         AC_ARG_WITH(linux-obj,
 133                 AS_HELP_STRING([--with-linux-obj=PATH],
 134                 [Path to kernel build objects]),
 135                 [kernelbuild="$withval"])
 136
 137         AC_MSG_CHECKING([kernel source directory])
 138         AS_IF([test -z "$kernelsrc"], [
 139                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 140                         headersdir="/lib/modules/$(uname -r)/source"
 141                         sourcelink=$(readlink -f "$headersdir")
 142                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 143                         headersdir="/lib/modules/$(uname -r)/build"
 144                         sourcelink=$(readlink -f "$headersdir")
 145                 ], [
 146                         sourcelink=$(ls -1d /usr/src/kernels/* \
 147                                      /usr/src/linux-* \
 148                                      2>/dev/null | grep -v obj | tail -1)
 149                 ])
 150
 151                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 152                         kernelsrc=`readlink -f ${sourcelink}`
 153                 ], [
 154                         kernelsrc="[Not found]"
 155                 ])
 156         ], [
 157                 AS_IF([test "$kernelsrc" = "NONE"], [
 158                         kernsrcver=NONE
 159                 ])
 160         ])
 161
 162         AC_MSG_RESULT([$kernelsrc])
 163         AS_IF([test ! -d "$kernelsrc"], [
 164                 AC_MSG_ERROR([
 165         *** Please make sure the kernel devel package for your distribution
 166         *** is installed then try again.  If that fails you can specify the
 167         *** location of the kernel source with the '--with-linux=PATH' option.])
 168         ])
 169
 170         AC_MSG_CHECKING([kernel build directory])
 171         AS_IF([test -z "$kernelbuild"], [
 172                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 173                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 174                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 175                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 176                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 177                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 178                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 179                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 180                 ], [
 181                         kernelbuild=${kernelsrc}
 182                 ])
 183         ])
 184         AC_MSG_RESULT([$kernelbuild])
 185
 186         AC_MSG_CHECKING([kernel source version])
 187         utsrelease1=$kernelbuild/include/linux/version.h
 188         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 189         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 190         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 191                 utsrelease=linux/version.h
 192         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 193                 utsrelease=linux/utsrelease.h
 194         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 195                 utsrelease=generated/utsrelease.h
 196         ])
 197
 198         AS_IF([test "$utsrelease"], [
 199                 kernsrcver=`(echo "#include <$utsrelease>";
 200                              echo "kernsrcver=UTS_RELEASE") |
 201                              cpp -I $kernelbuild/include |
 202                              grep "^kernsrcver=" | cut -d \" -f 2`
 203
 204                 AS_IF([test -z "$kernsrcver"], [
 205                         AC_MSG_RESULT([Not found])
 206                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 207                 ])
 208         ], [
 209                 AC_MSG_RESULT([Not found])
 210                 if test "x$enable_linux_builtin" != xyes; then
 211                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 212                 else
 213                         AC_MSG_ERROR([
 214         *** Cannot find UTS_RELEASE definition.
 215         *** Please run 'make prepare' inside the kernel source tree.])
 216                 fi
 217         ])
 218
 219         AC_MSG_RESULT([$kernsrcver])
 220
 221         LINUX=${kernelsrc}
 222         LINUX_OBJ=${kernelbuild}
 223         LINUX_VERSION=${kernsrcver}
 224
 225         AC_SUBST(LINUX)
 226         AC_SUBST(LINUX_OBJ)
 227         AC_SUBST(LINUX_VERSION)
 228
 229         ZFS_AC_MODULE_SYMVERS
 230 ])
 231
 232 dnl #
 233 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 234 dnl # does not exist this is likely because the SPL has been configured
 235 dnl # but not built.  The '--with-spl-timeout' option can be passed
 236 dnl # to pause here, waiting for the file to appear from a concurrently
 237 dnl # building SPL package.  If the file does not appear in time, a good
 238 dnl # guess is made as to what this file will be named based on what it
 239 dnl # is named in the kernel build products.  This file will first be
 240 dnl # used at link time so if the guess is wrong the build will fail
 241 dnl # then.  This unfortunately means the ZFS package does not contain a
 242 dnl # reliable mechanism to detect symbols exported by the SPL at
 243 dnl # configure time.
 244 dnl #
 245 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 246         AC_ARG_WITH([spl-timeout],
 247                 AS_HELP_STRING([--with-spl-timeout=SECS],
 248                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 249                 [timeout="$withval"], [timeout=0])
 250
 251         AC_MSG_CHECKING([spl file name for module symbols])
 252         SPL_SYMBOLS=NONE
 253
 254         while true; do
 255                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 256                         SPL_SYMBOLS=Module.symvers
 257                 ], [test -r $SPL_OBJ/Modules.symvers], [
 258                         SPL_SYMBOLS=Modules.symvers
 259                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 260                         SPL_SYMBOLS=Module.symvers
 261                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 262                         SPL_SYMBOLS=Modules.symvers
 263                 ])
 264
 265                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 266                         break;
 267                 ], [
 268                         sleep 1
 269                         timeout=$((timeout-1))
 270                 ])
 271         done
 272
 273         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 274                 SPL_SYMBOLS=$LINUX_SYMBOLS
 275         ])
 276
 277         AC_MSG_RESULT([$SPL_SYMBOLS])
 278         AC_SUBST(SPL_SYMBOLS)
 279 ])
 280
 281 dnl #
 282 dnl # Detect the SPL module to be built against
 283 dnl #
 284 AC_DEFUN([ZFS_AC_SPL], [
 285         AC_ARG_WITH([spl],
 286                 AS_HELP_STRING([--with-spl=PATH],
 287                 [Path to spl source]),
 288                 [splsrc="$withval"])
 289
 290         AC_ARG_WITH([spl-obj],
 291                 AS_HELP_STRING([--with-spl-obj=PATH],
 292                 [Path to spl build objects]),
 293                 [splbuild="$withval"])
 294
 295
 296         AC_MSG_CHECKING([spl source directory])
 297         AS_IF([test -z "$splsrc"], [
 298                 dnl #
 299                 dnl # Look in the standard development package location
 300                 dnl #
 301                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 302                             2>/dev/null | tail -1`
 303
 304                 dnl #
 305                 dnl # Look in the DKMS source location
 306                 dnl #
 307                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 308                         sourcelink=`ls -1d /var/lib/dkms/spl/*/build \
 309                                     2>/dev/null | tail -1`
 310                 ])
 311
 312                 dnl #
 313                 dnl # Look in the parent directory
 314                 dnl #
 315                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 316                         sourcelink=../spl
 317                 ])
 318
 319                 dnl #
 320                 dnl # Look in the kernel directory
 321                 dnl #
 322                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 323                         sourcelink="$LINUX"
 324                 ])
 325
 326                 AS_IF([test -e $sourcelink/spl_config.h], [
 327                         splsrc=`readlink -f ${sourcelink}`
 328                 ], [
 329                         AC_MSG_RESULT([Not found])
 330                         AC_MSG_ERROR([
 331         *** Please make sure the spl devel package for your distribution
 332         *** is installed then try again.  If that fails you can specify the
 333         *** location of the spl source with the '--with-spl=PATH' option.])
 334                 ])
 335         ], [
 336                 AS_IF([test "$splsrc" = "NONE"], [
 337                         splbuild=NONE
 338                         splsrcver=NONE
 339                 ])
 340         ])
 341
 342         AC_MSG_RESULT([$splsrc])
 343         AC_MSG_CHECKING([spl build directory])
 344         AS_IF([test -z "$splbuild"], [
 345                 splbuild=${splsrc}
 346         ])
 347         AC_MSG_RESULT([$splbuild])
 348
 349         AC_MSG_CHECKING([spl source version])
 350         AS_IF([test -r $splbuild/spl_config.h &&
 351                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 352
 353                 splsrcver=`(echo "#include <spl_config.h>";
 354                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 355                             cpp -I $splbuild |
 356                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 357         ])
 358
 359         AS_IF([test -z "$splsrcver"], [
 360                 AC_MSG_RESULT([Not found])
 361                 AC_MSG_ERROR([
 362         *** Cannot determine the version of the spl source.
 363         *** Please prepare the spl source before running this script])
 364         ])
 365
 366         AC_MSG_RESULT([$splsrcver])
 367
 368         SPL=${splsrc}
 369         SPL_OBJ=${splbuild}
 370         SPL_VERSION=${splsrcver}
 371
 372         AC_SUBST(SPL)
 373         AC_SUBST(SPL_OBJ)
 374         AC_SUBST(SPL_VERSION)
 375
 376         ZFS_AC_SPL_MODULE_SYMVERS
 377 ])
 378
 379 dnl #
 380 dnl # Basic toolchain sanity check.
 381 dnl #
 382 AC_DEFUN([ZFS_AC_TEST_MODULE],
 383         [AC_MSG_CHECKING([whether modules can be built])
 384         ZFS_LINUX_TRY_COMPILE([],[],[
 385                 AC_MSG_RESULT([yes])
 386         ],[
 387                 AC_MSG_RESULT([no])
 388                 if test "x$enable_linux_builtin" != xyes; then
 389                         AC_MSG_ERROR([*** Unable to build an empty module.])
 390                 else
 391                         AC_MSG_ERROR([
 392         *** Unable to build an empty module.
 393         *** Please run 'make scripts' inside the kernel source tree.])
 394                 fi
 395         ])
 396 ])
 397
 398 dnl #
 399 dnl # Certain kernel build options are not supported.  These must be
 400 dnl # detected at configure time and cause a build failure.  Otherwise
 401 dnl # modules may be successfully built that behave incorrectly.
 402 dnl #
 403 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 404
 405         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 406                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 407                         [Define to 1 if licensed under the GPL])
 408         ])
 409
 410         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 411 ])
 412
 413 dnl #
 414 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 415 dnl #
 416 dnl # This is typically only set for debug kernels because it comes with
 417 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 418 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 419 dnl # This will cause a failure at link time which we'd rather know about
 420 dnl # at compile time.
 421 dnl #
 422 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 423 dnl # with the upstream community we add a check to detect this case.
 424 dnl #
 425 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 426
 427         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 428                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 429                 tmp_flags="$EXTRA_KCFLAGS"
 430                 ZFS_LINUX_TRY_COMPILE([
 431                         #include <linux/module.h>
 432                         #include <linux/mutex.h>
 433
 434                         MODULE_LICENSE("$ZFS_META_LICENSE");
 435                 ],[
 436                         struct mutex lock;
 437
 438                         mutex_init(&lock);
 439                         mutex_lock(&lock);
 440                         mutex_unlock(&lock);
 441                 ],[
 442                         AC_MSG_RESULT(no)
 443                 ],[
 444                         AC_MSG_RESULT(yes)
 445                         AC_MSG_ERROR([
 446         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 447         *** with the CDDL license and will prevent the module linking stage
 448         *** from succeeding.  You must rebuild your kernel without this
 449         *** option enabled.])
 450                 ])
 451                 EXTRA_KCFLAGS="$tmp_flags"
 452         ], [])
 453 ])
 454
 455 dnl #
 456 dnl # ZFS_LINUX_CONFTEST
 457 dnl #
 458 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 459 cat confdefs.h - <<_ACEOF >conftest.c
 460 $1
 461 _ACEOF
 462 ])
 463
 464 dnl #
 465 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 466 dnl #
 467 m4_define([ZFS_LANG_PROGRAM], [
 468 $1
 469 int
 470 main (void)
 471 {
 472 dnl Do *not* indent the following line: there may be CPP directives.
 473 dnl Don't move the `;' right after for the same reason.
 474 $2
 475   ;
 476   return 0;
 477 }
 478 ])
 479
 480 dnl #
 481 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 482 dnl #
 483 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 484         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 485         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 486         echo "obj-m := conftest.o" >build/Makefile
 487         modpost_flag=''
 488         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 489         AS_IF(
 490                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 491                 [$4],
 492                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 493         )
 494         rm -Rf build
 495 ])
 496
 497 dnl #
 498 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 499 dnl #
 500 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 501         [ZFS_LINUX_COMPILE_IFELSE(
 502         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 503         [modules],
 504         [test -s build/conftest.o],
 505         [$3], [$4])
 506 ])
 507
 508 dnl #
 509 dnl # ZFS_LINUX_CONFIG
 510 dnl #
 511 AC_DEFUN([ZFS_LINUX_CONFIG],
 512         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 513         ZFS_LINUX_TRY_COMPILE([
 514                 #include <linux/module.h>
 515         ],[
 516                 #ifndef CONFIG_$1
 517                 #error CONFIG_$1 not #defined
 518                 #endif
 519         ],[
 520                 AC_MSG_RESULT([yes])
 521                 $2
 522         ],[
 523                 AC_MSG_RESULT([no])
 524                 $3
 525         ])
 526 ])
 527
 528 dnl #
 529 dnl # ZFS_CHECK_SYMBOL_EXPORT
 530 dnl # check symbol exported or not
 531 dnl #
 532 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 533         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 534                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 535         rc=$?
 536         if test $rc -ne 0; then
 537                 export=0
 538                 for file in $2; do
 539                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 540                                 "$LINUX/$file" 2>/dev/null
 541                         rc=$?
 542                         if test $rc -eq 0; then
 543                                 export=1
 544                                 break;
 545                         fi
 546                 done
 547                 if test $export -eq 0; then :
 548                         $4
 549                 else :
 550                         $3
 551                 fi
 552         else :
 553                 $3
 554         fi
 555 ])
 556
 557 dnl #
 558 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 559 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 560 dnl # is called if not compiling for builtin
 561 dnl #
 562 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 563         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 564         if test $rc -ne 0; then :
 565                 $6
 566         else
 567                 if test "x$enable_linux_builtin" != xyes; then
 568                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 569                 fi
 570                 if test $rc -ne 0; then :
 571                         $6
 572                 else :
 573                         $5
 574                 fi
 575         fi
 576 ])