config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG], [
  10         AC_MSG_CHECKING([whether debugging is enabled])
  11         AC_ARG_ENABLE([debug],
  12                 [AS_HELP_STRING([--enable-debug],
  13                 [Enable generic debug support @<:@default=no@:>@])],
  14                 [],
  15                 [enable_debug=no])
  16
  17         AS_IF([test "x$enable_debug" = xyes],
  18         [
  19                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
  20                 HOSTCFLAGS="${HOSTCFLAGS} -DDEBUG -Werror"
  21                 DEBUG_CFLAGS="-DDEBUG -Werror"
  22                 DEBUG_STACKFLAGS="-fstack-check"
  23         ],
  24         [
  25                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG "
  26                 HOSTCFLAGS="${HOSTCFLAGS} -DNDEBUG "
  27                 DEBUG_CFLAGS="-DNDEBUG"
  28                 DEBUG_STACKFLAGS=""
  29         ])
  30
  31         AC_SUBST(DEBUG_CFLAGS)
  32         AC_SUBST(DEBUG_STACKFLAGS)
  33         AC_MSG_RESULT([$enable_debug])
  34 ])
  35
  36 AC_DEFUN([ZFS_AC_CONFIG_SCRIPT], [
  37         cat >.script-config <<EOF
  38 KERNELSRC=${LINUX}
  39 KERNELBUILD=${LINUX_OBJ}
  40 KERNELSRCVER=${LINUX_VERSION}
  41 KERNELMOD=/lib/modules/\${KERNELSRCVER}/kernel
  42
  43 SPLSRC=${SPL}
  44 SPLBUILD=${SPL_OBJ}
  45 SPLSRCVER=${SPL_VERSION}
  46
  47 TOPDIR=${TOPDIR}
  48 BUILDDIR=${BUILDDIR}
  49 LIBDIR=${LIBDIR}
  50 CMDDIR=${CMDDIR}
  51 MODDIR=${MODDIR}
  52 SCRIPTDIR=${SCRIPTDIR}
  53 ETCDIR=\${TOPDIR}/etc
  54 DEVDIR=\${TOPDIR}/dev
  55 ZPOOLDIR=\${TOPDIR}/scripts/zpool-config
  56
  57 ZDB=\${CMDDIR}/zdb/zdb
  58 ZFS=\${CMDDIR}/zfs/zfs
  59 ZINJECT=\${CMDDIR}/zinject/zinject
  60 ZPOOL=\${CMDDIR}/zpool/zpool
  61 ZPOOL_ID=\${CMDDIR}/zpool_id/zpool_id
  62 ZTEST=\${CMDDIR}/ztest/ztest
  63
  64 COMMON_SH=\${SCRIPTDIR}/common.sh
  65 ZFS_SH=\${SCRIPTDIR}/zfs.sh
  66 ZPOOL_CREATE_SH=\${SCRIPTDIR}/zpool-create.sh
  67
  68 INTREE=1
  69 LDMOD=/sbin/insmod
  70
  71 KERNEL_MODULES=(                                      \\
  72         \${KERNELMOD}/lib/zlib_deflate/zlib_deflate.ko \\
  73 )
  74
  75 SPL_MODULES=(                                         \\
  76         \${SPLBUILD}/spl/spl.ko                        \\
  77         \${SPLBUILD}/splat/splat.ko                    \\
  78 )
  79
  80 ZFS_MODULES=(                                         \\
  81         \${MODDIR}/avl/zavl.ko                         \\
  82         \${MODDIR}/nvpair/znvpair.ko                   \\
  83         \${MODDIR}/unicode/zunicode.ko                 \\
  84         \${MODDIR}/zcommon/zcommon.ko                  \\
  85         \${MODDIR}/zfs/zfs.ko                          \\
  86 )
  87
  88 MODULES=(                                             \\
  89         \${KERNEL_MODULES[[*]]}                          \\
  90         \${SPL_MODULES[[*]]}                             \\
  91         \${ZFS_MODULES[[*]]}                             \\
  92 )
  93 EOF
  94 ])
  95
  96 AC_DEFUN([ZFS_AC_CONFIG], [
  97         TOPDIR=`readlink -f ${srcdir}`
  98         BUILDDIR=$TOPDIR
  99         LIBDIR=$TOPDIR/lib
 100         CMDDIR=$TOPDIR/cmd
 101         MODDIR=$TOPDIR/module
 102         SCRIPTDIR=$TOPDIR/scripts
 103         TARGET_ASM_DIR=asm-generic
 104
 105         AC_SUBST(TOPDIR)
 106         AC_SUBST(BUILDDIR)
 107         AC_SUBST(LIBDIR)
 108         AC_SUBST(CMDDIR)
 109         AC_SUBST(MODDIR)
 110         AC_SUBST(SCRIPTDIR)
 111         AC_SUBST(TARGET_ASM_DIR)
 112
 113         ZFS_CONFIG=all
 114         AC_ARG_WITH([config],
 115                 AS_HELP_STRING([--with-config=CONFIG],
 116                 [Config file 'kernel|user|all|srpm']),
 117                 [ZFS_CONFIG="$withval"])
 118
 119         AC_MSG_CHECKING([zfs config])
 120         AC_MSG_RESULT([$ZFS_CONFIG]);
 121         AC_SUBST(ZFS_CONFIG)
 122
 123         case "$ZFS_CONFIG" in
 124                 kernel) ZFS_AC_CONFIG_KERNEL ;;
 125                 user)   ZFS_AC_CONFIG_USER   ;;
 126                 all)    ZFS_AC_CONFIG_KERNEL
 127                         ZFS_AC_CONFIG_USER   ;;
 128                 srpm)                        ;;
 129                 *)
 130                 AC_MSG_RESULT([Error!])
 131                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
 132                               user kernel|user|all|srpm]) ;;
 133         esac
 134
 135         AM_CONDITIONAL([CONFIG_USER],
 136                        [test "$ZFS_CONFIG" = user] ||
 137                        [test "$ZFS_CONFIG" = all])
 138         AM_CONDITIONAL([CONFIG_KERNEL],
 139                        [test "$ZFS_CONFIG" = kernel] ||
 140                        [test "$ZFS_CONFIG" = all])
 141
 142         ZFS_AC_CONFIG_SCRIPT
 143 ])
 144
 145 dnl #
 146 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 147 dnl # are missing it is non-fatal but you will not be able to build
 148 dnl # RPM packages and will be warned if you try too.
 149 dnl #
 150 AC_DEFUN([ZFS_AC_RPM], [
 151         RPM=rpm
 152         RPMBUILD=rpmbuild
 153
 154         AC_MSG_CHECKING([whether $RPM is available])
 155         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 156                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 157                 HAVE_RPM=yes
 158                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 159         ],[
 160                 HAVE_RPM=no
 161                 AC_MSG_RESULT([$HAVE_RPM])
 162         ])
 163
 164         AC_MSG_CHECKING([whether $RPMBUILD is available])
 165         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 166                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 167                 HAVE_RPMBUILD=yes
 168                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 169         ],[
 170                 HAVE_RPMBUILD=no
 171                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 172         ])
 173
 174         AC_SUBST(HAVE_RPM)
 175         AC_SUBST(RPM)
 176         AC_SUBST(RPM_VERSION)
 177
 178         AC_SUBST(HAVE_RPMBUILD)
 179         AC_SUBST(RPMBUILD)
 180         AC_SUBST(RPMBUILD_VERSION)
 181 ])
 182
 183 dnl #
 184 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 185 dnl # tools are missing it is non-fatal but you will not be able to build
 186 dnl # DEB packages and will be warned if you try too.
 187 dnl #
 188 AC_DEFUN([ZFS_AC_DPKG], [
 189         DPKG=dpkg
 190         DPKGBUILD=dpkg-buildpackage
 191
 192         AC_MSG_CHECKING([whether $DPKG is available])
 193         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 194                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 195                 HAVE_DPKG=yes
 196                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 197         ],[
 198                 HAVE_DPKG=no
 199                 AC_MSG_RESULT([$HAVE_DPKG])
 200         ])
 201
 202         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 203         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 204                 DPKGBUILD_VERSION=$(echo $tmp | \
 205                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 206                 HAVE_DPKGBUILD=yes
 207                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 208         ],[
 209                 HAVE_DPKGBUILD=no
 210                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 211         ])
 212
 213         AC_SUBST(HAVE_DPKG)
 214         AC_SUBST(DPKG)
 215         AC_SUBST(DPKG_VERSION)
 216
 217         AC_SUBST(HAVE_DPKGBUILD)
 218         AC_SUBST(DPKGBUILD)
 219         AC_SUBST(DPKGBUILD_VERSION)
 220 ])
 221
 222 dnl #
 223 dnl # Until native packaging for various different packing systems
 224 dnl # can be added the least we can do is attempt to use alien to
 225 dnl # convert the RPM packages to the needed package type.  This is
 226 dnl # a hack but so far it has worked reasonable well.
 227 dnl #
 228 AC_DEFUN([ZFS_AC_ALIEN], [
 229         ALIEN=alien
 230
 231         AC_MSG_CHECKING([whether $ALIEN is available])
 232         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 233                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 234                 HAVE_ALIEN=yes
 235                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 236         ],[
 237                 HAVE_ALIEN=no
 238                 AC_MSG_RESULT([$HAVE_ALIEN])
 239         ])
 240
 241         AC_SUBST(HAVE_ALIEN)
 242         AC_SUBST(ALIEN)
 243         AC_SUBST(ALIEN_VERSION)
 244 ])
 245
 246 dnl #
 247 dnl # Using the VENDOR tag from config.guess set the default
 248 dnl # package type for 'make pkg': (rpm | deb | tgz)
 249 dnl #
 250 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 251         AC_MSG_CHECKING([linux distribution])
 252         if test -f /etc/redhat-release ; then
 253                 VENDOR=redhat ;
 254         elif test -f /etc/fedora-release ; then
 255                 VENDOR=fedora ;
 256         elif test -f /etc/debian_version ; then
 257                 VENDOR=debian ;
 258         elif test -f /etc/lsb-release ; then
 259                 VENDOR=ubuntu ;
 260         elif test -f /etc/SuSE-release ; then
 261                 VENDOR=sles ;
 262         elif test -f /etc/slackware-version ; then
 263                 VENDOR=slackware ;
 264         elif test -f /etc/gentoo-release ; then
 265                 VENDOR=gentoo ;
 266         else
 267                 VENDOR= ;
 268         fi
 269         AC_MSG_RESULT([$VENDOR])
 270         AC_SUBST(VENDOR)
 271
 272         AC_MSG_CHECKING([default package type])
 273         case "$VENDOR" in
 274                 fedora)     DEFAULT_PACKAGE=rpm ;;
 275                 redhat)     DEFAULT_PACKAGE=rpm ;;
 276                 sles)       DEFAULT_PACKAGE=rpm ;;
 277                 ubuntu)     DEFAULT_PACKAGE=deb ;;
 278                 debian)     DEFAULT_PACKAGE=deb ;;
 279                 slackware)  DEFAULT_PACKAGE=tgz ;;
 280                 *)          DEFAULT_PACKAGE=rpm ;;
 281         esac
 282
 283         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 284         AC_SUBST(DEFAULT_PACKAGE)
 285 ])
 286
 287 dnl #
 288 dnl # Default ZFS package configuration
 289 dnl #
 290 AC_DEFUN([ZFS_AC_PACKAGE], [
 291         ZFS_AC_RPM
 292         ZFS_AC_DPKG
 293         ZFS_AC_ALIEN
 294         ZFS_AC_DEFAULT_PACKAGE
 295 ])