config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG], [
  10         AC_MSG_CHECKING([whether debugging is enabled])
  11         AC_ARG_ENABLE([debug],
  12                 [AS_HELP_STRING([--enable-debug],
  13                 [Enable generic debug support @<:@default=no@:>@])],
  14                 [],
  15                 [enable_debug=no])
  16
  17         AS_IF([test "x$enable_debug" = xyes],
  18         [
  19                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
  20                 HOSTCFLAGS="${HOSTCFLAGS} -DDEBUG -Werror"
  21                 DEBUG_CFLAGS="-DDEBUG -Werror"
  22                 DEBUG_STACKFLAGS="-fstack-check"
  23                 DEBUG_ZFS="_with_debug"
  24                 AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  25         ],
  26         [
  27                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG "
  28                 HOSTCFLAGS="${HOSTCFLAGS} -DNDEBUG "
  29                 DEBUG_CFLAGS="-DNDEBUG"
  30                 DEBUG_STACKFLAGS=""
  31                 DEBUG_ZFS="_without_debug"
  32         ])
  33
  34         AC_SUBST(DEBUG_CFLAGS)
  35         AC_SUBST(DEBUG_STACKFLAGS)
  36         AC_SUBST(DEBUG_ZFS)
  37         AC_MSG_RESULT([$enable_debug])
  38 ])
  39
  40 AC_DEFUN([ZFS_AC_DEBUG_DMU_TX], [
  41         AC_ARG_ENABLE([debug-dmu-tx],
  42                 [AS_HELP_STRING([--enable-debug-dmu-tx],
  43                 [Enable dmu tx validation @<:@default=no@:>@])],
  44                 [],
  45                 [enable_debug_dmu_tx=no])
  46
  47         AS_IF([test "x$enable_debug_dmu_tx" = xyes],
  48         [
  49                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_DMU_TX"
  50                 DEBUG_DMU_TX="_with_debug_dmu_tx"
  51                 AC_DEFINE([DEBUG_DMU_TX], [1],
  52                 [Define to 1 to enabled dmu tx validation])
  53         ],
  54         [
  55                 DEBUG_DMU_TX="_without_debug_dmu_tx"
  56         ])
  57
  58         AC_SUBST(DEBUG_DMU_TX)
  59         AC_MSG_CHECKING([whether dmu tx validation is enabled])
  60         AC_MSG_RESULT([$enable_debug_dmu_tx])
  61 ])
  62
  63 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
  64         ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE
  65 ])
  66
  67 AC_DEFUN([ZFS_AC_CONFIG], [
  68         TARGET_ASM_DIR=asm-generic
  69         AC_SUBST(TARGET_ASM_DIR)
  70
  71         ZFS_CONFIG=all
  72         AC_ARG_WITH([config],
  73                 AS_HELP_STRING([--with-config=CONFIG],
  74                 [Config file 'kernel|user|all|srpm']),
  75                 [ZFS_CONFIG="$withval"])
  76         AC_ARG_ENABLE([linux-builtin],
  77                 [AC_HELP_STRING([--enable-linux-builtin],
  78                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
  79                 [],
  80                 [enable_linux_builtin=no])
  81
  82         AC_MSG_CHECKING([zfs config])
  83         AC_MSG_RESULT([$ZFS_CONFIG]);
  84         AC_SUBST(ZFS_CONFIG)
  85
  86         ZFS_AC_CONFIG_ALWAYS
  87
  88         case "$ZFS_CONFIG" in
  89                 kernel) ZFS_AC_CONFIG_KERNEL ;;
  90                 user)   ZFS_AC_CONFIG_USER   ;;
  91                 all)    ZFS_AC_CONFIG_KERNEL
  92                         ZFS_AC_CONFIG_USER   ;;
  93                 srpm)                        ;;
  94                 *)
  95                 AC_MSG_RESULT([Error!])
  96                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
  97                               user kernel|user|all|srpm]) ;;
  98         esac
  99
 100         AM_CONDITIONAL([CONFIG_USER],
 101                        [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 102         AM_CONDITIONAL([CONFIG_KERNEL],
 103                        [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 104                        [test "x$enable_linux_builtin" != xyes ])
 105 ])
 106
 107 dnl #
 108 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 109 dnl # are missing it is non-fatal but you will not be able to build
 110 dnl # RPM packages and will be warned if you try too.
 111 dnl #
 112 AC_DEFUN([ZFS_AC_RPM], [
 113         RPM=rpm
 114         RPMBUILD=rpmbuild
 115
 116         AC_MSG_CHECKING([whether $RPM is available])
 117         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 118                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 119                 HAVE_RPM=yes
 120                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 121         ],[
 122                 HAVE_RPM=no
 123                 AC_MSG_RESULT([$HAVE_RPM])
 124         ])
 125
 126         AC_MSG_CHECKING([whether $RPMBUILD is available])
 127         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 128                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 129                 HAVE_RPMBUILD=yes
 130                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 131         ],[
 132                 HAVE_RPMBUILD=no
 133                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 134         ])
 135
 136         AC_SUBST(HAVE_RPM)
 137         AC_SUBST(RPM)
 138         AC_SUBST(RPM_VERSION)
 139
 140         AC_SUBST(HAVE_RPMBUILD)
 141         AC_SUBST(RPMBUILD)
 142         AC_SUBST(RPMBUILD_VERSION)
 143 ])
 144
 145 dnl #
 146 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 147 dnl # tools are missing it is non-fatal but you will not be able to build
 148 dnl # DEB packages and will be warned if you try too.
 149 dnl #
 150 AC_DEFUN([ZFS_AC_DPKG], [
 151         DPKG=dpkg
 152         DPKGBUILD=dpkg-buildpackage
 153
 154         AC_MSG_CHECKING([whether $DPKG is available])
 155         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 156                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 157                 HAVE_DPKG=yes
 158                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 159         ],[
 160                 HAVE_DPKG=no
 161                 AC_MSG_RESULT([$HAVE_DPKG])
 162         ])
 163
 164         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 165         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 166                 DPKGBUILD_VERSION=$(echo $tmp | \
 167                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 168                 HAVE_DPKGBUILD=yes
 169                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 170         ],[
 171                 HAVE_DPKGBUILD=no
 172                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 173         ])
 174
 175         AC_SUBST(HAVE_DPKG)
 176         AC_SUBST(DPKG)
 177         AC_SUBST(DPKG_VERSION)
 178
 179         AC_SUBST(HAVE_DPKGBUILD)
 180         AC_SUBST(DPKGBUILD)
 181         AC_SUBST(DPKGBUILD_VERSION)
 182 ])
 183
 184 dnl #
 185 dnl # Until native packaging for various different packing systems
 186 dnl # can be added the least we can do is attempt to use alien to
 187 dnl # convert the RPM packages to the needed package type.  This is
 188 dnl # a hack but so far it has worked reasonable well.
 189 dnl #
 190 AC_DEFUN([ZFS_AC_ALIEN], [
 191         ALIEN=alien
 192
 193         AC_MSG_CHECKING([whether $ALIEN is available])
 194         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 195                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 196                 HAVE_ALIEN=yes
 197                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 198         ],[
 199                 HAVE_ALIEN=no
 200                 AC_MSG_RESULT([$HAVE_ALIEN])
 201         ])
 202
 203         AC_SUBST(HAVE_ALIEN)
 204         AC_SUBST(ALIEN)
 205         AC_SUBST(ALIEN_VERSION)
 206 ])
 207
 208 dnl #
 209 dnl # Check for pacman+makepkg to build Arch Linux packages.  If these
 210 dnl # tools are missing it is non-fatal but you will not be able to
 211 dnl # build Arch Linux packages and will be warned if you try too.
 212 dnl #
 213 AC_DEFUN([ZFS_AC_PACMAN], [
 214         PACMAN=pacman
 215         MAKEPKG=makepkg
 216
 217         AC_MSG_CHECKING([whether $PACMAN is available])
 218         tmp=$($PACMAN --version 2>/dev/null)
 219         AS_IF([test -n "$tmp"], [
 220                 PACMAN_VERSION=$(echo $tmp |
 221                                  $AWK '/Pacman/ { print $[3] }' |
 222                                  $SED 's/^v//')
 223                 HAVE_PACMAN=yes
 224                 AC_MSG_RESULT([$HAVE_PACMAN ($PACMAN_VERSION)])
 225         ],[
 226                 HAVE_PACMAN=no
 227                 AC_MSG_RESULT([$HAVE_PACMAN])
 228         ])
 229
 230         AC_MSG_CHECKING([whether $MAKEPKG is available])
 231         tmp=$($MAKEPKG --version 2>/dev/null)
 232         AS_IF([test -n "$tmp"], [
 233                 MAKEPKG_VERSION=$(echo $tmp | $AWK '/makepkg/ { print $[3] }')
 234                 HAVE_MAKEPKG=yes
 235                 AC_MSG_RESULT([$HAVE_MAKEPKG ($MAKEPKG_VERSION)])
 236         ],[
 237                 HAVE_MAKEPKG=no
 238                 AC_MSG_RESULT([$HAVE_MAKEPKG])
 239         ])
 240
 241         AC_SUBST(HAVE_PACMAN)
 242         AC_SUBST(PACMAN)
 243         AC_SUBST(PACMAN_VERSION)
 244
 245         AC_SUBST(HAVE_MAKEPKG)
 246         AC_SUBST(MAKEPKG)
 247         AC_SUBST(MAKEPKG_VERSION)
 248 ])
 249
 250 dnl #
 251 dnl # Using the VENDOR tag from config.guess set the default
 252 dnl # package type for 'make pkg': (rpm | deb | tgz)
 253 dnl #
 254 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 255         AC_MSG_CHECKING([linux distribution])
 256         if test -f /etc/toss-release ; then
 257                 VENDOR=toss ;
 258         elif test -f /etc/fedora-release ; then
 259                 VENDOR=fedora ;
 260         elif test -f /etc/redhat-release ; then
 261                 VENDOR=redhat ;
 262         elif test -f /etc/gentoo-release ; then
 263                 VENDOR=gentoo ;
 264         elif test -f /etc/arch-release ; then
 265                 VENDOR=arch ;
 266         elif test -f /etc/SuSE-release ; then
 267                 VENDOR=sles ;
 268         elif test -f /etc/slackware-version ; then
 269                 VENDOR=slackware ;
 270         elif test -f /etc/lunar.release ; then
 271                 VENDOR=lunar ;
 272         elif test -f /etc/lsb-release ; then
 273                 VENDOR=ubuntu ;
 274         elif test -f /etc/debian_version ; then
 275                 VENDOR=debian ;
 276         else
 277                 VENDOR= ;
 278         fi
 279         AC_MSG_RESULT([$VENDOR])
 280         AC_SUBST(VENDOR)
 281
 282         AC_MSG_CHECKING([default package type])
 283         case "$VENDOR" in
 284                 toss)       DEFAULT_PACKAGE=rpm  ;;
 285                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 286                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 287                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 288                 arch)       DEFAULT_PACKAGE=arch ;;
 289                 sles)       DEFAULT_PACKAGE=rpm  ;;
 290                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 291                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 292                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 293                 debian)     DEFAULT_PACKAGE=deb  ;;
 294                 *)          DEFAULT_PACKAGE=rpm  ;;
 295         esac
 296
 297         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 298         AC_SUBST(DEFAULT_PACKAGE)
 299
 300         AC_MSG_CHECKING([default init directory])
 301         case "$VENDOR" in
 302                 arch)       DEFAULT_INIT_DIR=$sysconfdir/rc.d ;;
 303                 *)          DEFAULT_INIT_DIR=$sysconfdir/init.d ;;
 304         esac
 305
 306         AC_MSG_RESULT([$DEFAULT_INIT_DIR])
 307         AC_SUBST(DEFAULT_INIT_DIR)
 308
 309         AC_MSG_CHECKING([default init script type])
 310         case "$VENDOR" in
 311                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 312                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 313                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 314                 gentoo)     DEFAULT_INIT_SCRIPT=gentoo ;;
 315                 arch)       DEFAULT_INIT_SCRIPT=arch   ;;
 316                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 317                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 318                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 319                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 320                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 321                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 322         esac
 323
 324         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
 325         AC_SUBST(DEFAULT_INIT_SCRIPT)
 326 ])
 327
 328 dnl #
 329 dnl # Default ZFS package configuration
 330 dnl #
 331 AC_DEFUN([ZFS_AC_PACKAGE], [
 332         ZFS_AC_DEFAULT_PACKAGE
 333         ZFS_AC_RPM
 334         ZFS_AC_DPKG
 335         ZFS_AC_ALIEN
 336
 337         AS_IF([test "$VENDOR" = "arch"], [ZFS_AC_PACMAN])
 338 ])