config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG], [
  10         AC_MSG_CHECKING([whether debugging is enabled])
  11         AC_ARG_ENABLE([debug],
  12                 [AS_HELP_STRING([--enable-debug],
  13                 [Enable generic debug support @<:@default=no@:>@])],
  14                 [],
  15                 [enable_debug=no])
  16
  17         AS_IF([test "x$enable_debug" = xyes],
  18         [
  19                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
  20                 HOSTCFLAGS="${HOSTCFLAGS} -DDEBUG -Werror"
  21                 DEBUG_CFLAGS="-DDEBUG -Werror"
  22                 DEBUG_STACKFLAGS="-fstack-check"
  23                 DEBUG_ZFS="_with_debug"
  24                 AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  25         ],
  26         [
  27                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG "
  28                 HOSTCFLAGS="${HOSTCFLAGS} -DNDEBUG "
  29                 DEBUG_CFLAGS="-DNDEBUG"
  30                 DEBUG_STACKFLAGS=""
  31                 DEBUG_ZFS="_without_debug"
  32         ])
  33
  34         AC_SUBST(DEBUG_CFLAGS)
  35         AC_SUBST(DEBUG_STACKFLAGS)
  36         AC_SUBST(DEBUG_ZFS)
  37         AC_MSG_RESULT([$enable_debug])
  38 ])
  39
  40 AC_DEFUN([ZFS_AC_DEBUG_DMU_TX], [
  41         AC_ARG_ENABLE([debug-dmu-tx],
  42                 [AS_HELP_STRING([--enable-debug-dmu-tx],
  43                 [Enable dmu tx validation @<:@default=no@:>@])],
  44                 [],
  45                 [enable_debug_dmu_tx=no])
  46
  47         AS_IF([test "x$enable_debug_dmu_tx" = xyes],
  48         [
  49                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_DMU_TX"
  50                 DEBUG_DMU_TX="_with_debug_dmu_tx"
  51                 AC_DEFINE([DEBUG_DMU_TX], [1],
  52                 [Define to 1 to enabled dmu tx validation])
  53         ],
  54         [
  55                 DEBUG_DMU_TX="_without_debug_dmu_tx"
  56         ])
  57
  58         AC_SUBST(DEBUG_DMU_TX)
  59         AC_MSG_CHECKING([whether dmu tx validation is enabled])
  60         AC_MSG_RESULT([$enable_debug_dmu_tx])
  61 ])
  62
  63 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
  64         ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE
  65 ])
  66
  67 AC_DEFUN([ZFS_AC_CONFIG], [
  68         TARGET_ASM_DIR=asm-generic
  69         AC_SUBST(TARGET_ASM_DIR)
  70
  71         ZFS_CONFIG=all
  72         AC_ARG_WITH([config],
  73                 AS_HELP_STRING([--with-config=CONFIG],
  74                 [Config file 'kernel|user|all|srpm']),
  75                 [ZFS_CONFIG="$withval"])
  76
  77         AC_MSG_CHECKING([zfs config])
  78         AC_MSG_RESULT([$ZFS_CONFIG]);
  79         AC_SUBST(ZFS_CONFIG)
  80
  81         ZFS_AC_CONFIG_ALWAYS
  82
  83         case "$ZFS_CONFIG" in
  84                 kernel) ZFS_AC_CONFIG_KERNEL ;;
  85                 user)   ZFS_AC_CONFIG_USER   ;;
  86                 all)    ZFS_AC_CONFIG_KERNEL
  87                         ZFS_AC_CONFIG_USER   ;;
  88                 srpm)                        ;;
  89                 *)
  90                 AC_MSG_RESULT([Error!])
  91                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
  92                               user kernel|user|all|srpm]) ;;
  93         esac
  94
  95         AM_CONDITIONAL([CONFIG_USER],
  96                        [test "$ZFS_CONFIG" = user] ||
  97                        [test "$ZFS_CONFIG" = all])
  98         AM_CONDITIONAL([CONFIG_KERNEL],
  99                        [test "$ZFS_CONFIG" = kernel] ||
 100                        [test "$ZFS_CONFIG" = all])
 101 ])
 102
 103 dnl #
 104 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 105 dnl # are missing it is non-fatal but you will not be able to build
 106 dnl # RPM packages and will be warned if you try too.
 107 dnl #
 108 AC_DEFUN([ZFS_AC_RPM], [
 109         RPM=rpm
 110         RPMBUILD=rpmbuild
 111
 112         AC_MSG_CHECKING([whether $RPM is available])
 113         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 114                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 115                 HAVE_RPM=yes
 116                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 117         ],[
 118                 HAVE_RPM=no
 119                 AC_MSG_RESULT([$HAVE_RPM])
 120         ])
 121
 122         AC_MSG_CHECKING([whether $RPMBUILD is available])
 123         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 124                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 125                 HAVE_RPMBUILD=yes
 126                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 127         ],[
 128                 HAVE_RPMBUILD=no
 129                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 130         ])
 131
 132         AC_SUBST(HAVE_RPM)
 133         AC_SUBST(RPM)
 134         AC_SUBST(RPM_VERSION)
 135
 136         AC_SUBST(HAVE_RPMBUILD)
 137         AC_SUBST(RPMBUILD)
 138         AC_SUBST(RPMBUILD_VERSION)
 139 ])
 140
 141 dnl #
 142 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 143 dnl # tools are missing it is non-fatal but you will not be able to build
 144 dnl # DEB packages and will be warned if you try too.
 145 dnl #
 146 AC_DEFUN([ZFS_AC_DPKG], [
 147         DPKG=dpkg
 148         DPKGBUILD=dpkg-buildpackage
 149
 150         AC_MSG_CHECKING([whether $DPKG is available])
 151         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 152                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 153                 HAVE_DPKG=yes
 154                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 155         ],[
 156                 HAVE_DPKG=no
 157                 AC_MSG_RESULT([$HAVE_DPKG])
 158         ])
 159
 160         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 161         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 162                 DPKGBUILD_VERSION=$(echo $tmp | \
 163                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 164                 HAVE_DPKGBUILD=yes
 165                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 166         ],[
 167                 HAVE_DPKGBUILD=no
 168                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 169         ])
 170
 171         AC_SUBST(HAVE_DPKG)
 172         AC_SUBST(DPKG)
 173         AC_SUBST(DPKG_VERSION)
 174
 175         AC_SUBST(HAVE_DPKGBUILD)
 176         AC_SUBST(DPKGBUILD)
 177         AC_SUBST(DPKGBUILD_VERSION)
 178 ])
 179
 180 dnl #
 181 dnl # Until native packaging for various different packing systems
 182 dnl # can be added the least we can do is attempt to use alien to
 183 dnl # convert the RPM packages to the needed package type.  This is
 184 dnl # a hack but so far it has worked reasonable well.
 185 dnl #
 186 AC_DEFUN([ZFS_AC_ALIEN], [
 187         ALIEN=alien
 188
 189         AC_MSG_CHECKING([whether $ALIEN is available])
 190         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 191                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 192                 HAVE_ALIEN=yes
 193                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 194         ],[
 195                 HAVE_ALIEN=no
 196                 AC_MSG_RESULT([$HAVE_ALIEN])
 197         ])
 198
 199         AC_SUBST(HAVE_ALIEN)
 200         AC_SUBST(ALIEN)
 201         AC_SUBST(ALIEN_VERSION)
 202 ])
 203
 204 dnl #
 205 dnl # Check for pacman+makepkg to build Arch Linux packages.  If these
 206 dnl # tools are missing it is non-fatal but you will not be able to
 207 dnl # build Arch Linux packages and will be warned if you try too.
 208 dnl #
 209 AC_DEFUN([ZFS_AC_PACMAN], [
 210         PACMAN=pacman
 211         MAKEPKG=makepkg
 212
 213         AC_MSG_CHECKING([whether $PACMAN is available])
 214         tmp=$($PACMAN --version 2>/dev/null)
 215         AS_IF([test -n "$tmp"], [
 216                 PACMAN_VERSION=$(echo $tmp |
 217                                  $AWK '/Pacman/ { print $[3] }' |
 218                                  $SED 's/^v//')
 219                 HAVE_PACMAN=yes
 220                 AC_MSG_RESULT([$HAVE_PACMAN ($PACMAN_VERSION)])
 221         ],[
 222                 HAVE_PACMAN=no
 223                 AC_MSG_RESULT([$HAVE_PACMAN])
 224         ])
 225
 226         AC_MSG_CHECKING([whether $MAKEPKG is available])
 227         tmp=$($MAKEPKG --version 2>/dev/null)
 228         AS_IF([test -n "$tmp"], [
 229                 MAKEPKG_VERSION=$(echo $tmp | $AWK '/makepkg/ { print $[3] }')
 230                 HAVE_MAKEPKG=yes
 231                 AC_MSG_RESULT([$HAVE_MAKEPKG ($MAKEPKG_VERSION)])
 232         ],[
 233                 HAVE_MAKEPKG=no
 234                 AC_MSG_RESULT([$HAVE_MAKEPKG])
 235         ])
 236
 237         AC_SUBST(HAVE_PACMAN)
 238         AC_SUBST(PACMAN)
 239         AC_SUBST(PACMAN_VERSION)
 240
 241         AC_SUBST(HAVE_MAKEPKG)
 242         AC_SUBST(MAKEPKG)
 243         AC_SUBST(MAKEPKG_VERSION)
 244 ])
 245
 246 dnl #
 247 dnl # Using the VENDOR tag from config.guess set the default
 248 dnl # package type for 'make pkg': (rpm | deb | tgz)
 249 dnl #
 250 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 251         AC_MSG_CHECKING([linux distribution])
 252         if test -f /etc/toss-release ; then
 253                 VENDOR=toss ;
 254         elif test -f /etc/fedora-release ; then
 255                 VENDOR=fedora ;
 256         elif test -f /etc/redhat-release ; then
 257                 VENDOR=redhat ;
 258         elif test -f /etc/gentoo-release ; then
 259                 VENDOR=gentoo ;
 260         elif test -f /etc/arch-release ; then
 261                 VENDOR=arch ;
 262         elif test -f /etc/SuSE-release ; then
 263                 VENDOR=sles ;
 264         elif test -f /etc/slackware-version ; then
 265                 VENDOR=slackware ;
 266         elif test -f /etc/lunar.release ; then
 267                 VENDOR=lunar ;
 268         elif test -f /etc/lsb-release ; then
 269                 VENDOR=ubuntu ;
 270         elif test -f /etc/debian_version ; then
 271                 VENDOR=debian ;
 272         else
 273                 VENDOR= ;
 274         fi
 275         AC_MSG_RESULT([$VENDOR])
 276         AC_SUBST(VENDOR)
 277
 278         AC_MSG_CHECKING([default package type])
 279         case "$VENDOR" in
 280                 toss)       DEFAULT_PACKAGE=rpm  ;;
 281                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 282                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 283                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 284                 arch)       DEFAULT_PACKAGE=arch ;;
 285                 sles)       DEFAULT_PACKAGE=rpm  ;;
 286                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 287                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 288                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 289                 debian)     DEFAULT_PACKAGE=deb  ;;
 290                 *)          DEFAULT_PACKAGE=rpm  ;;
 291         esac
 292
 293         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 294         AC_SUBST(DEFAULT_PACKAGE)
 295
 296         AC_MSG_CHECKING([default init directory])
 297         case "$VENDOR" in
 298                 arch)       DEFAULT_INIT_DIR=$sysconfdir/rc.d ;;
 299                 *)          DEFAULT_INIT_DIR=$sysconfdir/init.d ;;
 300         esac
 301
 302         AC_MSG_RESULT([$DEFAULT_INIT_DIR])
 303         AC_SUBST(DEFAULT_INIT_DIR)
 304
 305         AC_MSG_CHECKING([default init script type])
 306         case "$VENDOR" in
 307                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 308                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 309                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 310                 gentoo)     DEFAULT_INIT_SCRIPT=gentoo ;;
 311                 arch)       DEFAULT_INIT_SCRIPT=arch   ;;
 312                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 313                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 314                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 315                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 316                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 317                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 318         esac
 319
 320         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
 321         AC_SUBST(DEFAULT_INIT_SCRIPT)
 322 ])
 323
 324 dnl #
 325 dnl # Default ZFS package configuration
 326 dnl #
 327 AC_DEFUN([ZFS_AC_PACKAGE], [
 328         ZFS_AC_DEFAULT_PACKAGE
 329         ZFS_AC_RPM
 330         ZFS_AC_DPKG
 331         ZFS_AC_ALIEN
 332
 333         AS_IF([test "$VENDOR" = "arch"], [ZFS_AC_PACMAN])
 334 ])