# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for youtube.com/de/...
#
# download strategy revised using
# http://www.kde-apps.org/content/show.php?content=41456

package videosite::YouTubeGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use LWP::UserAgent;
use HTTP::Cookies;
use HTML::TokeParser;
use HTML::Entities qw(decode_entities);
use Encode;
use Data::Dumper;
use videosite::JSArrayParser;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new();

    $self->{'NAME'} = 'youtube';
    $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/watch\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
                           '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/watch\#\!v=([-a-zA-Z0-9_]+))',
                           '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))',
                           '(http://(?:[-a-zA-Z0-9_.]+\.)*youtu\.be/([-a-zA-Z0-9_]+))',
                           '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube\.(?:com|de|co.uk)/user/\w+\?.*/([-a-zA-Z0-9_]+))'];
    $self->{'_PARAMS'} = {
            'QUALITY' => ['normal', 'Quality of the video to download.', {
                    'normal' => 'standard resolution flash video',
                    'high' => 'higher resolution flash video',
                    'h264' => 'high resolution MPEG4 video',
                    'hd' => 'HD720 resolution'}],
            'USERNAME' => ['', 'Username to use for YouTube login'],
            'PASSWORD' => ['', 'Password to use for YouTube login']};

    bless($self, $class);
    $self->_prepare_parameters();

    return $self;
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p;
    my $e;
    my $tag;
    my $jar = HTTP::Cookies->new;
    my $ua = LWP::UserAgent->new('agent' => 'Mozilla/5.0');
    my $r;
    my $videourl;
    my $quality = $self->_getval('QUALITY');
    my %preflist = (
        'hd' => [37, 22, 35, 18, 34, 6, 5],
        'h264' => [18, 34, 37, 22, 35, 6, 5],
        'high' => [34, 35, 18, 37, 22, 6, 5],
        'normal' => [6, 5, 34, 35, 18, 22, 37]);
    my $preflist;
    my $jsp;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    $self->debug("Matched id %s from pattern %s", $2, $pattern);

    $preflist = $preflist{$quality};
    $self->debug("Quality: %s, preflist: [%s]", $quality, join(", ", @{$preflist}));

    $videourl = sprintf('http://www.youtube.com/watch?v=%s', $2);

    unless(defined($r = $ua->get($videourl))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    if ($r->base->as_string() =~ m,/verify_age,) {
        $self->debug('Video requires age verification');
        $ua->cookie_jar($jar);
        $r = $self->__login($videourl, $ua);
        unless(defined($r)) {
            $self->error('Could not log into YouTube');
            return undef;
        }
    }
    $content = $r->content();

    $p = HTML::TokeParser->new(\$content);

    SWF_ARGS: while ($tag = $p->get_tag('div', 'meta', 'script')) {
        if ('meta' eq $tag->[0]) {
            if ('title' eq $tag->[1]->{'name'}) {
                $metadata->{'TITLE'} = $tag->[1]->{'content'};
                # Convert HTML entities in the title. This is a bit convoluted.
                $metadata->{'TITLE'} = encode("utf8",
                                         decode_entities(
                                           decode("utf8", $metadata->{'TITLE'})));
                    
                $self->debug('Title found: %s', $metadata->{'TITLE'});
            }
        } elsif ('script' eq $tag->[0]) {
            my %urls;

            $e = $p->get_text();
            $self->debug("Found script: %s", $e);

            if ($e =~ m|\x27SWF_ARGS\x27:\s+(.+),|) {
                my $args = $1;

                $self->debug("Found SWF_ARGS: %s", $args);
                $jsp = videosite::JSArrayParser->new();
                $self->debug("Using %s to parse", ref($jsp));
                $r = $jsp->parse($args);

                unless(defined($r)) {
                    $self->error("Found information hash, but could not parse");
                    return undef;
                }

                if (exists($r->{'fmt_url_map'}) and ($r->{'fmt_url_map'} ne '')) {
                    my $urls =  $r->{'fmt_url_map'};

                    $self->debug("Video has fmt_url_map: %s", $urls);

                    $urls =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
                    %urls = split(/[\|,]/, $urls);
                    $self->debug("Pagetype: old (SWF_ARGS), fmt_url_map");

                } elsif (exists($r->{'t'}) and ($r->{'t'} ne '')) {
                    my $thash = $r->{'t'};

                    if (exists($r->{'fmt_map'}) && ($r->{'fmt_map'} ne '')) {
                        my $fmt = $r->{'fmt_map'};
                        my @fmt;

                        $self->debug('Video has fmt_map');
                        $fmt =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
                        @fmt = split(/,/, $fmt);
                        foreach (@fmt) {
                            split(/\//);
                            $urls{$_[0]} =  sprintf('http://www.youtube.com/get_video?video_id=%s&fmt=%d&t=%s', 
                                $metadata->{'ID'},
                                $_[0],
                                $thash);
                        }
                        $self->debug("Pagetype: 2009 (SWF_ARGS), t with fmt_map");

                    } else {
                        $urls{5} = sprintf('http://www.youtube.com/get_video?video_id=%s&t=%s',
                            $metadata->{'ID'},
                            $thash);
                        $self->debug("Pagetype: 2009 (SWF_ARGS), t without fmt_map");
                    }
                } else {
                    $self->error('Neither fmt_url_map nor t found in video information hash');
                    return undef;
                }
            } elsif ($e =~ m|var swfHTML = .*fmt_url_map=([^\&]+)\&|) {
                my $urls = $1;
                $self->debug("Video has fmt_url_map: %s", $urls);

                $urls =~ s/%([[:xdigit:]]{2})/chr(hex($1))/ge;
                %urls = split(/[\|,]/, $urls);
                $self->debug("Pagetype: 2010 (swfHTML), fmt_url_map");
            }

            if (%urls) {
                foreach (keys(%urls)) {
                    if ($_ == 35) {
                        $self->debug('Found flv,h264,large: %s', $urls{$_});
                    } elsif ($_ == 34) {
                        $self->debug('Found flv,h264: %s', $urls{$_});
                    } elsif ($_ == 22) {
                        $self->debug('Found mp4,h264,720p: %s', $urls{$_});
                    } elsif ($_ == 37) {
                        $self->debug('Found mp4,h264,1080p: %s', $urls{$_});
                    } elsif ($_ == 18) {
                        $self->debug('Found mp4,h264: %s', $urls{$_});
                    } elsif ($_ == 5) {
                        $self->debug('Found flv,flv: %s', $urls{$_});
                    } else {
                        $self->error('Unknown tag %s: %s', $_, $urls{$_});
                    }
                }

                foreach (@{$preflist}) {
                    if (exists($urls{$_})) {
                        $self->debug("Selected URL with quality level %s", $_);
                        $metadata->{'DLURL'} = $urls{$_};
                        last;
                    }
                }

                $self->debug('URL found: %s', $metadata->{'DLURL'});
                last SWF_ARGS;
            }
        } elsif ('div' eq $tag->[0]) {
            if (exists($tag->[1]->{'class'}) and ('yt-alert-content' eq $tag->[1]->{'class'})) {
                $self->error("Could not get video data for youtube %s: %s",
                        $metadata->{'ID'}, $p->get_trimmed_text());
                return undef;
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

sub __login {
    my $self = shift;
    my $videourl = shift;
    my $ua = shift;
    my $user = $self->_getval('USERNAME');
    my $pass = $self->_getval('PASSWORD');
    my $r;
    my $p;
    my $c;
    my $token;

    sub check_cookie {

        my $jar = shift;
        my $key = shift;
        my $found = undef;

        $jar->scan(sub { $found = 1 if ( $key eq $_[1]) });

        return $found;
    }

    if (($user eq '') or ($pass eq '')) {
        $self->error('No username or password defined for YouTube');
        return undef;
    }

    $self->debug('Logging in');
    $r = $ua->post('http://www.youtube.com/signup', { 'next' => '/', 'current_form' => 'login', 'action_login' => '1', 'username' => $user, 'password' => $pass });

    unless(check_cookie($ua->cookie_jar, 'LOGIN_INFO')) {
        $self->error('Could not log into YouTube');
        return undef;
    }

    $self->debug("Got a cookie");

    $r = $ua->get($videourl);
    if ($r->base->as_string() =~ m,/verify_age,) {
        $self->debug("Looking for session token...");
        $c = $r->decoded_content();
        $p = HTML::TokeParser->new(\$c);
        while (my $tag = $p->get_tag('script')) {
            if ($p->get_text() =~ /gXSRF_token = '(.+)'/) {
                $token = $1;
                last;
            }
        }

        unless(defined($token)) {
            $self->error("Could not find session token");
            return undef;
        }

        $self->debug('Authenticating session...');
        $r = $ua->post($r->base->as_string, { 'next_url' => $r->base->path, 'action_confirm' => 'Confirm Birth Date', 'session_token' => $token });
    }

    unless(check_cookie($ua->cookie_jar, 'is_adult')) {
        $self->error('Could not authenticate session');
        return undef;
    }

    return $ua->get($videourl);
}

1;