config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  18         ZFS_AC_KERNEL_BIO_FAILFAST
  19         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  20         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  21         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  22         ZFS_AC_KERNEL_BIO_RW_SYNC
  23         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  24         ZFS_AC_KERNEL_REQ_SYNC
  25         ZFS_AC_KERNEL_BLK_END_REQUEST
  26         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  27         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  29         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  30         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  31         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  32         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  33         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  34         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  35         ZFS_AC_KERNEL_BLK_RQ_BYTES
  36         ZFS_AC_KERNEL_BLK_RQ_POS
  37         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_RQ_IS_SYNC
  41         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  42         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  43         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  44         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  46         ZFS_AC_KERNEL_SHOW_OPTIONS
  47         ZFS_AC_KERNEL_FSYNC
  48         ZFS_AC_KERNEL_EVICT_INODE
  49         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  50         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  51         ZFS_AC_KERNEL_FALLOCATE
  52         ZFS_AC_KERNEL_TRUNCATE_RANGE
  53         ZFS_AC_KERNEL_CREATE_UMODE_T
  54         ZFS_AC_KERNEL_AUTOMOUNT
  55         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  56         ZFS_AC_KERNEL_CLEAR_INODE
  57         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  58         ZFS_AC_KERNEL_D_MAKE_ROOT
  59         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  60         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  61         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  62         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  63         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  64         ZFS_AC_KERNEL_MOUNT_NODEV
  65         ZFS_AC_KERNEL_SHRINK
  66         ZFS_AC_KERNEL_BDI
  67         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  68         ZFS_AC_KERNEL_SET_NLINK
  69
  70         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  71                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  72         ])
  73         AC_SUBST(KERNELMAKE_PARAMS)
  74
  75
  76         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  77         dnl # compiler options are added by the kernel build system.
  78         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  79         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  80         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  81
  82         AC_SUBST(KERNELCPPFLAGS)
  83 ])
  84
  85 dnl #
  86 dnl # Detect name used for Module.symvers file in kernel
  87 dnl #
  88 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  89         modpost=$LINUX/scripts/Makefile.modpost
  90         AC_MSG_CHECKING([kernel file name for module symbols])
  91         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
  92                 AS_IF([grep -q Modules.symvers $modpost], [
  93                         LINUX_SYMBOLS=Modules.symvers
  94                 ], [
  95                         LINUX_SYMBOLS=Module.symvers
  96                 ])
  97
  98                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
  99                         AC_MSG_ERROR([
 100         *** Please make sure the kernel devel package for your distribution
 101         *** is installed.  If your building with a custom kernel make sure the
 102         *** kernel is configured, built, and the '--with-linux=PATH' configure
 103         *** option refers to the location of the kernel source.])
 104                 ])
 105         ], [
 106                 LINUX_SYMBOLS=NONE
 107         ])
 108         AC_MSG_RESULT($LINUX_SYMBOLS)
 109         AC_SUBST(LINUX_SYMBOLS)
 110 ])
 111
 112 dnl #
 113 dnl # Detect the kernel to be built against
 114 dnl #
 115 AC_DEFUN([ZFS_AC_KERNEL], [
 116         AC_ARG_WITH([linux],
 117                 AS_HELP_STRING([--with-linux=PATH],
 118                 [Path to kernel source]),
 119                 [kernelsrc="$withval"])
 120
 121         AC_ARG_WITH(linux-obj,
 122                 AS_HELP_STRING([--with-linux-obj=PATH],
 123                 [Path to kernel build objects]),
 124                 [kernelbuild="$withval"])
 125
 126         AC_MSG_CHECKING([kernel source directory])
 127         AS_IF([test -z "$kernelsrc"], [
 128                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 129                         headersdir="/lib/modules/$(uname -r)/source"
 130                         sourcelink=$(readlink -f "$headersdir")
 131                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 132                         headersdir="/lib/modules/$(uname -r)/build"
 133                         sourcelink=$(readlink -f "$headersdir")
 134                 ], [
 135                         sourcelink=$(ls -1d /usr/src/kernels/* \
 136                                      /usr/src/linux-* \
 137                                      2>/dev/null | grep -v obj | tail -1)
 138                 ])
 139
 140                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 141                         kernelsrc=`readlink -f ${sourcelink}`
 142                 ], [
 143                         AC_MSG_RESULT([Not found])
 144                         AC_MSG_ERROR([
 145         *** Please make sure the kernel devel package for your distribution
 146         *** is installed then try again.  If that fails you can specify the
 147         *** location of the kernel source with the '--with-linux=PATH' option.])
 148                 ])
 149         ], [
 150                 AS_IF([test "$kernelsrc" = "NONE"], [
 151                         kernsrcver=NONE
 152                 ])
 153         ])
 154
 155         AC_MSG_RESULT([$kernelsrc])
 156         AC_MSG_CHECKING([kernel build directory])
 157         AS_IF([test -z "$kernelbuild"], [
 158                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 159                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 160                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 161                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 162                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 163                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 164                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 165                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 166                 ], [
 167                         kernelbuild=${kernelsrc}
 168                 ])
 169         ])
 170         AC_MSG_RESULT([$kernelbuild])
 171
 172         AC_MSG_CHECKING([kernel source version])
 173         utsrelease1=$kernelbuild/include/linux/version.h
 174         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 175         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 176         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 177                 utsrelease=linux/version.h
 178         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 179                 utsrelease=linux/utsrelease.h
 180         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 181                 utsrelease=generated/utsrelease.h
 182         ])
 183
 184         AS_IF([test "$utsrelease"], [
 185                 kernsrcver=`(echo "#include <$utsrelease>";
 186                              echo "kernsrcver=UTS_RELEASE") |
 187                              cpp -I $kernelbuild/include |
 188                              grep "^kernsrcver=" | cut -d \" -f 2`
 189
 190                 AS_IF([test -z "$kernsrcver"], [
 191                         AC_MSG_RESULT([Not found])
 192                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 193                 ])
 194         ], [
 195                 AC_MSG_RESULT([Not found])
 196                 if test "x$enable_linux_builtin" != xyes; then
 197                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 198                 else
 199                         AC_MSG_ERROR([
 200         *** Cannot find UTS_RELEASE definition.
 201         *** Please run 'make prepare' inside the kernel source tree.])
 202                 fi
 203         ])
 204
 205         AC_MSG_RESULT([$kernsrcver])
 206
 207         LINUX=${kernelsrc}
 208         LINUX_OBJ=${kernelbuild}
 209         LINUX_VERSION=${kernsrcver}
 210
 211         AC_SUBST(LINUX)
 212         AC_SUBST(LINUX_OBJ)
 213         AC_SUBST(LINUX_VERSION)
 214
 215         ZFS_AC_MODULE_SYMVERS
 216 ])
 217
 218 dnl #
 219 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 220 dnl # does not exist this is likely because the SPL has been configured
 221 dnl # but not built.  To allow recursive builds a good guess is made as to
 222 dnl # what this file will be named based on what it is named in the kernel
 223 dnl # build products.  This file will first be used at link time so if
 224 dnl # the guess is wrong the build will fail then.  This unfortunately
 225 dnl # means the ZFS package does not contain a reliable mechanism to
 226 dnl # detect symbols exported by the SPL at configure time.
 227 dnl #
 228 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 229         AC_MSG_CHECKING([spl file name for module symbols])
 230         AS_IF([test -r $SPL_OBJ/Module.symvers], [
 231                 SPL_SYMBOLS=Module.symvers
 232         ], [test -r $SPL_OBJ/Modules.symvers], [
 233                 SPL_SYMBOLS=Modules.symvers
 234         ], [test -r $SPL_OBJ/module/Module.symvers], [
 235                 SPL_SYMBOLS=Module.symvers
 236         ], [test -r $SPL_OBJ/module/Modules.symvers], [
 237                 SPL_SYMBOLS=Modules.symvers
 238         ], [
 239                 SPL_SYMBOLS=$LINUX_SYMBOLS
 240         ])
 241
 242         AC_MSG_RESULT([$SPL_SYMBOLS])
 243         AC_SUBST(SPL_SYMBOLS)
 244 ])
 245
 246 dnl #
 247 dnl # Detect the SPL module to be built against
 248 dnl #
 249 AC_DEFUN([ZFS_AC_SPL], [
 250         AC_ARG_WITH([spl],
 251                 AS_HELP_STRING([--with-spl=PATH],
 252                 [Path to spl source]),
 253                 [splsrc="$withval"])
 254
 255         AC_ARG_WITH([spl-obj],
 256                 AS_HELP_STRING([--with-spl-obj=PATH],
 257                 [Path to spl build objects]),
 258                 [splbuild="$withval"])
 259
 260
 261         AC_MSG_CHECKING([spl source directory])
 262         AS_IF([test -z "$splsrc"], [
 263                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 264                             2>/dev/null | tail -1`
 265
 266                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink], [
 267                         sourcelink=../spl
 268                 ])
 269
 270                 AS_IF([test -e $sourcelink], [
 271                         splsrc=`readlink -f ${sourcelink}`
 272                 ], [
 273                         AC_MSG_RESULT([Not found])
 274                         AC_MSG_ERROR([
 275         *** Please make sure the spl devel package for your distribution
 276         *** is installed then try again.  If that fails you can specify the
 277         *** location of the spl source with the '--with-spl=PATH' option.])
 278                 ])
 279         ], [
 280                 AS_IF([test "$splsrc" = "NONE"], [
 281                         splbuild=NONE
 282                         splsrcver=NONE
 283                 ])
 284         ])
 285
 286         AC_MSG_RESULT([$splsrc])
 287         AC_MSG_CHECKING([spl build directory])
 288         AS_IF([test -z "$splbuild"], [
 289                 splbuild=${splsrc}
 290         ])
 291         AC_MSG_RESULT([$splbuild])
 292
 293         AC_MSG_CHECKING([spl source version])
 294         AS_IF([test -r $splbuild/spl_config.h &&
 295                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 296
 297                 splsrcver=`(echo "#include <spl_config.h>";
 298                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 299                             cpp -I $splbuild |
 300                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 301         ])
 302
 303         AS_IF([test -z "$splsrcver"], [
 304                 AC_MSG_RESULT([Not found])
 305                 AC_MSG_ERROR([
 306         *** Cannot determine the version of the spl source.
 307         *** Please prepare the spl source before running this script])
 308         ])
 309
 310         AC_MSG_RESULT([$splsrcver])
 311
 312         SPL=${splsrc}
 313         SPL_OBJ=${splbuild}
 314         SPL_VERSION=${splsrcver}
 315
 316         AC_SUBST(SPL)
 317         AC_SUBST(SPL_OBJ)
 318         AC_SUBST(SPL_VERSION)
 319
 320         ZFS_AC_SPL_MODULE_SYMVERS
 321 ])
 322
 323 dnl #
 324 dnl # Basic toolchain sanity check.
 325 dnl #
 326 AC_DEFUN([ZFS_AC_TEST_MODULE],
 327         [AC_MSG_CHECKING([whether modules can be built])
 328         ZFS_LINUX_TRY_COMPILE([],[],[
 329                 AC_MSG_RESULT([yes])
 330         ],[
 331                 AC_MSG_RESULT([no])
 332                 if test "x$enable_linux_builtin" != xyes; then
 333                         AC_MSG_ERROR([*** Unable to build an empty module.])
 334                 else
 335                         AC_MSG_ERROR([
 336         *** Unable to build an empty module.
 337         *** Please run 'make scripts' inside the kernel source tree.])
 338                 fi
 339         ])
 340 ])
 341
 342 dnl #
 343 dnl # Certain kernel build options are not supported.  These must be
 344 dnl # detected at configure time and cause a build failure.  Otherwise
 345 dnl # modules may be successfully built that behave incorrectly.
 346 dnl #
 347 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 348
 349         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 350                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 351                         [Define to 1 if licensed under the GPL])
 352         ])
 353
 354         ZFS_AC_KERNEL_CONFIG_PREEMPT
 355         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 356 ])
 357
 358 dnl #
 359 dnl # Check CONFIG_PREEMPT
 360 dnl #
 361 dnl # Premptible kernels will be supported in the future.  But at the
 362 dnl # moment there are a few places in the code which need to be updated
 363 dnl # to accomidate them.  Until that work occurs we should detect this
 364 dnl # at configure time and fail with a sensible message.  Otherwise,
 365 dnl # people will be able to build successfully, however they will have
 366 dnl # stability problems.  See https://github.com/zfsonlinux/zfs/issues/83
 367 dnl #
 368 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_PREEMPT], [
 369
 370         ZFS_LINUX_CONFIG([PREEMPT],
 371                 AC_MSG_ERROR([
 372         *** Kernel built with CONFIG_PREEMPT which is not supported.
 373         *** You must rebuild your kernel without this option.]), [])
 374 ])
 375
 376 dnl #
 377 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 378 dnl #
 379 dnl # This is typically only set for debug kernels because it comes with
 380 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 381 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 382 dnl # This will cause a failure at link time which we'd rather know about
 383 dnl # at compile time.
 384 dnl #
 385 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 386 dnl # with the upstream community we add a check to detect this case.
 387 dnl #
 388 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 389
 390         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 391                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 392                 tmp_flags="$EXTRA_KCFLAGS"
 393                 ZFS_LINUX_TRY_COMPILE([
 394                         #include <linux/module.h>
 395                         #include <linux/mutex.h>
 396
 397                         MODULE_LICENSE("$ZFS_META_LICENSE");
 398                 ],[
 399                         struct mutex lock;
 400
 401                         mutex_init(&lock);
 402                         mutex_lock(&lock);
 403                         mutex_unlock(&lock);
 404                 ],[
 405                         AC_MSG_RESULT(no)
 406                 ],[
 407                         AC_MSG_RESULT(yes)
 408                         AC_MSG_ERROR([
 409         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 410         *** with the CDDL license and will prevent the module linking stage
 411         *** from succeeding.  You must rebuild your kernel without this
 412         *** option enabled.])
 413                 ])
 414                 EXTRA_KCFLAGS="$tmp_flags"
 415         ], [])
 416 ])
 417
 418 dnl #
 419 dnl # ZFS_LINUX_CONFTEST
 420 dnl #
 421 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 422 cat confdefs.h - <<_ACEOF >conftest.c
 423 $1
 424 _ACEOF
 425 ])
 426
 427 dnl #
 428 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 429 dnl #
 430 m4_define([ZFS_LANG_PROGRAM], [
 431 $1
 432 int
 433 main (void)
 434 {
 435 dnl Do *not* indent the following line: there may be CPP directives.
 436 dnl Don't move the `;' right after for the same reason.
 437 $2
 438   ;
 439   return 0;
 440 }
 441 ])
 442
 443 dnl #
 444 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 445 dnl #
 446 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 447         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 448         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 449         echo "obj-m := conftest.o" >build/Makefile
 450         modpost_flag=''
 451         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 452         AS_IF(
 453                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 454                 [$4],
 455                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 456         )
 457         rm -Rf build
 458 ])
 459
 460 dnl #
 461 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 462 dnl #
 463 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 464         [ZFS_LINUX_COMPILE_IFELSE(
 465         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 466         [modules],
 467         [test -s build/conftest.o],
 468         [$3], [$4])
 469 ])
 470
 471 dnl #
 472 dnl # ZFS_LINUX_CONFIG
 473 dnl #
 474 AC_DEFUN([ZFS_LINUX_CONFIG],
 475         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 476         ZFS_LINUX_TRY_COMPILE([
 477                 #include <linux/module.h>
 478         ],[
 479                 #ifndef CONFIG_$1
 480                 #error CONFIG_$1 not #defined
 481                 #endif
 482         ],[
 483                 AC_MSG_RESULT([yes])
 484                 $2
 485         ],[
 486                 AC_MSG_RESULT([no])
 487                 $3
 488         ])
 489 ])
 490
 491 dnl #
 492 dnl # ZFS_CHECK_SYMBOL_EXPORT
 493 dnl # check symbol exported or not
 494 dnl #
 495 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 496         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 497                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 498         rc=$?
 499         if test $rc -ne 0; then
 500                 export=0
 501                 for file in $2; do
 502                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 503                                 "$LINUX/$file" 2>/dev/null
 504                         rc=$?
 505                         if test $rc -eq 0; then
 506                                 export=1
 507                                 break;
 508                         fi
 509                 done
 510                 if test $export -eq 0; then :
 511                         $4
 512                 else :
 513                         $3
 514                 fi
 515         else :
 516                 $3
 517         fi
 518 ])
 519
 520 dnl #
 521 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 522 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 523 dnl # is called if not compiling for builtin
 524 dnl #
 525 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 526         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 527         if test $rc -ne 0; then :
 528                 $6
 529         else
 530                 if test "x$enable_linux_builtin" != xyes; then
 531                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 532                 fi
 533                 if test $rc -ne 0; then :
 534                         $6
 535                 else :
 536                         $5
 537                 fi
 538         fi
 539 ])