config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  18         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  19         ZFS_AC_KERNEL_BIO_FAILFAST
  20         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  21         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  22         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  23         ZFS_AC_KERNEL_BIO_RW_SYNC
  24         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  25         ZFS_AC_KERNEL_REQ_SYNC
  26         ZFS_AC_KERNEL_BLK_END_REQUEST
  27         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  30         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  31         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  32         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  33         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  34         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  35         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  36         ZFS_AC_KERNEL_BLK_RQ_BYTES
  37         ZFS_AC_KERNEL_BLK_RQ_POS
  38         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  39         ZFS_AC_KERNEL_GET_DISK_RO
  40         ZFS_AC_KERNEL_GET_GENDISK
  41         ZFS_AC_KERNEL_RQ_IS_SYNC
  42         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  43         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  44         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  45         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  46         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  47         ZFS_AC_KERNEL_SHOW_OPTIONS
  48         ZFS_AC_KERNEL_FSYNC
  49         ZFS_AC_KERNEL_EVICT_INODE
  50         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  51         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  52         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  53         ZFS_AC_KERNEL_FALLOCATE
  54         ZFS_AC_KERNEL_MKDIR_UMODE_T
  55         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  56         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  57         ZFS_AC_KERNEL_TRUNCATE_RANGE
  58         ZFS_AC_KERNEL_AUTOMOUNT
  59         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  60         ZFS_AC_KERNEL_COMMIT_METADATA
  61         ZFS_AC_KERNEL_CLEAR_INODE
  62         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  63         ZFS_AC_KERNEL_D_MAKE_ROOT
  64         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  65         ZFS_AC_KERNEL_D_SET_D_OP
  66         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  67         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  68         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  69         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  70         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  71         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  72         ZFS_AC_KERNEL_MOUNT_NODEV
  73         ZFS_AC_KERNEL_SHRINK
  74         ZFS_AC_KERNEL_BDI
  75         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  76         ZFS_AC_KERNEL_SET_NLINK
  77         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  78         ZFS_AC_KERNEL_5ARG_SGET
  79
  80         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  81                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  82         ])
  83         AC_SUBST(KERNELMAKE_PARAMS)
  84
  85
  86         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  87         dnl # compiler options are added by the kernel build system.
  88         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  89         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  90         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  91
  92         AC_SUBST(KERNELCPPFLAGS)
  93 ])
  94
  95 dnl #
  96 dnl # Detect name used for Module.symvers file in kernel
  97 dnl #
  98 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  99         modpost=$LINUX/scripts/Makefile.modpost
 100         AC_MSG_CHECKING([kernel file name for module symbols])
 101         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 102                 AS_IF([grep -q Modules.symvers $modpost], [
 103                         LINUX_SYMBOLS=Modules.symvers
 104                 ], [
 105                         LINUX_SYMBOLS=Module.symvers
 106                 ])
 107
 108                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 109                         AC_MSG_ERROR([
 110         *** Please make sure the kernel devel package for your distribution
 111         *** is installed.  If your building with a custom kernel make sure the
 112         *** kernel is configured, built, and the '--with-linux=PATH' configure
 113         *** option refers to the location of the kernel source.])
 114                 ])
 115         ], [
 116                 LINUX_SYMBOLS=NONE
 117         ])
 118         AC_MSG_RESULT($LINUX_SYMBOLS)
 119         AC_SUBST(LINUX_SYMBOLS)
 120 ])
 121
 122 dnl #
 123 dnl # Detect the kernel to be built against
 124 dnl #
 125 AC_DEFUN([ZFS_AC_KERNEL], [
 126         AC_ARG_WITH([linux],
 127                 AS_HELP_STRING([--with-linux=PATH],
 128                 [Path to kernel source]),
 129                 [kernelsrc="$withval"])
 130
 131         AC_ARG_WITH(linux-obj,
 132                 AS_HELP_STRING([--with-linux-obj=PATH],
 133                 [Path to kernel build objects]),
 134                 [kernelbuild="$withval"])
 135
 136         AC_MSG_CHECKING([kernel source directory])
 137         AS_IF([test -z "$kernelsrc"], [
 138                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 139                         headersdir="/lib/modules/$(uname -r)/source"
 140                         sourcelink=$(readlink -f "$headersdir")
 141                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 142                         headersdir="/lib/modules/$(uname -r)/build"
 143                         sourcelink=$(readlink -f "$headersdir")
 144                 ], [
 145                         sourcelink=$(ls -1d /usr/src/kernels/* \
 146                                      /usr/src/linux-* \
 147                                      2>/dev/null | grep -v obj | tail -1)
 148                 ])
 149
 150                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 151                         kernelsrc=`readlink -f ${sourcelink}`
 152                 ], [
 153                         kernelsrc="[Not found]"
 154                 ])
 155         ], [
 156                 AS_IF([test "$kernelsrc" = "NONE"], [
 157                         kernsrcver=NONE
 158                 ])
 159         ])
 160
 161         AC_MSG_RESULT([$kernelsrc])
 162         AS_IF([test ! -d "$kernelsrc"], [
 163                 AC_MSG_ERROR([
 164         *** Please make sure the kernel devel package for your distribution
 165         *** is installed then try again.  If that fails you can specify the
 166         *** location of the kernel source with the '--with-linux=PATH' option.])
 167         ])
 168
 169         AC_MSG_CHECKING([kernel build directory])
 170         AS_IF([test -z "$kernelbuild"], [
 171                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 172                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 173                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 174                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 175                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 176                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 177                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 178                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 179                 ], [
 180                         kernelbuild=${kernelsrc}
 181                 ])
 182         ])
 183         AC_MSG_RESULT([$kernelbuild])
 184
 185         AC_MSG_CHECKING([kernel source version])
 186         utsrelease1=$kernelbuild/include/linux/version.h
 187         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 188         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 189         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 190                 utsrelease=linux/version.h
 191         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 192                 utsrelease=linux/utsrelease.h
 193         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 194                 utsrelease=generated/utsrelease.h
 195         ])
 196
 197         AS_IF([test "$utsrelease"], [
 198                 kernsrcver=`(echo "#include <$utsrelease>";
 199                              echo "kernsrcver=UTS_RELEASE") |
 200                              cpp -I $kernelbuild/include |
 201                              grep "^kernsrcver=" | cut -d \" -f 2`
 202
 203                 AS_IF([test -z "$kernsrcver"], [
 204                         AC_MSG_RESULT([Not found])
 205                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 206                 ])
 207         ], [
 208                 AC_MSG_RESULT([Not found])
 209                 if test "x$enable_linux_builtin" != xyes; then
 210                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 211                 else
 212                         AC_MSG_ERROR([
 213         *** Cannot find UTS_RELEASE definition.
 214         *** Please run 'make prepare' inside the kernel source tree.])
 215                 fi
 216         ])
 217
 218         AC_MSG_RESULT([$kernsrcver])
 219
 220         LINUX=${kernelsrc}
 221         LINUX_OBJ=${kernelbuild}
 222         LINUX_VERSION=${kernsrcver}
 223
 224         AC_SUBST(LINUX)
 225         AC_SUBST(LINUX_OBJ)
 226         AC_SUBST(LINUX_VERSION)
 227
 228         ZFS_AC_MODULE_SYMVERS
 229 ])
 230
 231 dnl #
 232 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 233 dnl # does not exist this is likely because the SPL has been configured
 234 dnl # but not built.  The '--with-spl-timeout' option can be passed
 235 dnl # to pause here, waiting for the file to appear from a concurrently
 236 dnl # building SPL package.  If the file does not appear in time, a good
 237 dnl # guess is made as to what this file will be named based on what it
 238 dnl # is named in the kernel build products.  This file will first be
 239 dnl # used at link time so if the guess is wrong the build will fail
 240 dnl # then.  This unfortunately means the ZFS package does not contain a
 241 dnl # reliable mechanism to detect symbols exported by the SPL at
 242 dnl # configure time.
 243 dnl #
 244 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 245         AC_ARG_WITH([spl-timeout],
 246                 AS_HELP_STRING([--with-spl-timeout=SECS],
 247                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 248                 [timeout="$withval"], [timeout=0])
 249
 250         AC_MSG_CHECKING([spl file name for module symbols])
 251         SPL_SYMBOLS=NONE
 252
 253         while true; do
 254                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 255                         SPL_SYMBOLS=Module.symvers
 256                 ], [test -r $SPL_OBJ/Modules.symvers], [
 257                         SPL_SYMBOLS=Modules.symvers
 258                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 259                         SPL_SYMBOLS=Module.symvers
 260                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 261                         SPL_SYMBOLS=Modules.symvers
 262                 ])
 263
 264                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 265                         break;
 266                 ], [
 267                         sleep 1
 268                         timeout=$((timeout-1))
 269                 ])
 270         done
 271
 272         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 273                 SPL_SYMBOLS=$LINUX_SYMBOLS
 274         ])
 275
 276         AC_MSG_RESULT([$SPL_SYMBOLS])
 277         AC_SUBST(SPL_SYMBOLS)
 278 ])
 279
 280 dnl #
 281 dnl # Detect the SPL module to be built against
 282 dnl #
 283 AC_DEFUN([ZFS_AC_SPL], [
 284         AC_ARG_WITH([spl],
 285                 AS_HELP_STRING([--with-spl=PATH],
 286                 [Path to spl source]),
 287                 [splsrc="$withval"])
 288
 289         AC_ARG_WITH([spl-obj],
 290                 AS_HELP_STRING([--with-spl-obj=PATH],
 291                 [Path to spl build objects]),
 292                 [splbuild="$withval"])
 293
 294
 295         AC_MSG_CHECKING([spl source directory])
 296         AS_IF([test -z "$splsrc"], [
 297                 dnl #
 298                 dnl # Look in the standard development package location
 299                 dnl #
 300                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 301                             2>/dev/null | tail -1`
 302
 303                 dnl #
 304                 dnl # Look in the DKMS source location
 305                 dnl #
 306                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 307                         sourcelink=`ls -1d /var/lib/dkms/spl/*/build \
 308                                     2>/dev/null | tail -1`
 309                 ])
 310
 311                 dnl #
 312                 dnl # Look in the parent directory
 313                 dnl #
 314                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 315                         sourcelink=../spl
 316                 ])
 317
 318                 dnl #
 319                 dnl # Look in the kernel directory
 320                 dnl #
 321                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 322                         sourcelink="$LINUX"
 323                 ])
 324
 325                 AS_IF([test -e $sourcelink/spl_config.h], [
 326                         splsrc=`readlink -f ${sourcelink}`
 327                 ], [
 328                         AC_MSG_RESULT([Not found])
 329                         AC_MSG_ERROR([
 330         *** Please make sure the spl devel package for your distribution
 331         *** is installed then try again.  If that fails you can specify the
 332         *** location of the spl source with the '--with-spl=PATH' option.])
 333                 ])
 334         ], [
 335                 AS_IF([test "$splsrc" = "NONE"], [
 336                         splbuild=NONE
 337                         splsrcver=NONE
 338                 ])
 339         ])
 340
 341         AC_MSG_RESULT([$splsrc])
 342         AC_MSG_CHECKING([spl build directory])
 343         AS_IF([test -z "$splbuild"], [
 344                 splbuild=${splsrc}
 345         ])
 346         AC_MSG_RESULT([$splbuild])
 347
 348         AC_MSG_CHECKING([spl source version])
 349         AS_IF([test -r $splbuild/spl_config.h &&
 350                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 351
 352                 splsrcver=`(echo "#include <spl_config.h>";
 353                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 354                             cpp -I $splbuild |
 355                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 356         ])
 357
 358         AS_IF([test -z "$splsrcver"], [
 359                 AC_MSG_RESULT([Not found])
 360                 AC_MSG_ERROR([
 361         *** Cannot determine the version of the spl source.
 362         *** Please prepare the spl source before running this script])
 363         ])
 364
 365         AC_MSG_RESULT([$splsrcver])
 366
 367         SPL=${splsrc}
 368         SPL_OBJ=${splbuild}
 369         SPL_VERSION=${splsrcver}
 370
 371         AC_SUBST(SPL)
 372         AC_SUBST(SPL_OBJ)
 373         AC_SUBST(SPL_VERSION)
 374
 375         ZFS_AC_SPL_MODULE_SYMVERS
 376 ])
 377
 378 dnl #
 379 dnl # Basic toolchain sanity check.
 380 dnl #
 381 AC_DEFUN([ZFS_AC_TEST_MODULE],
 382         [AC_MSG_CHECKING([whether modules can be built])
 383         ZFS_LINUX_TRY_COMPILE([],[],[
 384                 AC_MSG_RESULT([yes])
 385         ],[
 386                 AC_MSG_RESULT([no])
 387                 if test "x$enable_linux_builtin" != xyes; then
 388                         AC_MSG_ERROR([*** Unable to build an empty module.])
 389                 else
 390                         AC_MSG_ERROR([
 391         *** Unable to build an empty module.
 392         *** Please run 'make scripts' inside the kernel source tree.])
 393                 fi
 394         ])
 395 ])
 396
 397 dnl #
 398 dnl # Certain kernel build options are not supported.  These must be
 399 dnl # detected at configure time and cause a build failure.  Otherwise
 400 dnl # modules may be successfully built that behave incorrectly.
 401 dnl #
 402 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 403
 404         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 405                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 406                         [Define to 1 if licensed under the GPL])
 407         ])
 408
 409         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 410 ])
 411
 412 dnl #
 413 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 414 dnl #
 415 dnl # This is typically only set for debug kernels because it comes with
 416 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 417 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 418 dnl # This will cause a failure at link time which we'd rather know about
 419 dnl # at compile time.
 420 dnl #
 421 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 422 dnl # with the upstream community we add a check to detect this case.
 423 dnl #
 424 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 425
 426         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 427                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 428                 tmp_flags="$EXTRA_KCFLAGS"
 429                 ZFS_LINUX_TRY_COMPILE([
 430                         #include <linux/module.h>
 431                         #include <linux/mutex.h>
 432
 433                         MODULE_LICENSE("$ZFS_META_LICENSE");
 434                 ],[
 435                         struct mutex lock;
 436
 437                         mutex_init(&lock);
 438                         mutex_lock(&lock);
 439                         mutex_unlock(&lock);
 440                 ],[
 441                         AC_MSG_RESULT(no)
 442                 ],[
 443                         AC_MSG_RESULT(yes)
 444                         AC_MSG_ERROR([
 445         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 446         *** with the CDDL license and will prevent the module linking stage
 447         *** from succeeding.  You must rebuild your kernel without this
 448         *** option enabled.])
 449                 ])
 450                 EXTRA_KCFLAGS="$tmp_flags"
 451         ], [])
 452 ])
 453
 454 dnl #
 455 dnl # ZFS_LINUX_CONFTEST
 456 dnl #
 457 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 458 cat confdefs.h - <<_ACEOF >conftest.c
 459 $1
 460 _ACEOF
 461 ])
 462
 463 dnl #
 464 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 465 dnl #
 466 m4_define([ZFS_LANG_PROGRAM], [
 467 $1
 468 int
 469 main (void)
 470 {
 471 dnl Do *not* indent the following line: there may be CPP directives.
 472 dnl Don't move the `;' right after for the same reason.
 473 $2
 474   ;
 475   return 0;
 476 }
 477 ])
 478
 479 dnl #
 480 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 481 dnl #
 482 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 483         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 484         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 485         echo "obj-m := conftest.o" >build/Makefile
 486         modpost_flag=''
 487         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 488         AS_IF(
 489                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 490                 [$4],
 491                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 492         )
 493         rm -Rf build
 494 ])
 495
 496 dnl #
 497 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 498 dnl #
 499 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 500         [ZFS_LINUX_COMPILE_IFELSE(
 501         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 502         [modules],
 503         [test -s build/conftest.o],
 504         [$3], [$4])
 505 ])
 506
 507 dnl #
 508 dnl # ZFS_LINUX_CONFIG
 509 dnl #
 510 AC_DEFUN([ZFS_LINUX_CONFIG],
 511         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 512         ZFS_LINUX_TRY_COMPILE([
 513                 #include <linux/module.h>
 514         ],[
 515                 #ifndef CONFIG_$1
 516                 #error CONFIG_$1 not #defined
 517                 #endif
 518         ],[
 519                 AC_MSG_RESULT([yes])
 520                 $2
 521         ],[
 522                 AC_MSG_RESULT([no])
 523                 $3
 524         ])
 525 ])
 526
 527 dnl #
 528 dnl # ZFS_CHECK_SYMBOL_EXPORT
 529 dnl # check symbol exported or not
 530 dnl #
 531 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 532         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 533                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 534         rc=$?
 535         if test $rc -ne 0; then
 536                 export=0
 537                 for file in $2; do
 538                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 539                                 "$LINUX/$file" 2>/dev/null
 540                         rc=$?
 541                         if test $rc -eq 0; then
 542                                 export=1
 543                                 break;
 544                         fi
 545                 done
 546                 if test $export -eq 0; then :
 547                         $4
 548                 else :
 549                         $3
 550                 fi
 551         else :
 552                 $3
 553         fi
 554 ])
 555
 556 dnl #
 557 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 558 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 559 dnl # is called if not compiling for builtin
 560 dnl #
 561 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 562         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 563         if test $rc -ne 0; then :
 564                 $6
 565         else
 566                 if test "x$enable_linux_builtin" != xyes; then
 567                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 568                 fi
 569                 if test $rc -ne 0; then :
 570                         $6
 571                 else :
 572                         $5
 573                 fi
 574         fi
 575 ])