config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_KERNEL_CONFIG
   8         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
   9         ZFS_AC_KERNEL_TYPE_FMODE_T
  10         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  11         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  12         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  13         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  14         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  15         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  16         ZFS_AC_KERNEL_BIO_FAILFAST
  17         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  18         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  19         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  20         ZFS_AC_KERNEL_BIO_RW_SYNC
  21         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  22         ZFS_AC_KERNEL_REQ_SYNC
  23         ZFS_AC_KERNEL_BLK_END_REQUEST
  24         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  25         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  26         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  27         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  28         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  29         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  30         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  31         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  32         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  33         ZFS_AC_KERNEL_BLK_RQ_BYTES
  34         ZFS_AC_KERNEL_BLK_RQ_POS
  35         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  36         ZFS_AC_KERNEL_GET_DISK_RO
  37         ZFS_AC_KERNEL_RQ_IS_SYNC
  38         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  39         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  40         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  41         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  42         ZFS_AC_KERNEL_SHOW_OPTIONS
  43         ZFS_AC_KERNEL_FSYNC
  44         ZFS_AC_KERNEL_EVICT_INODE
  45         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  46         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  47         ZFS_AC_KERNEL_FALLOCATE
  48         ZFS_AC_KERNEL_CREATE_UMODE_T
  49         ZFS_AC_KERNEL_AUTOMOUNT
  50         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  51         ZFS_AC_KERNEL_D_MAKE_ROOT
  52         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  53         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  54         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  55         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  56         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  57         ZFS_AC_KERNEL_MOUNT_NODEV
  58         ZFS_AC_KERNEL_SHRINK
  59         ZFS_AC_KERNEL_BDI
  60         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  61         ZFS_AC_KERNEL_SET_NLINK
  62
  63         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  64                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  65         ])
  66         AC_SUBST(KERNELMAKE_PARAMS)
  67
  68
  69         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  70         dnl # compiler options are added by the kernel build system.
  71         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  72         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  73         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  74
  75         AC_SUBST(KERNELCPPFLAGS)
  76 ])
  77
  78 dnl #
  79 dnl # Detect name used for Module.symvers file in kernel
  80 dnl #
  81 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  82         modpost=$LINUX/scripts/Makefile.modpost
  83         AC_MSG_CHECKING([kernel file name for module symbols])
  84         AS_IF([test -f "$modpost"], [
  85                 AS_IF([grep -q Modules.symvers $modpost], [
  86                         LINUX_SYMBOLS=Modules.symvers
  87                 ], [
  88                         LINUX_SYMBOLS=Module.symvers
  89                 ])
  90
  91                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
  92                         AC_MSG_ERROR([
  93         *** Please make sure the kernel devel package for your distribution
  94         *** is installed.  If your building with a custom kernel make sure the
  95         *** kernel is configured, built, and the '--with-linux=PATH' configure
  96         *** option refers to the location of the kernel source.])
  97                 ])
  98         ], [
  99                 LINUX_SYMBOLS=NONE
 100         ])
 101         AC_MSG_RESULT($LINUX_SYMBOLS)
 102         AC_SUBST(LINUX_SYMBOLS)
 103 ])
 104
 105 dnl #
 106 dnl # Detect the kernel to be built against
 107 dnl #
 108 AC_DEFUN([ZFS_AC_KERNEL], [
 109         AC_ARG_WITH([linux],
 110                 AS_HELP_STRING([--with-linux=PATH],
 111                 [Path to kernel source]),
 112                 [kernelsrc="$withval"])
 113
 114         AC_ARG_WITH(linux-obj,
 115                 AS_HELP_STRING([--with-linux-obj=PATH],
 116                 [Path to kernel build objects]),
 117                 [kernelbuild="$withval"])
 118
 119         AC_MSG_CHECKING([kernel source directory])
 120         AS_IF([test -z "$kernelsrc"], [
 121                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 122                         headersdir="/lib/modules/$(uname -r)/source"
 123                         sourcelink=$(readlink -f "$headersdir")
 124                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 125                         headersdir="/lib/modules/$(uname -r)/build"
 126                         sourcelink=$(readlink -f "$headersdir")
 127                 ], [
 128                         sourcelink=$(ls -1d /usr/src/kernels/* \
 129                                      /usr/src/linux-* \
 130                                      2>/dev/null | grep -v obj | tail -1)
 131                 ])
 132
 133                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 134                         kernelsrc=`readlink -f ${sourcelink}`
 135                 ], [
 136                         AC_MSG_RESULT([Not found])
 137                         AC_MSG_ERROR([
 138         *** Please make sure the kernel devel package for your distribution
 139         *** is installed then try again.  If that fails you can specify the
 140         *** location of the kernel source with the '--with-linux=PATH' option.])
 141                 ])
 142         ], [
 143                 AS_IF([test "$kernelsrc" = "NONE"], [
 144                         kernsrcver=NONE
 145                 ])
 146         ])
 147
 148         AC_MSG_RESULT([$kernelsrc])
 149         AC_MSG_CHECKING([kernel build directory])
 150         AS_IF([test -z "$kernelbuild"], [
 151                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 152                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 153                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 154                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 155                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 156                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 157                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 158                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 159                 ], [
 160                         kernelbuild=${kernelsrc}
 161                 ])
 162         ])
 163         AC_MSG_RESULT([$kernelbuild])
 164
 165         AC_MSG_CHECKING([kernel source version])
 166         utsrelease1=$kernelbuild/include/linux/version.h
 167         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 168         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 169         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 170                 utsrelease=linux/version.h
 171         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 172                 utsrelease=linux/utsrelease.h
 173         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 174                 utsrelease=generated/utsrelease.h
 175         ])
 176
 177         AS_IF([test "$utsrelease"], [
 178                 kernsrcver=`(echo "#include <$utsrelease>";
 179                              echo "kernsrcver=UTS_RELEASE") |
 180                              cpp -I $kernelbuild/include |
 181                              grep "^kernsrcver=" | cut -d \" -f 2`
 182
 183                 AS_IF([test -z "$kernsrcver"], [
 184                         AC_MSG_RESULT([Not found])
 185                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 186                 ])
 187         ], [
 188                 AC_MSG_RESULT([Not found])
 189                 AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 190         ])
 191
 192         AC_MSG_RESULT([$kernsrcver])
 193
 194         LINUX=${kernelsrc}
 195         LINUX_OBJ=${kernelbuild}
 196         LINUX_VERSION=${kernsrcver}
 197
 198         AC_SUBST(LINUX)
 199         AC_SUBST(LINUX_OBJ)
 200         AC_SUBST(LINUX_VERSION)
 201
 202         ZFS_AC_MODULE_SYMVERS
 203 ])
 204
 205 dnl #
 206 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 207 dnl # does not exist this is likely because the SPL has been configured
 208 dnl # but not built.  To allow recursive builds a good guess is made as to
 209 dnl # what this file will be named based on what it is named in the kernel
 210 dnl # build products.  This file will first be used at link time so if
 211 dnl # the guess is wrong the build will fail then.  This unfortunately
 212 dnl # means the ZFS package does not contain a reliable mechanism to
 213 dnl # detect symbols exported by the SPL at configure time.
 214 dnl #
 215 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 216         AC_MSG_CHECKING([spl file name for module symbols])
 217         AS_IF([test -r $SPL_OBJ/Module.symvers], [
 218                 SPL_SYMBOLS=Module.symvers
 219         ], [test -r $SPL_OBJ/Modules.symvers], [
 220                 SPL_SYMBOLS=Modules.symvers
 221         ], [test -r $SPL_OBJ/module/Module.symvers], [
 222                 SPL_SYMBOLS=Module.symvers
 223         ], [test -r $SPL_OBJ/module/Modules.symvers], [
 224                 SPL_SYMBOLS=Modules.symvers
 225         ], [
 226                 SPL_SYMBOLS=$LINUX_SYMBOLS
 227         ])
 228
 229         AC_MSG_RESULT([$SPL_SYMBOLS])
 230         AC_SUBST(SPL_SYMBOLS)
 231 ])
 232
 233 dnl #
 234 dnl # Detect the SPL module to be built against
 235 dnl #
 236 AC_DEFUN([ZFS_AC_SPL], [
 237         AC_ARG_WITH([spl],
 238                 AS_HELP_STRING([--with-spl=PATH],
 239                 [Path to spl source]),
 240                 [splsrc="$withval"])
 241
 242         AC_ARG_WITH([spl-obj],
 243                 AS_HELP_STRING([--with-spl-obj=PATH],
 244                 [Path to spl build objects]),
 245                 [splbuild="$withval"])
 246
 247
 248         AC_MSG_CHECKING([spl source directory])
 249         AS_IF([test -z "$splsrc"], [
 250                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 251                             2>/dev/null | tail -1`
 252
 253                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink], [
 254                         sourcelink=../spl
 255                 ])
 256
 257                 AS_IF([test -e $sourcelink], [
 258                         splsrc=`readlink -f ${sourcelink}`
 259                 ], [
 260                         AC_MSG_RESULT([Not found])
 261                         AC_MSG_ERROR([
 262         *** Please make sure the spl devel package for your distribution
 263         *** is installed then try again.  If that fails you can specify the
 264         *** location of the spl source with the '--with-spl=PATH' option.])
 265                 ])
 266         ], [
 267                 AS_IF([test "$splsrc" = "NONE"], [
 268                         splbuild=NONE
 269                         splsrcver=NONE
 270                 ])
 271         ])
 272
 273         AC_MSG_RESULT([$splsrc])
 274         AC_MSG_CHECKING([spl build directory])
 275         AS_IF([test -z "$splbuild"], [
 276                 splbuild=${splsrc}
 277         ])
 278         AC_MSG_RESULT([$splbuild])
 279
 280         AC_MSG_CHECKING([spl source version])
 281         AS_IF([test -r $splbuild/spl_config.h &&
 282                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 283
 284                 splsrcver=`(echo "#include <spl_config.h>";
 285                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 286                             cpp -I $splbuild |
 287                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 288         ])
 289
 290         AS_IF([test -z "$splsrcver"], [
 291                 AC_MSG_RESULT([Not found])
 292                 AC_MSG_ERROR([
 293         *** Cannot determine the version of the spl source.
 294         *** Please prepare the spl source before running this script])
 295         ])
 296
 297         AC_MSG_RESULT([$splsrcver])
 298
 299         SPL=${splsrc}
 300         SPL_OBJ=${splbuild}
 301         SPL_VERSION=${splsrcver}
 302
 303         AC_SUBST(SPL)
 304         AC_SUBST(SPL_OBJ)
 305         AC_SUBST(SPL_VERSION)
 306
 307         ZFS_AC_SPL_MODULE_SYMVERS
 308 ])
 309
 310 dnl #
 311 dnl # Certain kernel build options are not supported.  These must be
 312 dnl # detected at configure time and cause a build failure.  Otherwise
 313 dnl # modules may be successfully built that behave incorrectly.
 314 dnl #
 315 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 316
 317         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 318                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 319                         [Define to 1 if licensed under the GPL])
 320         ])
 321
 322         ZFS_AC_KERNEL_CONFIG_PREEMPT
 323         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 324 ])
 325
 326 dnl #
 327 dnl # Check CONFIG_PREEMPT
 328 dnl #
 329 dnl # Premptible kernels will be supported in the future.  But at the
 330 dnl # moment there are a few places in the code which need to be updated
 331 dnl # to accomidate them.  Until that work occurs we should detect this
 332 dnl # at configure time and fail with a sensible message.  Otherwise,
 333 dnl # people will be able to build successfully, however they will have
 334 dnl # stability problems.  See https://github.com/zfsonlinux/zfs/issues/83
 335 dnl #
 336 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_PREEMPT], [
 337
 338         ZFS_LINUX_CONFIG([PREEMPT],
 339                 AC_MSG_ERROR([
 340         *** Kernel built with CONFIG_PREEMPT which is not supported.
 341         *** You must rebuild your kernel without this option.]), [])
 342 ])
 343
 344 dnl #
 345 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 346 dnl #
 347 dnl # This is typically only set for debug kernels because it comes with
 348 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 349 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 350 dnl # This will cause a failure at link time which we'd rather know about
 351 dnl # at compile time.
 352 dnl #
 353 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 354 dnl # with the upstream community we add a check to detect this case.
 355 dnl #
 356 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 357
 358         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 359                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 360                 tmp_flags="$EXTRA_KCFLAGS"
 361                 ZFS_LINUX_TRY_COMPILE([
 362                         #include <linux/module.h>
 363                         #include <linux/mutex.h>
 364
 365                         MODULE_LICENSE("$ZFS_META_LICENSE");
 366                 ],[
 367                         struct mutex lock;
 368
 369                         mutex_init(&lock);
 370                         mutex_lock(&lock);
 371                         mutex_unlock(&lock);
 372                 ],[
 373                         AC_MSG_RESULT(no)
 374                 ],[
 375                         AC_MSG_RESULT(yes)
 376                         AC_MSG_ERROR([
 377         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 378         *** with the CDDL license and will prevent the module linking stage
 379         *** from succeeding.  You must rebuild your kernel without this
 380         *** option enabled.])
 381                 ])
 382                 EXTRA_KCFLAGS="$tmp_flags"
 383         ], [])
 384 ])
 385
 386 dnl #
 387 dnl # ZFS_LINUX_CONFTEST
 388 dnl #
 389 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 390 cat confdefs.h - <<_ACEOF >conftest.c
 391 $1
 392 _ACEOF
 393 ])
 394
 395 dnl #
 396 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 397 dnl #
 398 m4_define([ZFS_LANG_PROGRAM], [
 399 $1
 400 int
 401 main (void)
 402 {
 403 dnl Do *not* indent the following line: there may be CPP directives.
 404 dnl Don't move the `;' right after for the same reason.
 405 $2
 406   ;
 407   return 0;
 408 }
 409 ])
 410
 411 dnl #
 412 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 413 dnl #
 414 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 415         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 416         rm -Rf build && mkdir -p build
 417         echo "obj-m := conftest.o" >build/Makefile
 418         AS_IF(
 419                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 420                 [$4],
 421                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 422         )
 423         rm -Rf build
 424 ])
 425
 426 dnl #
 427 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 428 dnl #
 429 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 430         [ZFS_LINUX_COMPILE_IFELSE(
 431         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 432         [modules],
 433         [test -s build/conftest.o],
 434         [$3], [$4])
 435 ])
 436
 437 dnl #
 438 dnl # ZFS_LINUX_CONFIG
 439 dnl #
 440 AC_DEFUN([ZFS_LINUX_CONFIG],
 441         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 442         ZFS_LINUX_TRY_COMPILE([
 443                 #include <linux/module.h>
 444         ],[
 445                 #ifndef CONFIG_$1
 446                 #error CONFIG_$1 not #defined
 447                 #endif
 448         ],[
 449                 AC_MSG_RESULT([yes])
 450                 $2
 451         ],[
 452                 AC_MSG_RESULT([no])
 453                 $3
 454         ])
 455 ])
 456
 457 dnl #
 458 dnl # ZFS_CHECK_SYMBOL_EXPORT
 459 dnl # check symbol exported or not
 460 dnl #
 461 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT],
 462         [AC_MSG_CHECKING([whether symbol $1 is exported])
 463         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 464                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 465         rc=$?
 466         AS_IF([test $rc -ne 0], [
 467                 export=0
 468                 for file in $2; do
 469                         grep -q -E "EXPORT_SYMBOL.*($1)" "$LINUX/$file" 2>/dev/null
 470                         rc=$?
 471                         AS_IF([test $rc -eq 0], [
 472                                 export=1
 473                                 break;
 474                         ])
 475                 done
 476                 AS_IF([test $export -eq 0], [
 477                         AC_MSG_RESULT([no])
 478                         $4
 479                 ], [
 480                         AC_MSG_RESULT([yes])
 481                         $3
 482                 ])
 483         ], [
 484                 AC_MSG_RESULT([yes])
 485                 $3
 486         ])
 487 ])