config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_KERNEL_CONFIG
   8         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
   9         ZFS_AC_KERNEL_TYPE_FMODE_T
  10         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  11         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  12         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  13         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  14         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  15         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  16         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  17         ZFS_AC_KERNEL_BIO_FAILFAST
  18         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  19         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  20         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  21         ZFS_AC_KERNEL_BIO_RW_SYNC
  22         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  23         ZFS_AC_KERNEL_REQ_SYNC
  24         ZFS_AC_KERNEL_BLK_END_REQUEST
  25         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  26         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  27         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  28         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  29         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  30         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  31         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  32         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  33         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  34         ZFS_AC_KERNEL_BLK_RQ_BYTES
  35         ZFS_AC_KERNEL_BLK_RQ_POS
  36         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  37         ZFS_AC_KERNEL_GET_DISK_RO
  38         ZFS_AC_KERNEL_GET_GENDISK
  39         ZFS_AC_KERNEL_RQ_IS_SYNC
  40         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  41         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  42         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  43         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  44         ZFS_AC_KERNEL_SHOW_OPTIONS
  45         ZFS_AC_KERNEL_FSYNC
  46         ZFS_AC_KERNEL_EVICT_INODE
  47         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  48         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  49         ZFS_AC_KERNEL_FALLOCATE
  50         ZFS_AC_KERNEL_TRUNCATE_RANGE
  51         ZFS_AC_KERNEL_CREATE_UMODE_T
  52         ZFS_AC_KERNEL_AUTOMOUNT
  53         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  54         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  55         ZFS_AC_KERNEL_D_MAKE_ROOT
  56         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  57         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  58         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  59         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  60         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  61         ZFS_AC_KERNEL_MOUNT_NODEV
  62         ZFS_AC_KERNEL_SHRINK
  63         ZFS_AC_KERNEL_BDI
  64         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  65         ZFS_AC_KERNEL_SET_NLINK
  66
  67         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  68                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  69         ])
  70         AC_SUBST(KERNELMAKE_PARAMS)
  71
  72
  73         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  74         dnl # compiler options are added by the kernel build system.
  75         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  76         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  77         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  78
  79         AC_SUBST(KERNELCPPFLAGS)
  80 ])
  81
  82 dnl #
  83 dnl # Detect name used for Module.symvers file in kernel
  84 dnl #
  85 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  86         modpost=$LINUX/scripts/Makefile.modpost
  87         AC_MSG_CHECKING([kernel file name for module symbols])
  88         AS_IF([test -f "$modpost"], [
  89                 AS_IF([grep -q Modules.symvers $modpost], [
  90                         LINUX_SYMBOLS=Modules.symvers
  91                 ], [
  92                         LINUX_SYMBOLS=Module.symvers
  93                 ])
  94
  95                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
  96                         AC_MSG_ERROR([
  97         *** Please make sure the kernel devel package for your distribution
  98         *** is installed.  If your building with a custom kernel make sure the
  99         *** kernel is configured, built, and the '--with-linux=PATH' configure
 100         *** option refers to the location of the kernel source.])
 101                 ])
 102         ], [
 103                 LINUX_SYMBOLS=NONE
 104         ])
 105         AC_MSG_RESULT($LINUX_SYMBOLS)
 106         AC_SUBST(LINUX_SYMBOLS)
 107 ])
 108
 109 dnl #
 110 dnl # Detect the kernel to be built against
 111 dnl #
 112 AC_DEFUN([ZFS_AC_KERNEL], [
 113         AC_ARG_WITH([linux],
 114                 AS_HELP_STRING([--with-linux=PATH],
 115                 [Path to kernel source]),
 116                 [kernelsrc="$withval"])
 117
 118         AC_ARG_WITH(linux-obj,
 119                 AS_HELP_STRING([--with-linux-obj=PATH],
 120                 [Path to kernel build objects]),
 121                 [kernelbuild="$withval"])
 122
 123         AC_MSG_CHECKING([kernel source directory])
 124         AS_IF([test -z "$kernelsrc"], [
 125                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 126                         headersdir="/lib/modules/$(uname -r)/source"
 127                         sourcelink=$(readlink -f "$headersdir")
 128                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 129                         headersdir="/lib/modules/$(uname -r)/build"
 130                         sourcelink=$(readlink -f "$headersdir")
 131                 ], [
 132                         sourcelink=$(ls -1d /usr/src/kernels/* \
 133                                      /usr/src/linux-* \
 134                                      2>/dev/null | grep -v obj | tail -1)
 135                 ])
 136
 137                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 138                         kernelsrc=`readlink -f ${sourcelink}`
 139                 ], [
 140                         AC_MSG_RESULT([Not found])
 141                         AC_MSG_ERROR([
 142         *** Please make sure the kernel devel package for your distribution
 143         *** is installed then try again.  If that fails you can specify the
 144         *** location of the kernel source with the '--with-linux=PATH' option.])
 145                 ])
 146         ], [
 147                 AS_IF([test "$kernelsrc" = "NONE"], [
 148                         kernsrcver=NONE
 149                 ])
 150         ])
 151
 152         AC_MSG_RESULT([$kernelsrc])
 153         AC_MSG_CHECKING([kernel build directory])
 154         AS_IF([test -z "$kernelbuild"], [
 155                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 156                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 157                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 158                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 159                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 160                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 161                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 162                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 163                 ], [
 164                         kernelbuild=${kernelsrc}
 165                 ])
 166         ])
 167         AC_MSG_RESULT([$kernelbuild])
 168
 169         AC_MSG_CHECKING([kernel source version])
 170         utsrelease1=$kernelbuild/include/linux/version.h
 171         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 172         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 173         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 174                 utsrelease=linux/version.h
 175         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 176                 utsrelease=linux/utsrelease.h
 177         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 178                 utsrelease=generated/utsrelease.h
 179         ])
 180
 181         AS_IF([test "$utsrelease"], [
 182                 kernsrcver=`(echo "#include <$utsrelease>";
 183                              echo "kernsrcver=UTS_RELEASE") |
 184                              cpp -I $kernelbuild/include |
 185                              grep "^kernsrcver=" | cut -d \" -f 2`
 186
 187                 AS_IF([test -z "$kernsrcver"], [
 188                         AC_MSG_RESULT([Not found])
 189                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 190                 ])
 191         ], [
 192                 AC_MSG_RESULT([Not found])
 193                 AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 194         ])
 195
 196         AC_MSG_RESULT([$kernsrcver])
 197
 198         LINUX=${kernelsrc}
 199         LINUX_OBJ=${kernelbuild}
 200         LINUX_VERSION=${kernsrcver}
 201
 202         AC_SUBST(LINUX)
 203         AC_SUBST(LINUX_OBJ)
 204         AC_SUBST(LINUX_VERSION)
 205
 206         ZFS_AC_MODULE_SYMVERS
 207 ])
 208
 209 dnl #
 210 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 211 dnl # does not exist this is likely because the SPL has been configured
 212 dnl # but not built.  To allow recursive builds a good guess is made as to
 213 dnl # what this file will be named based on what it is named in the kernel
 214 dnl # build products.  This file will first be used at link time so if
 215 dnl # the guess is wrong the build will fail then.  This unfortunately
 216 dnl # means the ZFS package does not contain a reliable mechanism to
 217 dnl # detect symbols exported by the SPL at configure time.
 218 dnl #
 219 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 220         AC_MSG_CHECKING([spl file name for module symbols])
 221         AS_IF([test -r $SPL_OBJ/Module.symvers], [
 222                 SPL_SYMBOLS=Module.symvers
 223         ], [test -r $SPL_OBJ/Modules.symvers], [
 224                 SPL_SYMBOLS=Modules.symvers
 225         ], [test -r $SPL_OBJ/module/Module.symvers], [
 226                 SPL_SYMBOLS=Module.symvers
 227         ], [test -r $SPL_OBJ/module/Modules.symvers], [
 228                 SPL_SYMBOLS=Modules.symvers
 229         ], [
 230                 SPL_SYMBOLS=$LINUX_SYMBOLS
 231         ])
 232
 233         AC_MSG_RESULT([$SPL_SYMBOLS])
 234         AC_SUBST(SPL_SYMBOLS)
 235 ])
 236
 237 dnl #
 238 dnl # Detect the SPL module to be built against
 239 dnl #
 240 AC_DEFUN([ZFS_AC_SPL], [
 241         AC_ARG_WITH([spl],
 242                 AS_HELP_STRING([--with-spl=PATH],
 243                 [Path to spl source]),
 244                 [splsrc="$withval"])
 245
 246         AC_ARG_WITH([spl-obj],
 247                 AS_HELP_STRING([--with-spl-obj=PATH],
 248                 [Path to spl build objects]),
 249                 [splbuild="$withval"])
 250
 251
 252         AC_MSG_CHECKING([spl source directory])
 253         AS_IF([test -z "$splsrc"], [
 254                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 255                             2>/dev/null | tail -1`
 256
 257                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink], [
 258                         sourcelink=../spl
 259                 ])
 260
 261                 AS_IF([test -e $sourcelink], [
 262                         splsrc=`readlink -f ${sourcelink}`
 263                 ], [
 264                         AC_MSG_RESULT([Not found])
 265                         AC_MSG_ERROR([
 266         *** Please make sure the spl devel package for your distribution
 267         *** is installed then try again.  If that fails you can specify the
 268         *** location of the spl source with the '--with-spl=PATH' option.])
 269                 ])
 270         ], [
 271                 AS_IF([test "$splsrc" = "NONE"], [
 272                         splbuild=NONE
 273                         splsrcver=NONE
 274                 ])
 275         ])
 276
 277         AC_MSG_RESULT([$splsrc])
 278         AC_MSG_CHECKING([spl build directory])
 279         AS_IF([test -z "$splbuild"], [
 280                 splbuild=${splsrc}
 281         ])
 282         AC_MSG_RESULT([$splbuild])
 283
 284         AC_MSG_CHECKING([spl source version])
 285         AS_IF([test -r $splbuild/spl_config.h &&
 286                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 287
 288                 splsrcver=`(echo "#include <spl_config.h>";
 289                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 290                             cpp -I $splbuild |
 291                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 292         ])
 293
 294         AS_IF([test -z "$splsrcver"], [
 295                 AC_MSG_RESULT([Not found])
 296                 AC_MSG_ERROR([
 297         *** Cannot determine the version of the spl source.
 298         *** Please prepare the spl source before running this script])
 299         ])
 300
 301         AC_MSG_RESULT([$splsrcver])
 302
 303         SPL=${splsrc}
 304         SPL_OBJ=${splbuild}
 305         SPL_VERSION=${splsrcver}
 306
 307         AC_SUBST(SPL)
 308         AC_SUBST(SPL_OBJ)
 309         AC_SUBST(SPL_VERSION)
 310
 311         ZFS_AC_SPL_MODULE_SYMVERS
 312 ])
 313
 314 dnl #
 315 dnl # Certain kernel build options are not supported.  These must be
 316 dnl # detected at configure time and cause a build failure.  Otherwise
 317 dnl # modules may be successfully built that behave incorrectly.
 318 dnl #
 319 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 320
 321         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 322                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 323                         [Define to 1 if licensed under the GPL])
 324         ])
 325
 326         ZFS_AC_KERNEL_CONFIG_PREEMPT
 327         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 328 ])
 329
 330 dnl #
 331 dnl # Check CONFIG_PREEMPT
 332 dnl #
 333 dnl # Premptible kernels will be supported in the future.  But at the
 334 dnl # moment there are a few places in the code which need to be updated
 335 dnl # to accomidate them.  Until that work occurs we should detect this
 336 dnl # at configure time and fail with a sensible message.  Otherwise,
 337 dnl # people will be able to build successfully, however they will have
 338 dnl # stability problems.  See https://github.com/zfsonlinux/zfs/issues/83
 339 dnl #
 340 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_PREEMPT], [
 341
 342         ZFS_LINUX_CONFIG([PREEMPT],
 343                 AC_MSG_ERROR([
 344         *** Kernel built with CONFIG_PREEMPT which is not supported.
 345         *** You must rebuild your kernel without this option.]), [])
 346 ])
 347
 348 dnl #
 349 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 350 dnl #
 351 dnl # This is typically only set for debug kernels because it comes with
 352 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 353 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 354 dnl # This will cause a failure at link time which we'd rather know about
 355 dnl # at compile time.
 356 dnl #
 357 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 358 dnl # with the upstream community we add a check to detect this case.
 359 dnl #
 360 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 361
 362         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 363                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 364                 tmp_flags="$EXTRA_KCFLAGS"
 365                 ZFS_LINUX_TRY_COMPILE([
 366                         #include <linux/module.h>
 367                         #include <linux/mutex.h>
 368
 369                         MODULE_LICENSE("$ZFS_META_LICENSE");
 370                 ],[
 371                         struct mutex lock;
 372
 373                         mutex_init(&lock);
 374                         mutex_lock(&lock);
 375                         mutex_unlock(&lock);
 376                 ],[
 377                         AC_MSG_RESULT(no)
 378                 ],[
 379                         AC_MSG_RESULT(yes)
 380                         AC_MSG_ERROR([
 381         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 382         *** with the CDDL license and will prevent the module linking stage
 383         *** from succeeding.  You must rebuild your kernel without this
 384         *** option enabled.])
 385                 ])
 386                 EXTRA_KCFLAGS="$tmp_flags"
 387         ], [])
 388 ])
 389
 390 dnl #
 391 dnl # ZFS_LINUX_CONFTEST
 392 dnl #
 393 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 394 cat confdefs.h - <<_ACEOF >conftest.c
 395 $1
 396 _ACEOF
 397 ])
 398
 399 dnl #
 400 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 401 dnl #
 402 m4_define([ZFS_LANG_PROGRAM], [
 403 $1
 404 int
 405 main (void)
 406 {
 407 dnl Do *not* indent the following line: there may be CPP directives.
 408 dnl Don't move the `;' right after for the same reason.
 409 $2
 410   ;
 411   return 0;
 412 }
 413 ])
 414
 415 dnl #
 416 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 417 dnl #
 418 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 419         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 420         rm -Rf build && mkdir -p build
 421         echo "obj-m := conftest.o" >build/Makefile
 422         AS_IF(
 423                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 424                 [$4],
 425                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 426         )
 427         rm -Rf build
 428 ])
 429
 430 dnl #
 431 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 432 dnl #
 433 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 434         [ZFS_LINUX_COMPILE_IFELSE(
 435         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 436         [modules],
 437         [test -s build/conftest.o],
 438         [$3], [$4])
 439 ])
 440
 441 dnl #
 442 dnl # ZFS_LINUX_CONFIG
 443 dnl #
 444 AC_DEFUN([ZFS_LINUX_CONFIG],
 445         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 446         ZFS_LINUX_TRY_COMPILE([
 447                 #include <linux/module.h>
 448         ],[
 449                 #ifndef CONFIG_$1
 450                 #error CONFIG_$1 not #defined
 451                 #endif
 452         ],[
 453                 AC_MSG_RESULT([yes])
 454                 $2
 455         ],[
 456                 AC_MSG_RESULT([no])
 457                 $3
 458         ])
 459 ])
 460
 461 dnl #
 462 dnl # ZFS_CHECK_SYMBOL_EXPORT
 463 dnl # check symbol exported or not
 464 dnl #
 465 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT],
 466         [AC_MSG_CHECKING([whether symbol $1 is exported])
 467         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 468                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 469         rc=$?
 470         AS_IF([test $rc -ne 0], [
 471                 export=0
 472                 for file in $2; do
 473                         grep -q -E "EXPORT_SYMBOL.*($1)" "$LINUX/$file" 2>/dev/null
 474                         rc=$?
 475                         AS_IF([test $rc -eq 0], [
 476                                 export=1
 477                                 break;
 478                         ])
 479                 done
 480                 AS_IF([test $export -eq 0], [
 481                         AC_MSG_RESULT([no])
 482                         $4
 483                 ], [
 484                         AC_MSG_RESULT([yes])
 485                         $3
 486                 ])
 487         ], [
 488                 AC_MSG_RESULT([yes])
 489                 $3
 490         ])
 491 ])