config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  18         ZFS_AC_KERNEL_BIO_FAILFAST
  19         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  20         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  21         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  22         ZFS_AC_KERNEL_BIO_RW_SYNC
  23         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  24         ZFS_AC_KERNEL_REQ_SYNC
  25         ZFS_AC_KERNEL_BLK_END_REQUEST
  26         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  27         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  29         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  30         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  31         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  32         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  33         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  34         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  35         ZFS_AC_KERNEL_BLK_RQ_BYTES
  36         ZFS_AC_KERNEL_BLK_RQ_POS
  37         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_RQ_IS_SYNC
  41         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  42         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  43         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  44         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  46         ZFS_AC_KERNEL_SHOW_OPTIONS
  47         ZFS_AC_KERNEL_FSYNC
  48         ZFS_AC_KERNEL_EVICT_INODE
  49         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  50         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  51         ZFS_AC_KERNEL_FALLOCATE
  52         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  53         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  54         ZFS_AC_KERNEL_TRUNCATE_RANGE
  55         ZFS_AC_KERNEL_CREATE_UMODE_T
  56         ZFS_AC_KERNEL_AUTOMOUNT
  57         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  58         ZFS_AC_KERNEL_COMMIT_METADATA
  59         ZFS_AC_KERNEL_CLEAR_INODE
  60         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  61         ZFS_AC_KERNEL_D_MAKE_ROOT
  62         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  63         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  64         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  65         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  66         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  67         ZFS_AC_KERNEL_MOUNT_NODEV
  68         ZFS_AC_KERNEL_SHRINK
  69         ZFS_AC_KERNEL_BDI
  70         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  71         ZFS_AC_KERNEL_SET_NLINK
  72         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  73         ZFS_AC_KERNEL_5ARG_SGET
  74
  75         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  76                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  77         ])
  78         AC_SUBST(KERNELMAKE_PARAMS)
  79
  80
  81         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  82         dnl # compiler options are added by the kernel build system.
  83         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  84         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  85         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  86
  87         AC_SUBST(KERNELCPPFLAGS)
  88 ])
  89
  90 dnl #
  91 dnl # Detect name used for Module.symvers file in kernel
  92 dnl #
  93 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  94         modpost=$LINUX/scripts/Makefile.modpost
  95         AC_MSG_CHECKING([kernel file name for module symbols])
  96         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
  97                 AS_IF([grep -q Modules.symvers $modpost], [
  98                         LINUX_SYMBOLS=Modules.symvers
  99                 ], [
 100                         LINUX_SYMBOLS=Module.symvers
 101                 ])
 102
 103                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 104                         AC_MSG_ERROR([
 105         *** Please make sure the kernel devel package for your distribution
 106         *** is installed.  If your building with a custom kernel make sure the
 107         *** kernel is configured, built, and the '--with-linux=PATH' configure
 108         *** option refers to the location of the kernel source.])
 109                 ])
 110         ], [
 111                 LINUX_SYMBOLS=NONE
 112         ])
 113         AC_MSG_RESULT($LINUX_SYMBOLS)
 114         AC_SUBST(LINUX_SYMBOLS)
 115 ])
 116
 117 dnl #
 118 dnl # Detect the kernel to be built against
 119 dnl #
 120 AC_DEFUN([ZFS_AC_KERNEL], [
 121         AC_ARG_WITH([linux],
 122                 AS_HELP_STRING([--with-linux=PATH],
 123                 [Path to kernel source]),
 124                 [kernelsrc="$withval"])
 125
 126         AC_ARG_WITH(linux-obj,
 127                 AS_HELP_STRING([--with-linux-obj=PATH],
 128                 [Path to kernel build objects]),
 129                 [kernelbuild="$withval"])
 130
 131         AC_MSG_CHECKING([kernel source directory])
 132         AS_IF([test -z "$kernelsrc"], [
 133                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 134                         headersdir="/lib/modules/$(uname -r)/source"
 135                         sourcelink=$(readlink -f "$headersdir")
 136                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 137                         headersdir="/lib/modules/$(uname -r)/build"
 138                         sourcelink=$(readlink -f "$headersdir")
 139                 ], [
 140                         sourcelink=$(ls -1d /usr/src/kernels/* \
 141                                      /usr/src/linux-* \
 142                                      2>/dev/null | grep -v obj | tail -1)
 143                 ])
 144
 145                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 146                         kernelsrc=`readlink -f ${sourcelink}`
 147                 ], [
 148                         AC_MSG_RESULT([Not found])
 149                         AC_MSG_ERROR([
 150         *** Please make sure the kernel devel package for your distribution
 151         *** is installed then try again.  If that fails you can specify the
 152         *** location of the kernel source with the '--with-linux=PATH' option.])
 153                 ])
 154         ], [
 155                 AS_IF([test "$kernelsrc" = "NONE"], [
 156                         kernsrcver=NONE
 157                 ])
 158         ])
 159
 160         AC_MSG_RESULT([$kernelsrc])
 161         AC_MSG_CHECKING([kernel build directory])
 162         AS_IF([test -z "$kernelbuild"], [
 163                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 164                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 165                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 166                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 167                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 168                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 169                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 170                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 171                 ], [
 172                         kernelbuild=${kernelsrc}
 173                 ])
 174         ])
 175         AC_MSG_RESULT([$kernelbuild])
 176
 177         AC_MSG_CHECKING([kernel source version])
 178         utsrelease1=$kernelbuild/include/linux/version.h
 179         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 180         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 181         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 182                 utsrelease=linux/version.h
 183         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 184                 utsrelease=linux/utsrelease.h
 185         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 186                 utsrelease=generated/utsrelease.h
 187         ])
 188
 189         AS_IF([test "$utsrelease"], [
 190                 kernsrcver=`(echo "#include <$utsrelease>";
 191                              echo "kernsrcver=UTS_RELEASE") |
 192                              cpp -I $kernelbuild/include |
 193                              grep "^kernsrcver=" | cut -d \" -f 2`
 194
 195                 AS_IF([test -z "$kernsrcver"], [
 196                         AC_MSG_RESULT([Not found])
 197                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 198                 ])
 199         ], [
 200                 AC_MSG_RESULT([Not found])
 201                 if test "x$enable_linux_builtin" != xyes; then
 202                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 203                 else
 204                         AC_MSG_ERROR([
 205         *** Cannot find UTS_RELEASE definition.
 206         *** Please run 'make prepare' inside the kernel source tree.])
 207                 fi
 208         ])
 209
 210         AC_MSG_RESULT([$kernsrcver])
 211
 212         LINUX=${kernelsrc}
 213         LINUX_OBJ=${kernelbuild}
 214         LINUX_VERSION=${kernsrcver}
 215
 216         AC_SUBST(LINUX)
 217         AC_SUBST(LINUX_OBJ)
 218         AC_SUBST(LINUX_VERSION)
 219
 220         ZFS_AC_MODULE_SYMVERS
 221 ])
 222
 223 dnl #
 224 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 225 dnl # does not exist this is likely because the SPL has been configured
 226 dnl # but not built.  The '--with-spl-timeout' option can be passed
 227 dnl # to pause here, waiting for the file to appear from a concurrently
 228 dnl # building SPL package.  If the file does not appear in time, a good
 229 dnl # guess is made as to what this file will be named based on what it
 230 dnl # is named in the kernel build products.  This file will first be
 231 dnl # used at link time so if the guess is wrong the build will fail
 232 dnl # then.  This unfortunately means the ZFS package does not contain a
 233 dnl # reliable mechanism to detect symbols exported by the SPL at
 234 dnl # configure time.
 235 dnl #
 236 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 237         AC_ARG_WITH([spl-timeout],
 238                 AS_HELP_STRING([--with-spl-timeout=SECS],
 239                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 240                 [timeout="$withval"], [timeout=0])
 241
 242         AC_MSG_CHECKING([spl file name for module symbols])
 243         SPL_SYMBOLS=NONE
 244
 245         while true; do
 246                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 247                         SPL_SYMBOLS=Module.symvers
 248                 ], [test -r $SPL_OBJ/Modules.symvers], [
 249                         SPL_SYMBOLS=Modules.symvers
 250                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 251                         SPL_SYMBOLS=Module.symvers
 252                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 253                         SPL_SYMBOLS=Modules.symvers
 254                 ])
 255
 256                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 257                         break;
 258                 ], [
 259                         sleep 1
 260                         timeout=$((timeout-1))
 261                 ])
 262         done
 263
 264         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 265                 SPL_SYMBOLS=$LINUX_SYMBOLS
 266         ])
 267
 268         AC_MSG_RESULT([$SPL_SYMBOLS])
 269         AC_SUBST(SPL_SYMBOLS)
 270 ])
 271
 272 dnl #
 273 dnl # Detect the SPL module to be built against
 274 dnl #
 275 AC_DEFUN([ZFS_AC_SPL], [
 276         AC_ARG_WITH([spl],
 277                 AS_HELP_STRING([--with-spl=PATH],
 278                 [Path to spl source]),
 279                 [splsrc="$withval"])
 280
 281         AC_ARG_WITH([spl-obj],
 282                 AS_HELP_STRING([--with-spl-obj=PATH],
 283                 [Path to spl build objects]),
 284                 [splbuild="$withval"])
 285
 286
 287         AC_MSG_CHECKING([spl source directory])
 288         AS_IF([test -z "$splsrc"], [
 289                 dnl #
 290                 dnl # Look in the standard development package location
 291                 dnl #
 292                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 293                             2>/dev/null | tail -1`
 294
 295                 dnl #
 296                 dnl # Look in the DKMS source location
 297                 dnl #
 298                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 299                         sourcelink=`ls -1d /var/lib/dkms/spl/*/build \
 300                                     2>/dev/null | tail -1`
 301                 ])
 302
 303                 dnl #
 304                 dnl # Look in the parent directory
 305                 dnl #
 306                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 307                         sourcelink=../spl
 308                 ])
 309
 310                 dnl #
 311                 dnl # Look in the kernel directory
 312                 dnl #
 313                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 314                         sourcelink="$LINUX"
 315                 ])
 316
 317                 AS_IF([test -e $sourcelink/spl_config.h], [
 318                         splsrc=`readlink -f ${sourcelink}`
 319                 ], [
 320                         AC_MSG_RESULT([Not found])
 321                         AC_MSG_ERROR([
 322         *** Please make sure the spl devel package for your distribution
 323         *** is installed then try again.  If that fails you can specify the
 324         *** location of the spl source with the '--with-spl=PATH' option.])
 325                 ])
 326         ], [
 327                 AS_IF([test "$splsrc" = "NONE"], [
 328                         splbuild=NONE
 329                         splsrcver=NONE
 330                 ])
 331         ])
 332
 333         AC_MSG_RESULT([$splsrc])
 334         AC_MSG_CHECKING([spl build directory])
 335         AS_IF([test -z "$splbuild"], [
 336                 splbuild=${splsrc}
 337         ])
 338         AC_MSG_RESULT([$splbuild])
 339
 340         AC_MSG_CHECKING([spl source version])
 341         AS_IF([test -r $splbuild/spl_config.h &&
 342                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 343
 344                 splsrcver=`(echo "#include <spl_config.h>";
 345                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 346                             cpp -I $splbuild |
 347                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 348         ])
 349
 350         AS_IF([test -z "$splsrcver"], [
 351                 AC_MSG_RESULT([Not found])
 352                 AC_MSG_ERROR([
 353         *** Cannot determine the version of the spl source.
 354         *** Please prepare the spl source before running this script])
 355         ])
 356
 357         AC_MSG_RESULT([$splsrcver])
 358
 359         SPL=${splsrc}
 360         SPL_OBJ=${splbuild}
 361         SPL_VERSION=${splsrcver}
 362
 363         AC_SUBST(SPL)
 364         AC_SUBST(SPL_OBJ)
 365         AC_SUBST(SPL_VERSION)
 366
 367         ZFS_AC_SPL_MODULE_SYMVERS
 368 ])
 369
 370 dnl #
 371 dnl # Basic toolchain sanity check.
 372 dnl #
 373 AC_DEFUN([ZFS_AC_TEST_MODULE],
 374         [AC_MSG_CHECKING([whether modules can be built])
 375         ZFS_LINUX_TRY_COMPILE([],[],[
 376                 AC_MSG_RESULT([yes])
 377         ],[
 378                 AC_MSG_RESULT([no])
 379                 if test "x$enable_linux_builtin" != xyes; then
 380                         AC_MSG_ERROR([*** Unable to build an empty module.])
 381                 else
 382                         AC_MSG_ERROR([
 383         *** Unable to build an empty module.
 384         *** Please run 'make scripts' inside the kernel source tree.])
 385                 fi
 386         ])
 387 ])
 388
 389 dnl #
 390 dnl # Certain kernel build options are not supported.  These must be
 391 dnl # detected at configure time and cause a build failure.  Otherwise
 392 dnl # modules may be successfully built that behave incorrectly.
 393 dnl #
 394 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 395
 396         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 397                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 398                         [Define to 1 if licensed under the GPL])
 399         ])
 400
 401         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 402 ])
 403
 404 dnl #
 405 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 406 dnl #
 407 dnl # This is typically only set for debug kernels because it comes with
 408 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 409 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 410 dnl # This will cause a failure at link time which we'd rather know about
 411 dnl # at compile time.
 412 dnl #
 413 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 414 dnl # with the upstream community we add a check to detect this case.
 415 dnl #
 416 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 417
 418         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 419                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 420                 tmp_flags="$EXTRA_KCFLAGS"
 421                 ZFS_LINUX_TRY_COMPILE([
 422                         #include <linux/module.h>
 423                         #include <linux/mutex.h>
 424
 425                         MODULE_LICENSE("$ZFS_META_LICENSE");
 426                 ],[
 427                         struct mutex lock;
 428
 429                         mutex_init(&lock);
 430                         mutex_lock(&lock);
 431                         mutex_unlock(&lock);
 432                 ],[
 433                         AC_MSG_RESULT(no)
 434                 ],[
 435                         AC_MSG_RESULT(yes)
 436                         AC_MSG_ERROR([
 437         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 438         *** with the CDDL license and will prevent the module linking stage
 439         *** from succeeding.  You must rebuild your kernel without this
 440         *** option enabled.])
 441                 ])
 442                 EXTRA_KCFLAGS="$tmp_flags"
 443         ], [])
 444 ])
 445
 446 dnl #
 447 dnl # ZFS_LINUX_CONFTEST
 448 dnl #
 449 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 450 cat confdefs.h - <<_ACEOF >conftest.c
 451 $1
 452 _ACEOF
 453 ])
 454
 455 dnl #
 456 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 457 dnl #
 458 m4_define([ZFS_LANG_PROGRAM], [
 459 $1
 460 int
 461 main (void)
 462 {
 463 dnl Do *not* indent the following line: there may be CPP directives.
 464 dnl Don't move the `;' right after for the same reason.
 465 $2
 466   ;
 467   return 0;
 468 }
 469 ])
 470
 471 dnl #
 472 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 473 dnl #
 474 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 475         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 476         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 477         echo "obj-m := conftest.o" >build/Makefile
 478         modpost_flag=''
 479         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 480         AS_IF(
 481                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 482                 [$4],
 483                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 484         )
 485         rm -Rf build
 486 ])
 487
 488 dnl #
 489 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 490 dnl #
 491 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 492         [ZFS_LINUX_COMPILE_IFELSE(
 493         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 494         [modules],
 495         [test -s build/conftest.o],
 496         [$3], [$4])
 497 ])
 498
 499 dnl #
 500 dnl # ZFS_LINUX_CONFIG
 501 dnl #
 502 AC_DEFUN([ZFS_LINUX_CONFIG],
 503         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 504         ZFS_LINUX_TRY_COMPILE([
 505                 #include <linux/module.h>
 506         ],[
 507                 #ifndef CONFIG_$1
 508                 #error CONFIG_$1 not #defined
 509                 #endif
 510         ],[
 511                 AC_MSG_RESULT([yes])
 512                 $2
 513         ],[
 514                 AC_MSG_RESULT([no])
 515                 $3
 516         ])
 517 ])
 518
 519 dnl #
 520 dnl # ZFS_CHECK_SYMBOL_EXPORT
 521 dnl # check symbol exported or not
 522 dnl #
 523 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 524         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 525                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 526         rc=$?
 527         if test $rc -ne 0; then
 528                 export=0
 529                 for file in $2; do
 530                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 531                                 "$LINUX/$file" 2>/dev/null
 532                         rc=$?
 533                         if test $rc -eq 0; then
 534                                 export=1
 535                                 break;
 536                         fi
 537                 done
 538                 if test $export -eq 0; then :
 539                         $4
 540                 else :
 541                         $3
 542                 fi
 543         else :
 544                 $3
 545         fi
 546 ])
 547
 548 dnl #
 549 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 550 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 551 dnl # is called if not compiling for builtin
 552 dnl #
 553 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 554         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 555         if test $rc -ne 0; then :
 556                 $6
 557         else
 558                 if test "x$enable_linux_builtin" != xyes; then
 559                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 560                 fi
 561                 if test $rc -ne 0; then :
 562                         $6
 563                 else :
 564                         $5
 565                 fi
 566         fi
 567 ])