# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for blip.tv

package BlipTVGrabber;

use GrabberBase;
@ISA = qw(GrabberBase);

use LWP::Simple qw(!get);
use HTML::Parser;
use XML::Simple;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new();

    $self->{'NAME'} = 'bliptv';
    $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*blip.tv/file/(\d+)(?:\?\S+)?)'];

    bless($self, $class);
    $self->_prepare_parameters();

    return $self;
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p = HTML::Parser->new(api_version => 3);
    my @accum;
    my $e;
    my $xml = undef;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{"NAME"};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = LWP::Simple::get(sprintf('http://blip.tv/file/%s', $2)))) {
        $self->error('Could not download page');
        return undef;
    }

    $p->handler(start => \@accum, "tagname, attr");
    $p->report_tags(qw(div));
    $p->utf8_mode(1);
    $p->parse($content);

    # Look for the post id in the div tags
    foreach $e (@accum) {
        if (exists($e->[1]->{'pokkariparameters'})) {
            if ($e->[1]->{'pokkariparameters'} =~ m|posts_id:"(\d+)"|) {
                $xml = $1;
            }
        }
    }

    unless(defined($xml)) { 
        $self->error("Could not find post id");
        return undef;
    }

    # Download the XML file containing the stream information
    unless(defined($content = LWP::Simple::get(sprintf('http://blip.tv/rss/flash/%s', $xml)))) {
        $self->error('Could not download XML metadata');
        return undef;
    }

    $xml = XML::Simple::XMLin($content, KeepRoot => 1);
    $metadata->{'DLURL'} = $xml->{'rss'}->{'channel'}->{'item'}->{'media:group'}->{'media:content'}->{'url'};
    $metadata->{'TITLE'} = $xml->{'rss'}->{'channel'}->{'item'}->{'media:title'};

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

1;