# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for youtube.com/de/...
#
# download strategy revised using
# http://www.kde-apps.org/content/show.php?content=41456

package YouTubeGrabber;

use GrabberBase;
@ISA = qw(GrabberBase);

use LWP::UserAgent;
use HTTP::Cookies;
use HTML::TokeParser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new();

    $self->{'NAME'} = 'youtube';
    $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/watch\?(?:.+=.+&)*v=([-a-zA-Z0-9_]+))',
                           '(http://(?:[-a-zA-Z0-9_.]+\.)*youtube.(?:com|de|co.uk)/v/([-a-zA-Z0-9_]+))'];
    $self->{'_PARAMS'} = {'QUALITY' => ['normal', 'Quality of the video to download. normal = standard resolution flash video, high = higher resolution flash video, h264 = high resolution MPEG4 video, hd = HD720 resolution'], 'USERNAME' => ['', 'Username to use for YouTube login'], 'PASSWORD' => ['', 'Password to use for YouTube login']};

    bless($self, $class);
    $self->_prepare_parameters();

    return $self;
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p;
    my $e;
    my $tag;
    my $jar = HTTP::Cookies->new;
    my $ua = LWP::UserAgent->new('agent' => 'Mozilla/5.0');
    my $r;
    my $videourl;
    my $quality = $self->_getval('QUALITY');
    my $append = '';

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    if ($quality eq 'high') {
        $append = '&fmt=6';
    } elsif ($quality eq 'h264') {
        $append = '&fmt=18';
    } elsif ($quality eq 'hd') {
        $append = '&fmt=22';
    }

    $videourl = sprintf('http://www.youtube.com/watch?v=%s%s', $2, $append);

    unless(defined($r = $ua->get($videourl))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    if ($r->base->as_string() =~ m,/verify_age,) {
        $self->debug('Video requires age verification');
        $ua->cookie_jar($jar);
        $r = $self->__login($videourl, $ua);
        unless(defined($r)) {
            $self->error('Could not log into YouTube');
            return undef;
        }
    }
    $content = $r->content();

    $p = HTML::TokeParser->new(\$content);

    while ($tag = $p->get_tag('div', 'meta', 'script')) {
        if ('meta' eq $tag->[0]) {
            if ('title' eq $tag->[1]->{'name'}) {
                $metadata->{'TITLE'} = $tag->[1]->{'content'};
                $self->debug('Title found: %s', $metadata->{'TITLE'});
            }
        } elsif ('script' eq $tag->[0]) {
            $e = $p->get_text();
            if ($e =~ m|/watch_fullscreen\?(.+)\x27|) {
                my %args = map { split(/=/, $_, 2); } split(/&(?!amp;)/, $1);
                $metadata->{'DLURL'} = sprintf('http://www.youtube.com/get_video.php?video_id=%s&t=%s%s',
                        $metadata->{'ID'}, $args{'t'}, $append);
                $self->debug('URL found: %s', $metadata->{'DLURL'});
            }
        } elsif ('div' eq $tag->[0]) {
            if (exists($tag->[1]->{'class'}) and ('errorBox' eq $tag->[1]->{'class'})) {
                $self->error("Could not get video data for youtube %s: %s",
                        $metadata->{'ID'}, $p->get_trimmed_text());
                return undef;
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

sub __login {
    my $self = shift;
    my $videourl = shift;
    my $ua = shift;
    my $user = $self->_getval('USERNAME');
    my $pass = $self->_getval('PASSWORD');
    my $r;
    my $p;
    my $c;
    my $token;

    sub check_cookie {

        my $jar = shift;
        my $key = shift;
        my $found = undef;

        $jar->scan(sub { $found = 1 if ( $key eq $_[1]) });

        return $found;
    }

    if (($user eq '') or ($pass eq '')) {
        $self->error('No username or password defined for YouTube');
        return undef;
    }

    $self->debug('Logging in');
    $r = $ua->post('http://www.youtube.com/signup', { 'next' => '/', 'current_form' => 'login', 'action_login' => '1', 'username' => $user, 'password' => $pass });

    unless(check_cookie($ua->cookie_jar, 'LOGIN_INFO')) {
        $self->error('Could not log into YouTube');
        return undef;
    }

    $r = $ua->get($videourl);
    if ($r->base->as_string() =~ m,/verify_age,) {
        $self->debug("Looking for session token...");
        $c = $r->decoded_content();
        $p = HTML::TokeParser->new(\$c);
        while (my $tag = $p->get_tag('script')) {
            if ($p->get_text() =~ /gXSRF_token = '(.+)'/) {
                $token = $1;
                last;
            }
        }

        unless(defined($token)) {
            $self->error("Could not find session token");
            return undef;
        }

        $self->debug('Authenticating session...');
        $r = $ua->post($r->base->as_string, { 'next_url' => $r->base->path, 'action_confirm' => 'Confirm Birth Date', 'session_token' => $token });
    }

    unless(check_cookie($ua->cookie_jar, 'is_adult')) {
        $self->error('Could not authenticate session');
        return undef;
    }

    return $ua->get($videourl);
}

1;