# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for youtube.com/de/...
#
# download strategy revised using
# http://www.kde-apps.org/content/show.php?content=41456

package YouTubeGrabber;

use GrabberBase;
@ISA = qw(GrabberBase);

use LWP::Simple qw(!get);
use HTML::TokeParser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new();

    $self->{'NAME'} = 'youtube';
    $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/watch\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
                           '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))'];

    bless($self, $class);
    $self->_prepare_parameters();

    return $self;
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p;
    my $e;
    my $tag;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = LWP::Simple::get(sprintf('http://youtube.com/watch?v=%s', $2)))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    $p = HTML::TokeParser->new(\$content);

    while ($tag = $p->get_tag('div', 'meta', 'script')) {
        if ('meta' eq $tag->[0]) {
            if ('title' eq $tag->[1]->{'name'}) {
                $metadata->{'TITLE'} = $tag->[1]->{'content'};
                $self->debug('Title found: %s', $metadata->{'TITLE'});
            }
        } elsif ('script' eq $tag->[0]) {
            $e = $p->get_text();
            if ($e =~ m|/watch_fullscreen\?(.+)\x27|) {
                my %args = map { split(/=/, $_, 2); } split(/&/, $1);
                $metadata->{'DLURL'} = sprintf('http://www.youtube.com/get_video.php?video_id=%s&t=%s',
                        $metadata->{'ID'}, $args{'t'});
                $self->debug('URL found: %s', $metadata->{'DLURL'});
            }
        } elsif ('div' eq $tag->[0]) {
            if ('errorBox' eq $tag->[1]->{'class'}) {
                $self->error("Could not get video data for youtube %s: %s",
                        $metadata->{'ID'}, $p->get_trimmed_text());
                return undef;
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

1;