config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG], [
  10         AC_MSG_CHECKING([whether debugging is enabled])
  11         AC_ARG_ENABLE([debug],
  12                 [AS_HELP_STRING([--enable-debug],
  13                 [Enable generic debug support @<:@default=no@:>@])],
  14                 [],
  15                 [enable_debug=no])
  16
  17         AS_IF([test "x$enable_debug" = xyes],
  18         [
  19                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
  20                 HOSTCFLAGS="${HOSTCFLAGS} -DDEBUG -Werror"
  21                 DEBUG_CFLAGS="-DDEBUG -Werror"
  22                 DEBUG_STACKFLAGS="-fstack-check"
  23                 DEBUG_ZFS="_with_debug"
  24                 AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  25         ],
  26         [
  27                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG "
  28                 HOSTCFLAGS="${HOSTCFLAGS} -DNDEBUG "
  29                 DEBUG_CFLAGS="-DNDEBUG"
  30                 DEBUG_STACKFLAGS=""
  31                 DEBUG_ZFS="_without_debug"
  32         ])
  33
  34         AC_SUBST(DEBUG_CFLAGS)
  35         AC_SUBST(DEBUG_STACKFLAGS)
  36         AC_SUBST(DEBUG_ZFS)
  37         AC_MSG_RESULT([$enable_debug])
  38 ])
  39
  40 AC_DEFUN([ZFS_AC_DEBUG_DMU_TX], [
  41         AC_ARG_ENABLE([debug-dmu-tx],
  42                 [AS_HELP_STRING([--enable-debug-dmu-tx],
  43                 [Enable dmu tx validation @<:@default=no@:>@])],
  44                 [],
  45                 [enable_debug_dmu_tx=no])
  46
  47         AS_IF([test "x$enable_debug_dmu_tx" = xyes],
  48         [
  49                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_DMU_TX"
  50                 DEBUG_DMU_TX="_with_debug_dmu_tx"
  51                 AC_DEFINE([DEBUG_DMU_TX], [1],
  52                 [Define to 1 to enabled dmu tx validation])
  53         ],
  54         [
  55                 DEBUG_DMU_TX="_without_debug_dmu_tx"
  56         ])
  57
  58         AC_SUBST(DEBUG_DMU_TX)
  59         AC_MSG_CHECKING([whether dmu tx validation is enabled])
  60         AC_MSG_RESULT([$enable_debug_dmu_tx])
  61 ])
  62
  63 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
  64         ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE
  65 ])
  66
  67 AC_DEFUN([ZFS_AC_CONFIG], [
  68         TARGET_ASM_DIR=asm-generic
  69         AC_SUBST(TARGET_ASM_DIR)
  70
  71         ZFS_CONFIG=all
  72         AC_ARG_WITH([config],
  73                 AS_HELP_STRING([--with-config=CONFIG],
  74                 [Config file 'kernel|user|all|srpm']),
  75                 [ZFS_CONFIG="$withval"])
  76         AC_ARG_ENABLE([linux-builtin],
  77                 [AC_HELP_STRING([--enable-linux-builtin],
  78                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
  79                 [],
  80                 [enable_linux_builtin=no])
  81
  82         AC_MSG_CHECKING([zfs config])
  83         AC_MSG_RESULT([$ZFS_CONFIG]);
  84         AC_SUBST(ZFS_CONFIG)
  85
  86         ZFS_AC_CONFIG_ALWAYS
  87
  88         case "$ZFS_CONFIG" in
  89                 kernel) ZFS_AC_CONFIG_KERNEL ;;
  90                 user)   ZFS_AC_CONFIG_USER   ;;
  91                 all)    ZFS_AC_CONFIG_KERNEL
  92                         ZFS_AC_CONFIG_USER   ;;
  93                 srpm)                        ;;
  94                 *)
  95                 AC_MSG_RESULT([Error!])
  96                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
  97                               user kernel|user|all|srpm]) ;;
  98         esac
  99
 100         AM_CONDITIONAL([CONFIG_USER],
 101                        [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 102         AM_CONDITIONAL([CONFIG_KERNEL],
 103                        [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 104                        [test "x$enable_linux_builtin" != xyes ])
 105 ])
 106
 107 dnl #
 108 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 109 dnl # are missing it is non-fatal but you will not be able to build
 110 dnl # RPM packages and will be warned if you try too.
 111 dnl #
 112 AC_DEFUN([ZFS_AC_RPM], [
 113         RPM=rpm
 114         RPMBUILD=rpmbuild
 115
 116         AC_MSG_CHECKING([whether $RPM is available])
 117         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 118                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 119                 HAVE_RPM=yes
 120                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 121         ],[
 122                 HAVE_RPM=no
 123                 AC_MSG_RESULT([$HAVE_RPM])
 124         ])
 125
 126         AC_MSG_CHECKING([whether $RPMBUILD is available])
 127         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 128                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 129                 HAVE_RPMBUILD=yes
 130                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 131         ],[
 132                 HAVE_RPMBUILD=no
 133                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 134         ])
 135
 136         AC_SUBST(HAVE_RPM)
 137         AC_SUBST(RPM)
 138         AC_SUBST(RPM_VERSION)
 139
 140         AC_SUBST(HAVE_RPMBUILD)
 141         AC_SUBST(RPMBUILD)
 142         AC_SUBST(RPMBUILD_VERSION)
 143 ])
 144
 145 dnl #
 146 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 147 dnl # tools are missing it is non-fatal but you will not be able to build
 148 dnl # DEB packages and will be warned if you try too.
 149 dnl #
 150 AC_DEFUN([ZFS_AC_DPKG], [
 151         DPKG=dpkg
 152         DPKGBUILD=dpkg-buildpackage
 153
 154         AC_MSG_CHECKING([whether $DPKG is available])
 155         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 156                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 157                 HAVE_DPKG=yes
 158                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 159         ],[
 160                 HAVE_DPKG=no
 161                 AC_MSG_RESULT([$HAVE_DPKG])
 162         ])
 163
 164         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 165         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 166                 DPKGBUILD_VERSION=$(echo $tmp | \
 167                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 168                 HAVE_DPKGBUILD=yes
 169                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 170         ],[
 171                 HAVE_DPKGBUILD=no
 172                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 173         ])
 174
 175         AC_SUBST(HAVE_DPKG)
 176         AC_SUBST(DPKG)
 177         AC_SUBST(DPKG_VERSION)
 178
 179         AC_SUBST(HAVE_DPKGBUILD)
 180         AC_SUBST(DPKGBUILD)
 181         AC_SUBST(DPKGBUILD_VERSION)
 182 ])
 183
 184 dnl #
 185 dnl # Until native packaging for various different packing systems
 186 dnl # can be added the least we can do is attempt to use alien to
 187 dnl # convert the RPM packages to the needed package type.  This is
 188 dnl # a hack but so far it has worked reasonable well.
 189 dnl #
 190 AC_DEFUN([ZFS_AC_ALIEN], [
 191         ALIEN=alien
 192
 193         AC_MSG_CHECKING([whether $ALIEN is available])
 194         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 195                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 196                 HAVE_ALIEN=yes
 197                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 198         ],[
 199                 HAVE_ALIEN=no
 200                 AC_MSG_RESULT([$HAVE_ALIEN])
 201         ])
 202
 203         AC_SUBST(HAVE_ALIEN)
 204         AC_SUBST(ALIEN)
 205         AC_SUBST(ALIEN_VERSION)
 206 ])
 207
 208 dnl #
 209 dnl # Using the VENDOR tag from config.guess set the default
 210 dnl # package type for 'make pkg': (rpm | deb | tgz)
 211 dnl #
 212 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 213         AC_MSG_CHECKING([linux distribution])
 214         if test -f /etc/toss-release ; then
 215                 VENDOR=toss ;
 216         elif test -f /etc/fedora-release ; then
 217                 VENDOR=fedora ;
 218         elif test -f /etc/redhat-release ; then
 219                 VENDOR=redhat ;
 220         elif test -f /etc/gentoo-release ; then
 221                 VENDOR=gentoo ;
 222         elif test -f /etc/arch-release ; then
 223                 VENDOR=arch ;
 224         elif test -f /etc/SuSE-release ; then
 225                 VENDOR=sles ;
 226         elif test -f /etc/slackware-version ; then
 227                 VENDOR=slackware ;
 228         elif test -f /etc/lunar.release ; then
 229                 VENDOR=lunar ;
 230         elif test -f /etc/lsb-release ; then
 231                 VENDOR=ubuntu ;
 232         elif test -f /etc/debian_version ; then
 233                 VENDOR=debian ;
 234         else
 235                 VENDOR= ;
 236         fi
 237         AC_MSG_RESULT([$VENDOR])
 238         AC_SUBST(VENDOR)
 239
 240         AC_MSG_CHECKING([default package type])
 241         case "$VENDOR" in
 242                 toss)       DEFAULT_PACKAGE=rpm  ;;
 243                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 244                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 245                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 246                 arch)       DEFAULT_PACKAGE=tgz  ;;
 247                 sles)       DEFAULT_PACKAGE=rpm  ;;
 248                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 249                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 250                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 251                 debian)     DEFAULT_PACKAGE=deb  ;;
 252                 *)          DEFAULT_PACKAGE=rpm  ;;
 253         esac
 254
 255         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 256         AC_SUBST(DEFAULT_PACKAGE)
 257
 258         DEFAULT_INIT_DIR=$sysconfdir/init.d
 259         AC_MSG_CHECKING([default init directory])
 260         AC_MSG_RESULT([$DEFAULT_INIT_DIR])
 261         AC_SUBST(DEFAULT_INIT_DIR)
 262
 263         AC_MSG_CHECKING([default init script type])
 264         case "$VENDOR" in
 265                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 266                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 267                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 268                 gentoo)     DEFAULT_INIT_SCRIPT=gentoo ;;
 269                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 270                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 271                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 272                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 273                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 274                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 275                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 276         esac
 277
 278         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
 279         AC_SUBST(DEFAULT_INIT_SCRIPT)
 280 ])
 281
 282 dnl #
 283 dnl # Default ZFS package configuration
 284 dnl #
 285 AC_DEFUN([ZFS_AC_PACKAGE], [
 286         ZFS_AC_DEFAULT_PACKAGE
 287         ZFS_AC_RPM
 288         ZFS_AC_DPKG
 289         ZFS_AC_ALIEN
 290 ])