# Grabber for break.com
#
# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2

package BreakGrabber;

use GrabberBase;
@ISA = qw(GrabberBase);

use LWP::Simple qw(!get);
use HTML::Parser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new();

    $self->{'NAME'} = 'break';
    $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*break.com/index/([-a-zA-Z0-9_]+?)\.html)'];

    bless($self, $class);

    $self->_prepare_parameters();

    return $self;
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p = HTML::Parser->new(api_version => 3);
    my @accum;
    my @text;
    my $e;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = LWP::Simple::get($1))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    $p->handler(start => \@accum, "tagname, attr");
    $p->report_tags(qw(meta));
    $p->utf8_mode(1);
    $p->parse($content);

    # Look for the title in the meta tags
    foreach $e (@accum) {
        if ('meta' eq $e->[0]) {
            if ('embed_video_title' eq $e->[1]->{'name'}) {
                $metadata->{'TITLE'} = $e->[1]->{'content'};
            }

            if ('embed_video_thumb_url' eq $e->[1]->{'name'}) {
                $metadata->{'DLURL'} = $e->[1]->{'content'};
                $metadata->{'DLURL'} =~ s/\.jpg$/\.flv/;
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

1;