# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for youtube.com/de/...
#
# download strategy revised using
# http://www.kde-apps.org/content/show.php?content=41456

package YouTubeGrabber;

use GrabberBase;
@ISA = qw(GrabberBase);

use LWP::Simple qw(!get);
use HTML::Parser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new();

    $self->{'NAME'} = 'youtube';
    $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/watch\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
                           '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))'];

    bless($self, $class);
    $self->_prepare_parameters();

    return $self;
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p = HTML::Parser->new(api_version => 3);
    my @accum;
    my @text;
    my $e;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = LWP::Simple::get(sprintf('http://youtube.com/watch?v=%s', $2)))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    if ($content =~ /This video has been removed due to terms of use violation/) {
        $self->error('Video has been removed');
        return undef;
    }

    $p->handler(start => \@accum, "tagname, attr");
    $p->handler(text => \@text, "text");
    $p->report_tags(qw(meta script));
    $p->utf8_mode(1);
    $p->parse($content);

    # Look for the title in the meta tags
    foreach $e (@accum) {
        if ('meta' eq $e->[0]) {
            if ('title' eq $e->[1]->{'name'}) {
                $metadata->{'TITLE'} = $e->[1]->{'content'};
                $self->debug('Title found: %s', $metadata->{'TITLE'});
            }
        }
    }

    # Look for the download URL
    foreach $e (@text) {
        if ($e->[0] =~ m|/watch_fullscreen\?(.+)\x27|) {
            my %args = map { my @a = split(/=/); ($a[0], $a[1]) } split(/&/, $1);
            $metadata->{'DLURL'} = sprintf('http://www.youtube.com/get_video.php?video_id=%s&t=%s',
                    $metadata->{'ID'}, $args{'t'});
                $self->debug('URL found: %s', $metadata->{'DLURL'});
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

1;