config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  18         ZFS_AC_KERNEL_BIO_FAILFAST
  19         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  20         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  21         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  22         ZFS_AC_KERNEL_BIO_RW_SYNC
  23         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  24         ZFS_AC_KERNEL_REQ_SYNC
  25         ZFS_AC_KERNEL_BLK_END_REQUEST
  26         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  27         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  29         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  30         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  31         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  32         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  33         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  34         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  35         ZFS_AC_KERNEL_BLK_RQ_BYTES
  36         ZFS_AC_KERNEL_BLK_RQ_POS
  37         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_RQ_IS_SYNC
  41         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  42         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  43         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  44         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  45         ZFS_AC_KERNEL_SHOW_OPTIONS
  46         ZFS_AC_KERNEL_FSYNC
  47         ZFS_AC_KERNEL_EVICT_INODE
  48         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  49         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  50         ZFS_AC_KERNEL_FALLOCATE
  51         ZFS_AC_KERNEL_TRUNCATE_RANGE
  52         ZFS_AC_KERNEL_CREATE_UMODE_T
  53         ZFS_AC_KERNEL_AUTOMOUNT
  54         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  55         ZFS_AC_KERNEL_CLEAR_INODE
  56         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  57         ZFS_AC_KERNEL_D_MAKE_ROOT
  58         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  59         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  60         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  61         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  62         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  63         ZFS_AC_KERNEL_MOUNT_NODEV
  64         ZFS_AC_KERNEL_SHRINK
  65         ZFS_AC_KERNEL_BDI
  66         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  67         ZFS_AC_KERNEL_SET_NLINK
  68
  69         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  70                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  71         ])
  72         AC_SUBST(KERNELMAKE_PARAMS)
  73
  74
  75         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  76         dnl # compiler options are added by the kernel build system.
  77         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  78         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  79         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  80
  81         AC_SUBST(KERNELCPPFLAGS)
  82 ])
  83
  84 dnl #
  85 dnl # Detect name used for Module.symvers file in kernel
  86 dnl #
  87 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  88         modpost=$LINUX/scripts/Makefile.modpost
  89         AC_MSG_CHECKING([kernel file name for module symbols])
  90         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
  91                 AS_IF([grep -q Modules.symvers $modpost], [
  92                         LINUX_SYMBOLS=Modules.symvers
  93                 ], [
  94                         LINUX_SYMBOLS=Module.symvers
  95                 ])
  96
  97                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
  98                         AC_MSG_ERROR([
  99         *** Please make sure the kernel devel package for your distribution
 100         *** is installed.  If your building with a custom kernel make sure the
 101         *** kernel is configured, built, and the '--with-linux=PATH' configure
 102         *** option refers to the location of the kernel source.])
 103                 ])
 104         ], [
 105                 LINUX_SYMBOLS=NONE
 106         ])
 107         AC_MSG_RESULT($LINUX_SYMBOLS)
 108         AC_SUBST(LINUX_SYMBOLS)
 109 ])
 110
 111 dnl #
 112 dnl # Detect the kernel to be built against
 113 dnl #
 114 AC_DEFUN([ZFS_AC_KERNEL], [
 115         AC_ARG_WITH([linux],
 116                 AS_HELP_STRING([--with-linux=PATH],
 117                 [Path to kernel source]),
 118                 [kernelsrc="$withval"])
 119
 120         AC_ARG_WITH(linux-obj,
 121                 AS_HELP_STRING([--with-linux-obj=PATH],
 122                 [Path to kernel build objects]),
 123                 [kernelbuild="$withval"])
 124
 125         AC_MSG_CHECKING([kernel source directory])
 126         AS_IF([test -z "$kernelsrc"], [
 127                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 128                         headersdir="/lib/modules/$(uname -r)/source"
 129                         sourcelink=$(readlink -f "$headersdir")
 130                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 131                         headersdir="/lib/modules/$(uname -r)/build"
 132                         sourcelink=$(readlink -f "$headersdir")
 133                 ], [
 134                         sourcelink=$(ls -1d /usr/src/kernels/* \
 135                                      /usr/src/linux-* \
 136                                      2>/dev/null | grep -v obj | tail -1)
 137                 ])
 138
 139                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 140                         kernelsrc=`readlink -f ${sourcelink}`
 141                 ], [
 142                         AC_MSG_RESULT([Not found])
 143                         AC_MSG_ERROR([
 144         *** Please make sure the kernel devel package for your distribution
 145         *** is installed then try again.  If that fails you can specify the
 146         *** location of the kernel source with the '--with-linux=PATH' option.])
 147                 ])
 148         ], [
 149                 AS_IF([test "$kernelsrc" = "NONE"], [
 150                         kernsrcver=NONE
 151                 ])
 152         ])
 153
 154         AC_MSG_RESULT([$kernelsrc])
 155         AC_MSG_CHECKING([kernel build directory])
 156         AS_IF([test -z "$kernelbuild"], [
 157                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 158                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 159                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 160                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 161                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 162                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 163                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 164                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 165                 ], [
 166                         kernelbuild=${kernelsrc}
 167                 ])
 168         ])
 169         AC_MSG_RESULT([$kernelbuild])
 170
 171         AC_MSG_CHECKING([kernel source version])
 172         utsrelease1=$kernelbuild/include/linux/version.h
 173         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 174         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 175         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 176                 utsrelease=linux/version.h
 177         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 178                 utsrelease=linux/utsrelease.h
 179         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 180                 utsrelease=generated/utsrelease.h
 181         ])
 182
 183         AS_IF([test "$utsrelease"], [
 184                 kernsrcver=`(echo "#include <$utsrelease>";
 185                              echo "kernsrcver=UTS_RELEASE") |
 186                              cpp -I $kernelbuild/include |
 187                              grep "^kernsrcver=" | cut -d \" -f 2`
 188
 189                 AS_IF([test -z "$kernsrcver"], [
 190                         AC_MSG_RESULT([Not found])
 191                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 192                 ])
 193         ], [
 194                 AC_MSG_RESULT([Not found])
 195                 if test "x$enable_linux_builtin" != xyes; then
 196                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 197                 else
 198                         AC_MSG_ERROR([
 199         *** Cannot find UTS_RELEASE definition.
 200         *** Please run 'make prepare' inside the kernel source tree.])
 201                 fi
 202         ])
 203
 204         AC_MSG_RESULT([$kernsrcver])
 205
 206         LINUX=${kernelsrc}
 207         LINUX_OBJ=${kernelbuild}
 208         LINUX_VERSION=${kernsrcver}
 209
 210         AC_SUBST(LINUX)
 211         AC_SUBST(LINUX_OBJ)
 212         AC_SUBST(LINUX_VERSION)
 213
 214         ZFS_AC_MODULE_SYMVERS
 215 ])
 216
 217 dnl #
 218 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 219 dnl # does not exist this is likely because the SPL has been configured
 220 dnl # but not built.  To allow recursive builds a good guess is made as to
 221 dnl # what this file will be named based on what it is named in the kernel
 222 dnl # build products.  This file will first be used at link time so if
 223 dnl # the guess is wrong the build will fail then.  This unfortunately
 224 dnl # means the ZFS package does not contain a reliable mechanism to
 225 dnl # detect symbols exported by the SPL at configure time.
 226 dnl #
 227 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 228         AC_MSG_CHECKING([spl file name for module symbols])
 229         AS_IF([test -r $SPL_OBJ/Module.symvers], [
 230                 SPL_SYMBOLS=Module.symvers
 231         ], [test -r $SPL_OBJ/Modules.symvers], [
 232                 SPL_SYMBOLS=Modules.symvers
 233         ], [test -r $SPL_OBJ/module/Module.symvers], [
 234                 SPL_SYMBOLS=Module.symvers
 235         ], [test -r $SPL_OBJ/module/Modules.symvers], [
 236                 SPL_SYMBOLS=Modules.symvers
 237         ], [
 238                 SPL_SYMBOLS=$LINUX_SYMBOLS
 239         ])
 240
 241         AC_MSG_RESULT([$SPL_SYMBOLS])
 242         AC_SUBST(SPL_SYMBOLS)
 243 ])
 244
 245 dnl #
 246 dnl # Detect the SPL module to be built against
 247 dnl #
 248 AC_DEFUN([ZFS_AC_SPL], [
 249         AC_ARG_WITH([spl],
 250                 AS_HELP_STRING([--with-spl=PATH],
 251                 [Path to spl source]),
 252                 [splsrc="$withval"])
 253
 254         AC_ARG_WITH([spl-obj],
 255                 AS_HELP_STRING([--with-spl-obj=PATH],
 256                 [Path to spl build objects]),
 257                 [splbuild="$withval"])
 258
 259
 260         AC_MSG_CHECKING([spl source directory])
 261         AS_IF([test -z "$splsrc"], [
 262                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 263                             2>/dev/null | tail -1`
 264
 265                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink], [
 266                         sourcelink=../spl
 267                 ])
 268
 269                 AS_IF([test -e $sourcelink], [
 270                         splsrc=`readlink -f ${sourcelink}`
 271                 ], [
 272                         AC_MSG_RESULT([Not found])
 273                         AC_MSG_ERROR([
 274         *** Please make sure the spl devel package for your distribution
 275         *** is installed then try again.  If that fails you can specify the
 276         *** location of the spl source with the '--with-spl=PATH' option.])
 277                 ])
 278         ], [
 279                 AS_IF([test "$splsrc" = "NONE"], [
 280                         splbuild=NONE
 281                         splsrcver=NONE
 282                 ])
 283         ])
 284
 285         AC_MSG_RESULT([$splsrc])
 286         AC_MSG_CHECKING([spl build directory])
 287         AS_IF([test -z "$splbuild"], [
 288                 splbuild=${splsrc}
 289         ])
 290         AC_MSG_RESULT([$splbuild])
 291
 292         AC_MSG_CHECKING([spl source version])
 293         AS_IF([test -r $splbuild/spl_config.h &&
 294                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 295
 296                 splsrcver=`(echo "#include <spl_config.h>";
 297                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 298                             cpp -I $splbuild |
 299                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 300         ])
 301
 302         AS_IF([test -z "$splsrcver"], [
 303                 AC_MSG_RESULT([Not found])
 304                 AC_MSG_ERROR([
 305         *** Cannot determine the version of the spl source.
 306         *** Please prepare the spl source before running this script])
 307         ])
 308
 309         AC_MSG_RESULT([$splsrcver])
 310
 311         SPL=${splsrc}
 312         SPL_OBJ=${splbuild}
 313         SPL_VERSION=${splsrcver}
 314
 315         AC_SUBST(SPL)
 316         AC_SUBST(SPL_OBJ)
 317         AC_SUBST(SPL_VERSION)
 318
 319         ZFS_AC_SPL_MODULE_SYMVERS
 320 ])
 321
 322 dnl #
 323 dnl # Basic toolchain sanity check.
 324 dnl #
 325 AC_DEFUN([ZFS_AC_TEST_MODULE],
 326         [AC_MSG_CHECKING([whether modules can be built])
 327         ZFS_LINUX_TRY_COMPILE([],[],[
 328                 AC_MSG_RESULT([yes])
 329         ],[
 330                 AC_MSG_RESULT([no])
 331                 if test "x$enable_linux_builtin" != xyes; then
 332                         AC_MSG_ERROR([*** Unable to build an empty module.])
 333                 else
 334                         AC_MSG_ERROR([
 335         *** Unable to build an empty module.
 336         *** Please run 'make scripts' inside the kernel source tree.])
 337                 fi
 338         ])
 339 ])
 340
 341 dnl #
 342 dnl # Certain kernel build options are not supported.  These must be
 343 dnl # detected at configure time and cause a build failure.  Otherwise
 344 dnl # modules may be successfully built that behave incorrectly.
 345 dnl #
 346 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 347
 348         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 349                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 350                         [Define to 1 if licensed under the GPL])
 351         ])
 352
 353         ZFS_AC_KERNEL_CONFIG_PREEMPT
 354         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 355 ])
 356
 357 dnl #
 358 dnl # Check CONFIG_PREEMPT
 359 dnl #
 360 dnl # Premptible kernels will be supported in the future.  But at the
 361 dnl # moment there are a few places in the code which need to be updated
 362 dnl # to accomidate them.  Until that work occurs we should detect this
 363 dnl # at configure time and fail with a sensible message.  Otherwise,
 364 dnl # people will be able to build successfully, however they will have
 365 dnl # stability problems.  See https://github.com/zfsonlinux/zfs/issues/83
 366 dnl #
 367 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_PREEMPT], [
 368
 369         ZFS_LINUX_CONFIG([PREEMPT],
 370                 AC_MSG_ERROR([
 371         *** Kernel built with CONFIG_PREEMPT which is not supported.
 372         *** You must rebuild your kernel without this option.]), [])
 373 ])
 374
 375 dnl #
 376 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 377 dnl #
 378 dnl # This is typically only set for debug kernels because it comes with
 379 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 380 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 381 dnl # This will cause a failure at link time which we'd rather know about
 382 dnl # at compile time.
 383 dnl #
 384 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 385 dnl # with the upstream community we add a check to detect this case.
 386 dnl #
 387 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 388
 389         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 390                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 391                 tmp_flags="$EXTRA_KCFLAGS"
 392                 ZFS_LINUX_TRY_COMPILE([
 393                         #include <linux/module.h>
 394                         #include <linux/mutex.h>
 395
 396                         MODULE_LICENSE("$ZFS_META_LICENSE");
 397                 ],[
 398                         struct mutex lock;
 399
 400                         mutex_init(&lock);
 401                         mutex_lock(&lock);
 402                         mutex_unlock(&lock);
 403                 ],[
 404                         AC_MSG_RESULT(no)
 405                 ],[
 406                         AC_MSG_RESULT(yes)
 407                         AC_MSG_ERROR([
 408         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 409         *** with the CDDL license and will prevent the module linking stage
 410         *** from succeeding.  You must rebuild your kernel without this
 411         *** option enabled.])
 412                 ])
 413                 EXTRA_KCFLAGS="$tmp_flags"
 414         ], [])
 415 ])
 416
 417 dnl #
 418 dnl # ZFS_LINUX_CONFTEST
 419 dnl #
 420 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 421 cat confdefs.h - <<_ACEOF >conftest.c
 422 $1
 423 _ACEOF
 424 ])
 425
 426 dnl #
 427 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 428 dnl #
 429 m4_define([ZFS_LANG_PROGRAM], [
 430 $1
 431 int
 432 main (void)
 433 {
 434 dnl Do *not* indent the following line: there may be CPP directives.
 435 dnl Don't move the `;' right after for the same reason.
 436 $2
 437   ;
 438   return 0;
 439 }
 440 ])
 441
 442 dnl #
 443 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 444 dnl #
 445 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 446         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 447         rm -Rf build && mkdir -p build
 448         echo "obj-m := conftest.o" >build/Makefile
 449         AS_IF(
 450                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 451                 [$4],
 452                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 453         )
 454         rm -Rf build
 455 ])
 456
 457 dnl #
 458 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 459 dnl #
 460 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 461         [ZFS_LINUX_COMPILE_IFELSE(
 462         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 463         [modules],
 464         [test -s build/conftest.o],
 465         [$3], [$4])
 466 ])
 467
 468 dnl #
 469 dnl # ZFS_LINUX_CONFIG
 470 dnl #
 471 AC_DEFUN([ZFS_LINUX_CONFIG],
 472         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 473         ZFS_LINUX_TRY_COMPILE([
 474                 #include <linux/module.h>
 475         ],[
 476                 #ifndef CONFIG_$1
 477                 #error CONFIG_$1 not #defined
 478                 #endif
 479         ],[
 480                 AC_MSG_RESULT([yes])
 481                 $2
 482         ],[
 483                 AC_MSG_RESULT([no])
 484                 $3
 485         ])
 486 ])
 487
 488 dnl #
 489 dnl # ZFS_CHECK_SYMBOL_EXPORT
 490 dnl # check symbol exported or not
 491 dnl #
 492 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT],
 493         [AC_MSG_CHECKING([whether symbol $1 is exported])
 494         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 495                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 496         rc=$?
 497         AS_IF([test $rc -ne 0], [
 498                 export=0
 499                 for file in $2; do
 500                         grep -q -E "EXPORT_SYMBOL.*($1)" "$LINUX/$file" 2>/dev/null
 501                         rc=$?
 502                         AS_IF([test $rc -eq 0], [
 503                                 export=1
 504                                 break;
 505                         ])
 506                 done
 507                 AS_IF([test $export -eq 0], [
 508                         AC_MSG_RESULT([no])
 509                         $4
 510                 ], [
 511                         AC_MSG_RESULT([yes])
 512                         $3
 513                 ])
 514         ], [
 515                 AC_MSG_RESULT([yes])
 516                 $3
 517         ])
 518 ])