config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_KERNEL_CONFIG
   8         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
   9         ZFS_AC_KERNEL_TYPE_FMODE_T
  10         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  11         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  12         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  13         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  14         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  15         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  16         ZFS_AC_KERNEL_BIO_FAILFAST
  17         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  18         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  19         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  20         ZFS_AC_KERNEL_BIO_RW_SYNC
  21         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  22         ZFS_AC_KERNEL_REQ_SYNC
  23         ZFS_AC_KERNEL_BLK_END_REQUEST
  24         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  25         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  26         ZFS_AC_KERNEL_BLK_RQ_BYTES
  27         ZFS_AC_KERNEL_BLK_RQ_POS
  28         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  29         ZFS_AC_KERNEL_GET_DISK_RO
  30         ZFS_AC_KERNEL_RQ_IS_SYNC
  31         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  32         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  33         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  34         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  35         ZFS_AC_KERNEL_SHOW_OPTIONS
  36         ZFS_AC_KERNEL_FSYNC
  37         ZFS_AC_KERNEL_EVICT_INODE
  38         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  39         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  40         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  41         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  42         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  43         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  44         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  45         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  46         ZFS_AC_KERNEL_MOUNT_NODEV
  47         ZFS_AC_KERNEL_SHRINK
  48         ZFS_AC_KERNEL_BDI
  49         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  50         ZFS_AC_KERNEL_SET_NLINK
  51
  52         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  53                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  54         ])
  55         AC_SUBST(KERNELMAKE_PARAMS)
  56
  57
  58         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  59         dnl # compiler options are added by the kernel build system.
  60         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  61         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  62         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  63
  64         AC_SUBST(KERNELCPPFLAGS)
  65 ])
  66
  67 dnl #
  68 dnl # Detect name used for Module.symvers file in kernel
  69 dnl #
  70 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  71         modpost=$LINUX/scripts/Makefile.modpost
  72         AC_MSG_CHECKING([kernel file name for module symbols])
  73         AS_IF([test -f "$modpost"], [
  74                 AS_IF([grep -q Modules.symvers $modpost], [
  75                         LINUX_SYMBOLS=Modules.symvers
  76                 ], [
  77                         LINUX_SYMBOLS=Module.symvers
  78                 ])
  79
  80                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
  81                         AC_MSG_ERROR([
  82         *** Please make sure the kernel devel package for your distribution
  83         *** is installed.  If your building with a custom kernel make sure the
  84         *** kernel is configured, built, and the '--with-linux=PATH' configure
  85         *** option refers to the location of the kernel source.])
  86                 ])
  87         ], [
  88                 LINUX_SYMBOLS=NONE
  89         ])
  90         AC_MSG_RESULT($LINUX_SYMBOLS)
  91         AC_SUBST(LINUX_SYMBOLS)
  92 ])
  93
  94 dnl #
  95 dnl # Detect the kernel to be built against
  96 dnl #
  97 AC_DEFUN([ZFS_AC_KERNEL], [
  98         AC_ARG_WITH([linux],
  99                 AS_HELP_STRING([--with-linux=PATH],
 100                 [Path to kernel source]),
 101                 [kernelsrc="$withval"])
 102
 103         AC_ARG_WITH(linux-obj,
 104                 AS_HELP_STRING([--with-linux-obj=PATH],
 105                 [Path to kernel build objects]),
 106                 [kernelbuild="$withval"])
 107
 108         AC_MSG_CHECKING([kernel source directory])
 109         AS_IF([test -z "$kernelsrc"], [
 110                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 111                         headersdir="/lib/modules/$(uname -r)/source"
 112                         sourcelink=$(readlink -f "$headersdir")
 113                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 114                         headersdir="/lib/modules/$(uname -r)/build"
 115                         sourcelink=$(readlink -f "$headersdir")
 116                 ], [
 117                         sourcelink=$(ls -1d /usr/src/kernels/* \
 118                                      /usr/src/linux-* \
 119                                      2>/dev/null | grep -v obj | tail -1)
 120                 ])
 121
 122                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 123                         kernelsrc=`readlink -f ${sourcelink}`
 124                 ], [
 125                         AC_MSG_RESULT([Not found])
 126                         AC_MSG_ERROR([
 127         *** Please make sure the kernel devel package for your distribution
 128         *** is installed then try again.  If that fails you can specify the
 129         *** location of the kernel source with the '--with-linux=PATH' option.])
 130                 ])
 131         ], [
 132                 AS_IF([test "$kernelsrc" = "NONE"], [
 133                         kernsrcver=NONE
 134                 ])
 135         ])
 136
 137         AC_MSG_RESULT([$kernelsrc])
 138         AC_MSG_CHECKING([kernel build directory])
 139         AS_IF([test -z "$kernelbuild"], [
 140                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 141                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 142                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 143                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 144                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 145                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 146                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 147                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 148                 ], [
 149                         kernelbuild=${kernelsrc}
 150                 ])
 151         ])
 152         AC_MSG_RESULT([$kernelbuild])
 153
 154         AC_MSG_CHECKING([kernel source version])
 155         utsrelease1=$kernelbuild/include/linux/version.h
 156         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 157         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 158         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 159                 utsrelease=linux/version.h
 160         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 161                 utsrelease=linux/utsrelease.h
 162         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 163                 utsrelease=generated/utsrelease.h
 164         ])
 165
 166         AS_IF([test "$utsrelease"], [
 167                 kernsrcver=`(echo "#include <$utsrelease>";
 168                              echo "kernsrcver=UTS_RELEASE") |
 169                              cpp -I $kernelbuild/include |
 170                              grep "^kernsrcver=" | cut -d \" -f 2`
 171
 172                 AS_IF([test -z "$kernsrcver"], [
 173                         AC_MSG_RESULT([Not found])
 174                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 175                 ])
 176         ], [
 177                 AC_MSG_RESULT([Not found])
 178                 AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 179         ])
 180
 181         AC_MSG_RESULT([$kernsrcver])
 182
 183         LINUX=${kernelsrc}
 184         LINUX_OBJ=${kernelbuild}
 185         LINUX_VERSION=${kernsrcver}
 186
 187         AC_SUBST(LINUX)
 188         AC_SUBST(LINUX_OBJ)
 189         AC_SUBST(LINUX_VERSION)
 190
 191         ZFS_AC_MODULE_SYMVERS
 192 ])
 193
 194 dnl #
 195 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 196 dnl # does not exist this is likely because the SPL has been configured
 197 dnl # but not built.  To allow recursive builds a good guess is made as to
 198 dnl # what this file will be named based on what it is named in the kernel
 199 dnl # build products.  This file will first be used at link time so if
 200 dnl # the guess is wrong the build will fail then.  This unfortunately
 201 dnl # means the ZFS package does not contain a reliable mechanism to
 202 dnl # detect symbols exported by the SPL at configure time.
 203 dnl #
 204 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 205         AC_MSG_CHECKING([spl file name for module symbols])
 206         AS_IF([test -r $SPL_OBJ/Module.symvers], [
 207                 SPL_SYMBOLS=Module.symvers
 208         ], [test -r $SPL_OBJ/Modules.symvers], [
 209                 SPL_SYMBOLS=Modules.symvers
 210         ], [test -r $SPL_OBJ/module/Module.symvers], [
 211                 SPL_SYMBOLS=Module.symvers
 212         ], [test -r $SPL_OBJ/module/Modules.symvers], [
 213                 SPL_SYMBOLS=Modules.symvers
 214         ], [
 215                 SPL_SYMBOLS=$LINUX_SYMBOLS
 216         ])
 217
 218         AC_MSG_RESULT([$SPL_SYMBOLS])
 219         AC_SUBST(SPL_SYMBOLS)
 220 ])
 221
 222 dnl #
 223 dnl # Detect the SPL module to be built against
 224 dnl #
 225 AC_DEFUN([ZFS_AC_SPL], [
 226         AC_ARG_WITH([spl],
 227                 AS_HELP_STRING([--with-spl=PATH],
 228                 [Path to spl source]),
 229                 [splsrc="$withval"])
 230
 231         AC_ARG_WITH([spl-obj],
 232                 AS_HELP_STRING([--with-spl-obj=PATH],
 233                 [Path to spl build objects]),
 234                 [splbuild="$withval"])
 235
 236
 237         AC_MSG_CHECKING([spl source directory])
 238         AS_IF([test -z "$splsrc"], [
 239                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 240                             2>/dev/null | tail -1`
 241
 242                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink], [
 243                         sourcelink=../spl
 244                 ])
 245
 246                 AS_IF([test -e $sourcelink], [
 247                         splsrc=`readlink -f ${sourcelink}`
 248                 ], [
 249                         AC_MSG_RESULT([Not found])
 250                         AC_MSG_ERROR([
 251         *** Please make sure the spl devel package for your distribution
 252         *** is installed then try again.  If that fails you can specify the
 253         *** location of the spl source with the '--with-spl=PATH' option.])
 254                 ])
 255         ], [
 256                 AS_IF([test "$splsrc" = "NONE"], [
 257                         splbuild=NONE
 258                         splsrcver=NONE
 259                 ])
 260         ])
 261
 262         AC_MSG_RESULT([$splsrc])
 263         AC_MSG_CHECKING([spl build directory])
 264         AS_IF([test -z "$splbuild"], [
 265                 splbuild=${splsrc}
 266         ])
 267         AC_MSG_RESULT([$splbuild])
 268
 269         AC_MSG_CHECKING([spl source version])
 270         AS_IF([test -r $splbuild/spl_config.h &&
 271                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 272
 273                 splsrcver=`(echo "#include <spl_config.h>";
 274                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 275                             cpp -I $splbuild |
 276                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 277         ])
 278
 279         AS_IF([test -z "$splsrcver"], [
 280                 AC_MSG_RESULT([Not found])
 281                 AC_MSG_ERROR([
 282         *** Cannot determine the version of the spl source.
 283         *** Please prepare the spl source before running this script])
 284         ])
 285
 286         AC_MSG_RESULT([$splsrcver])
 287
 288         SPL=${splsrc}
 289         SPL_OBJ=${splbuild}
 290         SPL_VERSION=${splsrcver}
 291
 292         AC_SUBST(SPL)
 293         AC_SUBST(SPL_OBJ)
 294         AC_SUBST(SPL_VERSION)
 295
 296         ZFS_AC_SPL_MODULE_SYMVERS
 297 ])
 298
 299 dnl #
 300 dnl # Certain kernel build options are not supported.  These must be
 301 dnl # detected at configure time and cause a build failure.  Otherwise
 302 dnl # modules may be successfully built that behave incorrectly.
 303 dnl #
 304 dnl # CONFIG_PREEMPT - Preempt kernels require special handling.
 305 dnl #
 306 dnl # There are certain kernel build options which when enabled are
 307 dnl # completely incompatible with non GPL kernel modules.  It is best
 308 dnl # to detect these at configure time and fail with a clear error
 309 dnl # rather than build everything and fail during linking.
 310 dnl #
 311 dnl # CONFIG_DEBUG_LOCK_ALLOC - Maps mutex_lock() to mutex_lock_nested()
 312 dnl #
 313 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 314
 315         ZFS_LINUX_CONFIG([PREEMPT],
 316                 AC_MSG_ERROR([
 317         *** Kernel built with CONFIG_PREEMPT which is not supported.
 318         *** You must rebuild your kernel without this option.]), [])
 319
 320         AS_IF([test "$ZFS_META_LICENSE" = CDDL], [
 321                 ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC],
 322                 AC_MSG_ERROR([
 323         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is
 324         *** incompatible with the CDDL license.  You must rebuild
 325         *** your kernel without this option.]), [])
 326         ])
 327
 328         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 329                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 330                         [Define to 1 if licensed under the GPL])
 331         ])
 332 ])
 333
 334 dnl #
 335 dnl # ZFS_LINUX_CONFTEST
 336 dnl #
 337 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 338 cat confdefs.h - <<_ACEOF >conftest.c
 339 $1
 340 _ACEOF
 341 ])
 342
 343 dnl #
 344 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 345 dnl #
 346 m4_define([ZFS_LANG_PROGRAM], [
 347 $1
 348 int
 349 main (void)
 350 {
 351 dnl Do *not* indent the following line: there may be CPP directives.
 352 dnl Don't move the `;' right after for the same reason.
 353 $2
 354   ;
 355   return 0;
 356 }
 357 ])
 358
 359 dnl #
 360 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 361 dnl #
 362 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 363         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 364         rm -Rf build && mkdir -p build
 365         echo "obj-m := conftest.o" >build/Makefile
 366         AS_IF(
 367                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 368                 [$4],
 369                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 370         )
 371         rm -Rf build
 372 ])
 373
 374 dnl #
 375 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 376 dnl #
 377 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 378         [ZFS_LINUX_COMPILE_IFELSE(
 379         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 380         [modules],
 381         [test -s build/conftest.o],
 382         [$3], [$4])
 383 ])
 384
 385 dnl #
 386 dnl # ZFS_LINUX_CONFIG
 387 dnl #
 388 AC_DEFUN([ZFS_LINUX_CONFIG],
 389         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 390         ZFS_LINUX_TRY_COMPILE([
 391                 #include <linux/module.h>
 392         ],[
 393                 #ifndef CONFIG_$1
 394                 #error CONFIG_$1 not #defined
 395                 #endif
 396         ],[
 397                 AC_MSG_RESULT([yes])
 398                 $2
 399         ],[
 400                 AC_MSG_RESULT([no])
 401                 $3
 402         ])
 403 ])
 404
 405 dnl #
 406 dnl # ZFS_CHECK_SYMBOL_EXPORT
 407 dnl # check symbol exported or not
 408 dnl #
 409 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT],
 410         [AC_MSG_CHECKING([whether symbol $1 is exported])
 411         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 412                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 413         rc=$?
 414         AS_IF([test $rc -ne 0], [
 415                 export=0
 416                 for file in $2; do
 417                         grep -q -E "EXPORT_SYMBOL.*($1)" "$LINUX/$file" 2>/dev/null
 418                         rc=$?
 419                         AS_IF([test $rc -eq 0], [
 420                                 export=1
 421                                 break;
 422                         ])
 423                 done
 424                 AS_IF([test $export -eq 0], [
 425                         AC_MSG_RESULT([no])
 426                         $4
 427                 ], [
 428                         AC_MSG_RESULT([yes])
 429                         $3
 430                 ])
 431         ], [
 432                 AC_MSG_RESULT([yes])
 433                 $3
 434         ])
 435 ])