config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  18         ZFS_AC_KERNEL_BIO_FAILFAST
  19         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  20         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  21         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  22         ZFS_AC_KERNEL_BIO_RW_SYNC
  23         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  24         ZFS_AC_KERNEL_REQ_SYNC
  25         ZFS_AC_KERNEL_BLK_END_REQUEST
  26         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  27         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  29         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  30         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  31         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  32         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  33         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  34         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  35         ZFS_AC_KERNEL_BLK_RQ_BYTES
  36         ZFS_AC_KERNEL_BLK_RQ_POS
  37         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_RQ_IS_SYNC
  41         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  42         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  43         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  44         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  46         ZFS_AC_KERNEL_SHOW_OPTIONS
  47         ZFS_AC_KERNEL_FSYNC
  48         ZFS_AC_KERNEL_EVICT_INODE
  49         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  50         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  51         ZFS_AC_KERNEL_FALLOCATE
  52         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  53         ZFS_AC_KERNEL_TRUNCATE_RANGE
  54         ZFS_AC_KERNEL_CREATE_UMODE_T
  55         ZFS_AC_KERNEL_AUTOMOUNT
  56         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  57         ZFS_AC_KERNEL_COMMIT_METADATA
  58         ZFS_AC_KERNEL_CLEAR_INODE
  59         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  60         ZFS_AC_KERNEL_D_MAKE_ROOT
  61         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  62         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  63         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  64         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  65         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  66         ZFS_AC_KERNEL_MOUNT_NODEV
  67         ZFS_AC_KERNEL_SHRINK
  68         ZFS_AC_KERNEL_BDI
  69         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  70         ZFS_AC_KERNEL_SET_NLINK
  71         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  72         ZFS_AC_KERNEL_5ARG_SGET
  73
  74         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  75                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  76         ])
  77         AC_SUBST(KERNELMAKE_PARAMS)
  78
  79
  80         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  81         dnl # compiler options are added by the kernel build system.
  82         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  83         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  84         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  85
  86         AC_SUBST(KERNELCPPFLAGS)
  87 ])
  88
  89 dnl #
  90 dnl # Detect name used for Module.symvers file in kernel
  91 dnl #
  92 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  93         modpost=$LINUX/scripts/Makefile.modpost
  94         AC_MSG_CHECKING([kernel file name for module symbols])
  95         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
  96                 AS_IF([grep -q Modules.symvers $modpost], [
  97                         LINUX_SYMBOLS=Modules.symvers
  98                 ], [
  99                         LINUX_SYMBOLS=Module.symvers
 100                 ])
 101
 102                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 103                         AC_MSG_ERROR([
 104         *** Please make sure the kernel devel package for your distribution
 105         *** is installed.  If your building with a custom kernel make sure the
 106         *** kernel is configured, built, and the '--with-linux=PATH' configure
 107         *** option refers to the location of the kernel source.])
 108                 ])
 109         ], [
 110                 LINUX_SYMBOLS=NONE
 111         ])
 112         AC_MSG_RESULT($LINUX_SYMBOLS)
 113         AC_SUBST(LINUX_SYMBOLS)
 114 ])
 115
 116 dnl #
 117 dnl # Detect the kernel to be built against
 118 dnl #
 119 AC_DEFUN([ZFS_AC_KERNEL], [
 120         AC_ARG_WITH([linux],
 121                 AS_HELP_STRING([--with-linux=PATH],
 122                 [Path to kernel source]),
 123                 [kernelsrc="$withval"])
 124
 125         AC_ARG_WITH(linux-obj,
 126                 AS_HELP_STRING([--with-linux-obj=PATH],
 127                 [Path to kernel build objects]),
 128                 [kernelbuild="$withval"])
 129
 130         AC_MSG_CHECKING([kernel source directory])
 131         AS_IF([test -z "$kernelsrc"], [
 132                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 133                         headersdir="/lib/modules/$(uname -r)/source"
 134                         sourcelink=$(readlink -f "$headersdir")
 135                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 136                         headersdir="/lib/modules/$(uname -r)/build"
 137                         sourcelink=$(readlink -f "$headersdir")
 138                 ], [
 139                         sourcelink=$(ls -1d /usr/src/kernels/* \
 140                                      /usr/src/linux-* \
 141                                      2>/dev/null | grep -v obj | tail -1)
 142                 ])
 143
 144                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 145                         kernelsrc=`readlink -f ${sourcelink}`
 146                 ], [
 147                         AC_MSG_RESULT([Not found])
 148                         AC_MSG_ERROR([
 149         *** Please make sure the kernel devel package for your distribution
 150         *** is installed then try again.  If that fails you can specify the
 151         *** location of the kernel source with the '--with-linux=PATH' option.])
 152                 ])
 153         ], [
 154                 AS_IF([test "$kernelsrc" = "NONE"], [
 155                         kernsrcver=NONE
 156                 ])
 157         ])
 158
 159         AC_MSG_RESULT([$kernelsrc])
 160         AC_MSG_CHECKING([kernel build directory])
 161         AS_IF([test -z "$kernelbuild"], [
 162                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 163                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 164                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 165                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 166                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 167                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 168                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 169                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 170                 ], [
 171                         kernelbuild=${kernelsrc}
 172                 ])
 173         ])
 174         AC_MSG_RESULT([$kernelbuild])
 175
 176         AC_MSG_CHECKING([kernel source version])
 177         utsrelease1=$kernelbuild/include/linux/version.h
 178         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 179         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 180         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 181                 utsrelease=linux/version.h
 182         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 183                 utsrelease=linux/utsrelease.h
 184         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 185                 utsrelease=generated/utsrelease.h
 186         ])
 187
 188         AS_IF([test "$utsrelease"], [
 189                 kernsrcver=`(echo "#include <$utsrelease>";
 190                              echo "kernsrcver=UTS_RELEASE") |
 191                              cpp -I $kernelbuild/include |
 192                              grep "^kernsrcver=" | cut -d \" -f 2`
 193
 194                 AS_IF([test -z "$kernsrcver"], [
 195                         AC_MSG_RESULT([Not found])
 196                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 197                 ])
 198         ], [
 199                 AC_MSG_RESULT([Not found])
 200                 if test "x$enable_linux_builtin" != xyes; then
 201                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 202                 else
 203                         AC_MSG_ERROR([
 204         *** Cannot find UTS_RELEASE definition.
 205         *** Please run 'make prepare' inside the kernel source tree.])
 206                 fi
 207         ])
 208
 209         AC_MSG_RESULT([$kernsrcver])
 210
 211         LINUX=${kernelsrc}
 212         LINUX_OBJ=${kernelbuild}
 213         LINUX_VERSION=${kernsrcver}
 214
 215         AC_SUBST(LINUX)
 216         AC_SUBST(LINUX_OBJ)
 217         AC_SUBST(LINUX_VERSION)
 218
 219         ZFS_AC_MODULE_SYMVERS
 220 ])
 221
 222 dnl #
 223 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 224 dnl # does not exist this is likely because the SPL has been configured
 225 dnl # but not built.  The '--with-spl-timeout' option can be passed
 226 dnl # to pause here, waiting for the file to appear from a concurrently
 227 dnl # building SPL package.  If the file does not appear in time, a good
 228 dnl # guess is made as to what this file will be named based on what it
 229 dnl # is named in the kernel build products.  This file will first be
 230 dnl # used at link time so if the guess is wrong the build will fail
 231 dnl # then.  This unfortunately means the ZFS package does not contain a
 232 dnl # reliable mechanism to detect symbols exported by the SPL at
 233 dnl # configure time.
 234 dnl #
 235 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 236         AC_ARG_WITH([spl-timeout],
 237                 AS_HELP_STRING([--with-spl-timeout=SECS],
 238                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 239                 [timeout="$withval"], [timeout=0])
 240
 241         AC_MSG_CHECKING([spl file name for module symbols])
 242         SPL_SYMBOLS=NONE
 243
 244         while true; do
 245                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 246                         SPL_SYMBOLS=Module.symvers
 247                 ], [test -r $SPL_OBJ/Modules.symvers], [
 248                         SPL_SYMBOLS=Modules.symvers
 249                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 250                         SPL_SYMBOLS=Module.symvers
 251                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 252                         SPL_SYMBOLS=Modules.symvers
 253                 ])
 254
 255                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 256                         break;
 257                 ], [
 258                         sleep 1
 259                         timeout=$((timeout-1))
 260                 ])
 261         done
 262
 263         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 264                 SPL_SYMBOLS=$LINUX_SYMBOLS
 265         ])
 266
 267         AC_MSG_RESULT([$SPL_SYMBOLS])
 268         AC_SUBST(SPL_SYMBOLS)
 269 ])
 270
 271 dnl #
 272 dnl # Detect the SPL module to be built against
 273 dnl #
 274 AC_DEFUN([ZFS_AC_SPL], [
 275         AC_ARG_WITH([spl],
 276                 AS_HELP_STRING([--with-spl=PATH],
 277                 [Path to spl source]),
 278                 [splsrc="$withval"])
 279
 280         AC_ARG_WITH([spl-obj],
 281                 AS_HELP_STRING([--with-spl-obj=PATH],
 282                 [Path to spl build objects]),
 283                 [splbuild="$withval"])
 284
 285
 286         AC_MSG_CHECKING([spl source directory])
 287         AS_IF([test -z "$splsrc"], [
 288                 dnl #
 289                 dnl # Look in the standard development package location
 290                 dnl #
 291                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 292                             2>/dev/null | tail -1`
 293
 294                 dnl #
 295                 dnl # Look in the DKMS source location
 296                 dnl #
 297                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 298                         sourcelink=`ls -1d /var/lib/dkms/spl/*/build \
 299                                     2>/dev/null | tail -1`
 300                 ])
 301
 302                 dnl #
 303                 dnl # Look in the parent directory
 304                 dnl #
 305                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 306                         sourcelink=../spl
 307                 ])
 308
 309                 dnl #
 310                 dnl # Look in the kernel directory
 311                 dnl #
 312                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 313                         sourcelink="$LINUX"
 314                 ])
 315
 316                 AS_IF([test -e $sourcelink/spl_config.h], [
 317                         splsrc=`readlink -f ${sourcelink}`
 318                 ], [
 319                         AC_MSG_RESULT([Not found])
 320                         AC_MSG_ERROR([
 321         *** Please make sure the spl devel package for your distribution
 322         *** is installed then try again.  If that fails you can specify the
 323         *** location of the spl source with the '--with-spl=PATH' option.])
 324                 ])
 325         ], [
 326                 AS_IF([test "$splsrc" = "NONE"], [
 327                         splbuild=NONE
 328                         splsrcver=NONE
 329                 ])
 330         ])
 331
 332         AC_MSG_RESULT([$splsrc])
 333         AC_MSG_CHECKING([spl build directory])
 334         AS_IF([test -z "$splbuild"], [
 335                 splbuild=${splsrc}
 336         ])
 337         AC_MSG_RESULT([$splbuild])
 338
 339         AC_MSG_CHECKING([spl source version])
 340         AS_IF([test -r $splbuild/spl_config.h &&
 341                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 342
 343                 splsrcver=`(echo "#include <spl_config.h>";
 344                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 345                             cpp -I $splbuild |
 346                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 347         ])
 348
 349         AS_IF([test -z "$splsrcver"], [
 350                 AC_MSG_RESULT([Not found])
 351                 AC_MSG_ERROR([
 352         *** Cannot determine the version of the spl source.
 353         *** Please prepare the spl source before running this script])
 354         ])
 355
 356         AC_MSG_RESULT([$splsrcver])
 357
 358         SPL=${splsrc}
 359         SPL_OBJ=${splbuild}
 360         SPL_VERSION=${splsrcver}
 361
 362         AC_SUBST(SPL)
 363         AC_SUBST(SPL_OBJ)
 364         AC_SUBST(SPL_VERSION)
 365
 366         ZFS_AC_SPL_MODULE_SYMVERS
 367 ])
 368
 369 dnl #
 370 dnl # Basic toolchain sanity check.
 371 dnl #
 372 AC_DEFUN([ZFS_AC_TEST_MODULE],
 373         [AC_MSG_CHECKING([whether modules can be built])
 374         ZFS_LINUX_TRY_COMPILE([],[],[
 375                 AC_MSG_RESULT([yes])
 376         ],[
 377                 AC_MSG_RESULT([no])
 378                 if test "x$enable_linux_builtin" != xyes; then
 379                         AC_MSG_ERROR([*** Unable to build an empty module.])
 380                 else
 381                         AC_MSG_ERROR([
 382         *** Unable to build an empty module.
 383         *** Please run 'make scripts' inside the kernel source tree.])
 384                 fi
 385         ])
 386 ])
 387
 388 dnl #
 389 dnl # Certain kernel build options are not supported.  These must be
 390 dnl # detected at configure time and cause a build failure.  Otherwise
 391 dnl # modules may be successfully built that behave incorrectly.
 392 dnl #
 393 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 394
 395         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 396                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 397                         [Define to 1 if licensed under the GPL])
 398         ])
 399
 400         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 401 ])
 402
 403 dnl #
 404 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 405 dnl #
 406 dnl # This is typically only set for debug kernels because it comes with
 407 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 408 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 409 dnl # This will cause a failure at link time which we'd rather know about
 410 dnl # at compile time.
 411 dnl #
 412 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 413 dnl # with the upstream community we add a check to detect this case.
 414 dnl #
 415 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 416
 417         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 418                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 419                 tmp_flags="$EXTRA_KCFLAGS"
 420                 ZFS_LINUX_TRY_COMPILE([
 421                         #include <linux/module.h>
 422                         #include <linux/mutex.h>
 423
 424                         MODULE_LICENSE("$ZFS_META_LICENSE");
 425                 ],[
 426                         struct mutex lock;
 427
 428                         mutex_init(&lock);
 429                         mutex_lock(&lock);
 430                         mutex_unlock(&lock);
 431                 ],[
 432                         AC_MSG_RESULT(no)
 433                 ],[
 434                         AC_MSG_RESULT(yes)
 435                         AC_MSG_ERROR([
 436         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 437         *** with the CDDL license and will prevent the module linking stage
 438         *** from succeeding.  You must rebuild your kernel without this
 439         *** option enabled.])
 440                 ])
 441                 EXTRA_KCFLAGS="$tmp_flags"
 442         ], [])
 443 ])
 444
 445 dnl #
 446 dnl # ZFS_LINUX_CONFTEST
 447 dnl #
 448 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 449 cat confdefs.h - <<_ACEOF >conftest.c
 450 $1
 451 _ACEOF
 452 ])
 453
 454 dnl #
 455 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 456 dnl #
 457 m4_define([ZFS_LANG_PROGRAM], [
 458 $1
 459 int
 460 main (void)
 461 {
 462 dnl Do *not* indent the following line: there may be CPP directives.
 463 dnl Don't move the `;' right after for the same reason.
 464 $2
 465   ;
 466   return 0;
 467 }
 468 ])
 469
 470 dnl #
 471 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 472 dnl #
 473 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 474         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 475         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 476         echo "obj-m := conftest.o" >build/Makefile
 477         modpost_flag=''
 478         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 479         AS_IF(
 480                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 481                 [$4],
 482                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 483         )
 484         rm -Rf build
 485 ])
 486
 487 dnl #
 488 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 489 dnl #
 490 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 491         [ZFS_LINUX_COMPILE_IFELSE(
 492         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 493         [modules],
 494         [test -s build/conftest.o],
 495         [$3], [$4])
 496 ])
 497
 498 dnl #
 499 dnl # ZFS_LINUX_CONFIG
 500 dnl #
 501 AC_DEFUN([ZFS_LINUX_CONFIG],
 502         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 503         ZFS_LINUX_TRY_COMPILE([
 504                 #include <linux/module.h>
 505         ],[
 506                 #ifndef CONFIG_$1
 507                 #error CONFIG_$1 not #defined
 508                 #endif
 509         ],[
 510                 AC_MSG_RESULT([yes])
 511                 $2
 512         ],[
 513                 AC_MSG_RESULT([no])
 514                 $3
 515         ])
 516 ])
 517
 518 dnl #
 519 dnl # ZFS_CHECK_SYMBOL_EXPORT
 520 dnl # check symbol exported or not
 521 dnl #
 522 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 523         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 524                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 525         rc=$?
 526         if test $rc -ne 0; then
 527                 export=0
 528                 for file in $2; do
 529                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 530                                 "$LINUX/$file" 2>/dev/null
 531                         rc=$?
 532                         if test $rc -eq 0; then
 533                                 export=1
 534                                 break;
 535                         fi
 536                 done
 537                 if test $export -eq 0; then :
 538                         $4
 539                 else :
 540                         $3
 541                 fi
 542         else :
 543                 $3
 544         fi
 545 ])
 546
 547 dnl #
 548 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 549 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 550 dnl # is called if not compiling for builtin
 551 dnl #
 552 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 553         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 554         if test $rc -ne 0; then :
 555                 $6
 556         else
 557                 if test "x$enable_linux_builtin" != xyes; then
 558                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 559                 fi
 560                 if test $rc -ne 0; then :
 561                         $6
 562                 else :
 563                         $5
 564                 fi
 565         fi
 566 ])