config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  18         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  19         ZFS_AC_KERNEL_BIO_FAILFAST
  20         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  21         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  22         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  23         ZFS_AC_KERNEL_BIO_RW_SYNC
  24         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  25         ZFS_AC_KERNEL_REQ_SYNC
  26         ZFS_AC_KERNEL_BLK_END_REQUEST
  27         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  30         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  31         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  32         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  33         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  34         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  35         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  36         ZFS_AC_KERNEL_BLK_RQ_BYTES
  37         ZFS_AC_KERNEL_BLK_RQ_POS
  38         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  39         ZFS_AC_KERNEL_GET_DISK_RO
  40         ZFS_AC_KERNEL_GET_GENDISK
  41         ZFS_AC_KERNEL_RQ_IS_SYNC
  42         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  43         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  44         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  45         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  46         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  47         ZFS_AC_KERNEL_SHOW_OPTIONS
  48         ZFS_AC_KERNEL_FSYNC
  49         ZFS_AC_KERNEL_EVICT_INODE
  50         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  51         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  52         ZFS_AC_KERNEL_FALLOCATE
  53         ZFS_AC_KERNEL_MKDIR_UMODE_T
  54         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  55         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  56         ZFS_AC_KERNEL_TRUNCATE_RANGE
  57         ZFS_AC_KERNEL_AUTOMOUNT
  58         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  59         ZFS_AC_KERNEL_COMMIT_METADATA
  60         ZFS_AC_KERNEL_CLEAR_INODE
  61         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  62         ZFS_AC_KERNEL_D_MAKE_ROOT
  63         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  64         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  65         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  66         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  67         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  68         ZFS_AC_KERNEL_MOUNT_NODEV
  69         ZFS_AC_KERNEL_SHRINK
  70         ZFS_AC_KERNEL_BDI
  71         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  72         ZFS_AC_KERNEL_SET_NLINK
  73         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  74         ZFS_AC_KERNEL_5ARG_SGET
  75
  76         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  77                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  78         ])
  79         AC_SUBST(KERNELMAKE_PARAMS)
  80
  81
  82         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  83         dnl # compiler options are added by the kernel build system.
  84         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  85         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  86         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  87
  88         AC_SUBST(KERNELCPPFLAGS)
  89 ])
  90
  91 dnl #
  92 dnl # Detect name used for Module.symvers file in kernel
  93 dnl #
  94 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  95         modpost=$LINUX/scripts/Makefile.modpost
  96         AC_MSG_CHECKING([kernel file name for module symbols])
  97         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
  98                 AS_IF([grep -q Modules.symvers $modpost], [
  99                         LINUX_SYMBOLS=Modules.symvers
 100                 ], [
 101                         LINUX_SYMBOLS=Module.symvers
 102                 ])
 103
 104                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 105                         AC_MSG_ERROR([
 106         *** Please make sure the kernel devel package for your distribution
 107         *** is installed.  If your building with a custom kernel make sure the
 108         *** kernel is configured, built, and the '--with-linux=PATH' configure
 109         *** option refers to the location of the kernel source.])
 110                 ])
 111         ], [
 112                 LINUX_SYMBOLS=NONE
 113         ])
 114         AC_MSG_RESULT($LINUX_SYMBOLS)
 115         AC_SUBST(LINUX_SYMBOLS)
 116 ])
 117
 118 dnl #
 119 dnl # Detect the kernel to be built against
 120 dnl #
 121 AC_DEFUN([ZFS_AC_KERNEL], [
 122         AC_ARG_WITH([linux],
 123                 AS_HELP_STRING([--with-linux=PATH],
 124                 [Path to kernel source]),
 125                 [kernelsrc="$withval"])
 126
 127         AC_ARG_WITH(linux-obj,
 128                 AS_HELP_STRING([--with-linux-obj=PATH],
 129                 [Path to kernel build objects]),
 130                 [kernelbuild="$withval"])
 131
 132         AC_MSG_CHECKING([kernel source directory])
 133         AS_IF([test -z "$kernelsrc"], [
 134                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 135                         headersdir="/lib/modules/$(uname -r)/source"
 136                         sourcelink=$(readlink -f "$headersdir")
 137                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 138                         headersdir="/lib/modules/$(uname -r)/build"
 139                         sourcelink=$(readlink -f "$headersdir")
 140                 ], [
 141                         sourcelink=$(ls -1d /usr/src/kernels/* \
 142                                      /usr/src/linux-* \
 143                                      2>/dev/null | grep -v obj | tail -1)
 144                 ])
 145
 146                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 147                         kernelsrc=`readlink -f ${sourcelink}`
 148                 ], [
 149                         kernelsrc="[Not found]"
 150                 ])
 151         ], [
 152                 AS_IF([test "$kernelsrc" = "NONE"], [
 153                         kernsrcver=NONE
 154                 ])
 155         ])
 156
 157         AC_MSG_RESULT([$kernelsrc])
 158         AS_IF([test ! -d "$kernelsrc"], [
 159                 AC_MSG_ERROR([
 160         *** Please make sure the kernel devel package for your distribution
 161         *** is installed then try again.  If that fails you can specify the
 162         *** location of the kernel source with the '--with-linux=PATH' option.])
 163         ])
 164
 165         AC_MSG_CHECKING([kernel build directory])
 166         AS_IF([test -z "$kernelbuild"], [
 167                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 168                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 169                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 170                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 171                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 172                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 173                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 174                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 175                 ], [
 176                         kernelbuild=${kernelsrc}
 177                 ])
 178         ])
 179         AC_MSG_RESULT([$kernelbuild])
 180
 181         AC_MSG_CHECKING([kernel source version])
 182         utsrelease1=$kernelbuild/include/linux/version.h
 183         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 184         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 185         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 186                 utsrelease=linux/version.h
 187         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 188                 utsrelease=linux/utsrelease.h
 189         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 190                 utsrelease=generated/utsrelease.h
 191         ])
 192
 193         AS_IF([test "$utsrelease"], [
 194                 kernsrcver=`(echo "#include <$utsrelease>";
 195                              echo "kernsrcver=UTS_RELEASE") |
 196                              cpp -I $kernelbuild/include |
 197                              grep "^kernsrcver=" | cut -d \" -f 2`
 198
 199                 AS_IF([test -z "$kernsrcver"], [
 200                         AC_MSG_RESULT([Not found])
 201                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 202                 ])
 203         ], [
 204                 AC_MSG_RESULT([Not found])
 205                 if test "x$enable_linux_builtin" != xyes; then
 206                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 207                 else
 208                         AC_MSG_ERROR([
 209         *** Cannot find UTS_RELEASE definition.
 210         *** Please run 'make prepare' inside the kernel source tree.])
 211                 fi
 212         ])
 213
 214         AC_MSG_RESULT([$kernsrcver])
 215
 216         LINUX=${kernelsrc}
 217         LINUX_OBJ=${kernelbuild}
 218         LINUX_VERSION=${kernsrcver}
 219
 220         AC_SUBST(LINUX)
 221         AC_SUBST(LINUX_OBJ)
 222         AC_SUBST(LINUX_VERSION)
 223
 224         ZFS_AC_MODULE_SYMVERS
 225 ])
 226
 227 dnl #
 228 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 229 dnl # does not exist this is likely because the SPL has been configured
 230 dnl # but not built.  The '--with-spl-timeout' option can be passed
 231 dnl # to pause here, waiting for the file to appear from a concurrently
 232 dnl # building SPL package.  If the file does not appear in time, a good
 233 dnl # guess is made as to what this file will be named based on what it
 234 dnl # is named in the kernel build products.  This file will first be
 235 dnl # used at link time so if the guess is wrong the build will fail
 236 dnl # then.  This unfortunately means the ZFS package does not contain a
 237 dnl # reliable mechanism to detect symbols exported by the SPL at
 238 dnl # configure time.
 239 dnl #
 240 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 241         AC_ARG_WITH([spl-timeout],
 242                 AS_HELP_STRING([--with-spl-timeout=SECS],
 243                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 244                 [timeout="$withval"], [timeout=0])
 245
 246         AC_MSG_CHECKING([spl file name for module symbols])
 247         SPL_SYMBOLS=NONE
 248
 249         while true; do
 250                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 251                         SPL_SYMBOLS=Module.symvers
 252                 ], [test -r $SPL_OBJ/Modules.symvers], [
 253                         SPL_SYMBOLS=Modules.symvers
 254                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 255                         SPL_SYMBOLS=Module.symvers
 256                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 257                         SPL_SYMBOLS=Modules.symvers
 258                 ])
 259
 260                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 261                         break;
 262                 ], [
 263                         sleep 1
 264                         timeout=$((timeout-1))
 265                 ])
 266         done
 267
 268         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 269                 SPL_SYMBOLS=$LINUX_SYMBOLS
 270         ])
 271
 272         AC_MSG_RESULT([$SPL_SYMBOLS])
 273         AC_SUBST(SPL_SYMBOLS)
 274 ])
 275
 276 dnl #
 277 dnl # Detect the SPL module to be built against
 278 dnl #
 279 AC_DEFUN([ZFS_AC_SPL], [
 280         AC_ARG_WITH([spl],
 281                 AS_HELP_STRING([--with-spl=PATH],
 282                 [Path to spl source]),
 283                 [splsrc="$withval"])
 284
 285         AC_ARG_WITH([spl-obj],
 286                 AS_HELP_STRING([--with-spl-obj=PATH],
 287                 [Path to spl build objects]),
 288                 [splbuild="$withval"])
 289
 290
 291         AC_MSG_CHECKING([spl source directory])
 292         AS_IF([test -z "$splsrc"], [
 293                 dnl #
 294                 dnl # Look in the standard development package location
 295                 dnl #
 296                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 297                             2>/dev/null | tail -1`
 298
 299                 dnl #
 300                 dnl # Look in the DKMS source location
 301                 dnl #
 302                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 303                         sourcelink=`ls -1d /var/lib/dkms/spl/*/build \
 304                                     2>/dev/null | tail -1`
 305                 ])
 306
 307                 dnl #
 308                 dnl # Look in the parent directory
 309                 dnl #
 310                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 311                         sourcelink=../spl
 312                 ])
 313
 314                 dnl #
 315                 dnl # Look in the kernel directory
 316                 dnl #
 317                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 318                         sourcelink="$LINUX"
 319                 ])
 320
 321                 AS_IF([test -e $sourcelink/spl_config.h], [
 322                         splsrc=`readlink -f ${sourcelink}`
 323                 ], [
 324                         AC_MSG_RESULT([Not found])
 325                         AC_MSG_ERROR([
 326         *** Please make sure the spl devel package for your distribution
 327         *** is installed then try again.  If that fails you can specify the
 328         *** location of the spl source with the '--with-spl=PATH' option.])
 329                 ])
 330         ], [
 331                 AS_IF([test "$splsrc" = "NONE"], [
 332                         splbuild=NONE
 333                         splsrcver=NONE
 334                 ])
 335         ])
 336
 337         AC_MSG_RESULT([$splsrc])
 338         AC_MSG_CHECKING([spl build directory])
 339         AS_IF([test -z "$splbuild"], [
 340                 splbuild=${splsrc}
 341         ])
 342         AC_MSG_RESULT([$splbuild])
 343
 344         AC_MSG_CHECKING([spl source version])
 345         AS_IF([test -r $splbuild/spl_config.h &&
 346                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 347
 348                 splsrcver=`(echo "#include <spl_config.h>";
 349                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 350                             cpp -I $splbuild |
 351                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 352         ])
 353
 354         AS_IF([test -z "$splsrcver"], [
 355                 AC_MSG_RESULT([Not found])
 356                 AC_MSG_ERROR([
 357         *** Cannot determine the version of the spl source.
 358         *** Please prepare the spl source before running this script])
 359         ])
 360
 361         AC_MSG_RESULT([$splsrcver])
 362
 363         SPL=${splsrc}
 364         SPL_OBJ=${splbuild}
 365         SPL_VERSION=${splsrcver}
 366
 367         AC_SUBST(SPL)
 368         AC_SUBST(SPL_OBJ)
 369         AC_SUBST(SPL_VERSION)
 370
 371         ZFS_AC_SPL_MODULE_SYMVERS
 372 ])
 373
 374 dnl #
 375 dnl # Basic toolchain sanity check.
 376 dnl #
 377 AC_DEFUN([ZFS_AC_TEST_MODULE],
 378         [AC_MSG_CHECKING([whether modules can be built])
 379         ZFS_LINUX_TRY_COMPILE([],[],[
 380                 AC_MSG_RESULT([yes])
 381         ],[
 382                 AC_MSG_RESULT([no])
 383                 if test "x$enable_linux_builtin" != xyes; then
 384                         AC_MSG_ERROR([*** Unable to build an empty module.])
 385                 else
 386                         AC_MSG_ERROR([
 387         *** Unable to build an empty module.
 388         *** Please run 'make scripts' inside the kernel source tree.])
 389                 fi
 390         ])
 391 ])
 392
 393 dnl #
 394 dnl # Certain kernel build options are not supported.  These must be
 395 dnl # detected at configure time and cause a build failure.  Otherwise
 396 dnl # modules may be successfully built that behave incorrectly.
 397 dnl #
 398 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 399
 400         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 401                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 402                         [Define to 1 if licensed under the GPL])
 403         ])
 404
 405         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 406 ])
 407
 408 dnl #
 409 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 410 dnl #
 411 dnl # This is typically only set for debug kernels because it comes with
 412 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 413 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 414 dnl # This will cause a failure at link time which we'd rather know about
 415 dnl # at compile time.
 416 dnl #
 417 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 418 dnl # with the upstream community we add a check to detect this case.
 419 dnl #
 420 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 421
 422         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 423                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 424                 tmp_flags="$EXTRA_KCFLAGS"
 425                 ZFS_LINUX_TRY_COMPILE([
 426                         #include <linux/module.h>
 427                         #include <linux/mutex.h>
 428
 429                         MODULE_LICENSE("$ZFS_META_LICENSE");
 430                 ],[
 431                         struct mutex lock;
 432
 433                         mutex_init(&lock);
 434                         mutex_lock(&lock);
 435                         mutex_unlock(&lock);
 436                 ],[
 437                         AC_MSG_RESULT(no)
 438                 ],[
 439                         AC_MSG_RESULT(yes)
 440                         AC_MSG_ERROR([
 441         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 442         *** with the CDDL license and will prevent the module linking stage
 443         *** from succeeding.  You must rebuild your kernel without this
 444         *** option enabled.])
 445                 ])
 446                 EXTRA_KCFLAGS="$tmp_flags"
 447         ], [])
 448 ])
 449
 450 dnl #
 451 dnl # ZFS_LINUX_CONFTEST
 452 dnl #
 453 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 454 cat confdefs.h - <<_ACEOF >conftest.c
 455 $1
 456 _ACEOF
 457 ])
 458
 459 dnl #
 460 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 461 dnl #
 462 m4_define([ZFS_LANG_PROGRAM], [
 463 $1
 464 int
 465 main (void)
 466 {
 467 dnl Do *not* indent the following line: there may be CPP directives.
 468 dnl Don't move the `;' right after for the same reason.
 469 $2
 470   ;
 471   return 0;
 472 }
 473 ])
 474
 475 dnl #
 476 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 477 dnl #
 478 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 479         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 480         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 481         echo "obj-m := conftest.o" >build/Makefile
 482         modpost_flag=''
 483         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 484         AS_IF(
 485                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 486                 [$4],
 487                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 488         )
 489         rm -Rf build
 490 ])
 491
 492 dnl #
 493 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 494 dnl #
 495 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 496         [ZFS_LINUX_COMPILE_IFELSE(
 497         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 498         [modules],
 499         [test -s build/conftest.o],
 500         [$3], [$4])
 501 ])
 502
 503 dnl #
 504 dnl # ZFS_LINUX_CONFIG
 505 dnl #
 506 AC_DEFUN([ZFS_LINUX_CONFIG],
 507         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 508         ZFS_LINUX_TRY_COMPILE([
 509                 #include <linux/module.h>
 510         ],[
 511                 #ifndef CONFIG_$1
 512                 #error CONFIG_$1 not #defined
 513                 #endif
 514         ],[
 515                 AC_MSG_RESULT([yes])
 516                 $2
 517         ],[
 518                 AC_MSG_RESULT([no])
 519                 $3
 520         ])
 521 ])
 522
 523 dnl #
 524 dnl # ZFS_CHECK_SYMBOL_EXPORT
 525 dnl # check symbol exported or not
 526 dnl #
 527 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 528         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 529                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 530         rc=$?
 531         if test $rc -ne 0; then
 532                 export=0
 533                 for file in $2; do
 534                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 535                                 "$LINUX/$file" 2>/dev/null
 536                         rc=$?
 537                         if test $rc -eq 0; then
 538                                 export=1
 539                                 break;
 540                         fi
 541                 done
 542                 if test $export -eq 0; then :
 543                         $4
 544                 else :
 545                         $3
 546                 fi
 547         else :
 548                 $3
 549         fi
 550 ])
 551
 552 dnl #
 553 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 554 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 555 dnl # is called if not compiling for builtin
 556 dnl #
 557 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 558         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 559         if test $rc -ne 0; then :
 560                 $6
 561         else
 562                 if test "x$enable_linux_builtin" != xyes; then
 563                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 564                 fi
 565                 if test $rc -ne 0; then :
 566                         $6
 567                 else :
 568                         $5
 569                 fi
 570         fi
 571 ])