# autodownload flash videos
#
# (c) 2007-2008 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Based on youtube.pl by Christian Garbs <mitch@cgarbs.de>
# which in turn is
# based on trigger.pl by Wouter Coekaerts <wouter@coekaerts.be>


BEGIN {
    # Get rid of a (possibly old) version of BettIrssi
    # This is a hack to prevent having to reload irssi just
    # because BettIrssi.pm changed

    delete($INC{'BettIrssi.pm'});
}

use strict;
use Irssi 20020324 qw (command_bind command_runsub signal_add_first signal_add_last);
use vars qw($VERSION %IRSSI);
use XML::Simple;
use Data::Dumper;
use File::Spec;
use BettIrssi 101 qw(_bcb _bcs);
use LWP::UserAgent;

my @grabbers;
my @getters;
my $getter;
my $conf;
my $conffile = File::Spec->catfile(Irssi::get_irssi_dir(), 'videosite.xml');
my $scriptdir = File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts');
my $plugindir = File::Spec->catfile($scriptdir, 'videosite');
my @outputstack = (undef);

my $PARAMS = {
    'getter' => '',
    'mode' => 'download'
};


# activate debug here
my $debug = 0;

# "message public", SERVER_REC, char *msg, char *nick, char *address, char *target
signal_add_last(_bcs("message public" => sub {check_for_link(@_)}));
# "message own_public", SERVER_REC, char *msg, char *target
signal_add_last(_bcs("message own_public" => sub {check_for_link(@_)}));

# "message private", SERVER_REC, char *msg, char *nick, char *address
signal_add_last(_bcs("message private" => sub {check_for_link(@_)}));
# "message own_private", SERVER_REC, char *msg, char *target, char *orig_target
signal_add_last(_bcs("message own_private" => sub {check_for_link(@_)}));

# "message irc action", SERVER_REC, char *msg, char *nick, char *address, char *target
signal_add_last(_bcs("message irc action" => sub {check_for_link(@_)}));
# "message irc own_action", SERVER_REC, char *msg, char *target
signal_add_last(_bcs("message irc own_action" => sub {check_for_link(@_)}));

# For tab completion
# This does not use BettIrssi (yet)
signal_add_first('complete word', \&sig_complete);

sub push_output {
    unshift(@outputstack, shift);
}

sub pop_output {
    shift(@outputstack);

    @outputstack = (undef) unless (@outputstack);
}

my $videosite_commands = {
    'save' => sub {
        cmd_save();
    },

    'set' => sub {
        cmd_set(@_);
    },
    
    'show' => sub {
        cmd_show(@_);
    },

    'help' => sub {
        cmd_help(@_);
    },

    'getter' => sub {
        cmd_getter(@_);
    },

    'enable' => sub {
        cmd_enable(@_);
    },

    'disable' => sub {
        cmd_disable(@_);
    },

    'reload' => sub {
        init_videosite(0);
    },

    'mode' => sub {
        cmd_mode(@_);
    },

    'debug' => sub {
        $debug = 1;
        foreach (@grabbers, @getters) {
            $_->setdebug(1);
        }
        write_irssi('Enabled debugging');
    },

    'nodebug' => sub {
        $debug = 0;
        foreach (@grabbers, @getters) {
            $_->setdebug(0);
        }
        write_irssi('Disabled debugging');
    },
};

sub write_irssi {
    my @text = @_;
    my $output = $outputstack[0];

    my $format = "%%mvideosite: %%n" . shift(@text);

    # escape % in parameters from irssi
    s/%/%%/g foreach @text;

    if (defined $output) {
        $output->(sprintf($format, @text), MSGLEVEL_CLIENTCRAP);
    } else {
        Irssi::print(sprintf($format, @text));
    }

}

sub write_debug {
    if ($debug) {
        write_irssi(@_);
    }
}

sub expand_url_shortener {
    my $s = shift;
    my $os = '';
    my @urlshortener = (
        'is.\gd/[[:alnum:]]+',
        'otf\.me/[[:alnum:]]+',
        'hel\.me/[[:alnum:]]+',
        '7ax\.de/[[:alnum:]]+',
        'ow\.ly/[[:alnum:]]+',
        'j\.mp/[[:alnum:]]+',
        'bit\.ly/[[:alnum:]]+',
        'tinyurl\.com/[[:alnum:]]+',
        'pop\.is/[[:alnum:]]+',
        'post\.ly/[[:alnum:]]+',
        );
    my $ua = LWP::UserAgent->new(agent => 'Mozilla', max_redirect => 0);
    my $i = 10;

    OUTER: while (($os ne $s) and ($i > 0)) {
        $os = $s;
        $i--;

        foreach my $pattern (@urlshortener) {
            my $p = "https?:\/\/" . $pattern;

            write_debug("Matching %s against %s", $p, $s);
            if ($s =~ m|($p)|) {
                my $matched = $1;
                my $res;

                write_debug("Found %s", $matched);
                $res = $ua->head($matched);
                if ($res->is_redirect()) {
                    my $new = $res->headers()->header("Location");

                    write_debug("Replacing %s with %s", $matched, $new);
                    $s =~ s/$matched/$new/;
                    next OUTER;
                } else {
                    write_debug("Error resolving %s", $matched);
                }
            }
        }
    }

    if ($i == 0) {
        write_debug("Loop terminated by counter");
    }

    write_debug("Final string: %s", $s);

    return $s;
}


sub check_for_link {
    my $event = shift;
    my $message = $event->message();
    my $witem = $event->channel();
    my $g;
    my $m;
    my $p;


    # Look if we should ignore this line
    if ($message =~ m,(?:\s|^)/nosave(?:\s|$),) {
        return;
    }

    push_output($event->ewpf);
    $message = expand_url_shortener($message);

    study($message);

    # Offer the message to all Grabbers in turn
    GRABBER: foreach $g (@grabbers) {
        ($m, $p) = $g->get($message);
        while (defined($m)) {
            write_debug('Metadata: %s', Dumper($m));
            if ('download' eq ($conf->{'videosite'}->{'mode'})) {
                write_irssi('%%R>>> %%NSaving %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
                unless($getter->get($m)) {
                    write_irssi('%%R>>> FAILED');
                }
            } elsif ('display' eq ($conf->{'videosite'}->{'mode'})) {
                write_irssi('%%M>>> %%NSaw %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
            } else {
                write_irssi('%%R>>> Invalid operation mode');
            }

            # Remove the matched part from the message and try again (there may be
            # more!)
            $message =~ s/$p//;
            study($message);
            last GRABBER if ($message =~ /^\s*$/);

            ($m, $p) = $g->get($message);
        }
    }

    pop_output();
}

sub cmd_save {

    eval {
        open(CONF, '>'.$conffile) or die 'Could not open config file';
        print CONF XML::Simple::XMLout($conf, KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'});
        close(CONF);
    };
    if ($@) {
        write_irssi('Could not save config to %s: %s', ($conffile, $@));
    } else {
        write_irssi('configuration saved to %s', $conffile);
    }
}

sub cmd_set {
    my $target = shift;
    my $key = shift;
    my $val = shift;
    my $p;

    foreach $p (@getters, @grabbers) {
        if ($p->{'NAME'} eq $target) {
            $p->setval($key, $val);
            return;
        }
    }
    write_irssi('No such module');
}


sub cmd_enable {
    my $target = shift;
    my $p;

    foreach $p (@grabbers) {
        if ($p->{'NAME'} eq $target) {
            $p->enable();
            return;
        }
    }
    write_irssi('No such module');
}


sub cmd_disable {
    my $target = shift;
    my $p;

    foreach $p (@grabbers) {
        if ($p->{'NAME'} eq $target) {
            $p->disable();
            return;
        }
    }
    write_irssi('No such module');
}


sub cmd_show {
    my $target = shift;
    my $p;
    my $e;

    if (defined($target)) {
        foreach $p (@getters, @grabbers) {
            if ($p->{'NAME'} eq $target) {
                write_irssi($p->getconfstr());
                return;
            }
        }
        write_irssi('No such module');
    } else {
        write_irssi('Loaded grabbers (* denotes enabled modules):');
        foreach $p (@grabbers) {
            $e = $p->_getval('enabled');
            write_irssi(' %s%s', $p->{'NAME'}, $e?'*':'');
        };

        write_irssi('Loaded getters:');
        foreach $p (@getters) {
            write_irssi(' %s', $p->{'NAME'});
        };
    }
}

sub cmd_help {
    my $target = shift;
    my $p;

    if (defined($target)) {
        foreach $p (@getters, @grabbers) {
            if ($p->{'NAME'} eq $target) {
                write_irssi($p->gethelpstr());
                return;
            }
        }
        write_irssi('No such module');
    } else {
        write_irssi(<<'EOT');
Supported commands:
 save: save the current configuration
 help [modulename]: display this help, or module specific help
 show [modulename]: show loaded modules, or the current parameters of a module
 set modulename parameter value: set a module parameter to a new value
 getter [modulename]: display or set the getter to use
 enable [modulename]: enable the usage of this module (grabbers only)
 disable [modulename]: disable the usage of this module (grabbers only)
 reload: reload all modules (this is somewhat experimental)
 mode [modename]: display or set the operation mode (download/display)
 debug: enable debugging messages
 nodebug: disable debugging messages
EOT
    }
}

sub cmd_getter {
    my $target = shift;
    my $p;

    if (defined($target)) {
        foreach $p (@getters) {
            if ($p->{'NAME'} eq $target) {
                $getter = $p;
                $conf->{'videosite'}->{'getter'} = $target;
                write_irssi("Getter changed to %s", $target);
                return;
            }
        }
        write_irssi('No such getter');
    } else {
        write_irssi('Current getter: %s', $conf->{'videosite'}->{'getter'});
    }
}

sub cmd_mode {
    my $mode = shift;

    if (defined($mode)) {
        $mode = lc($mode);
        if (('download' eq $mode) or ('display' eq $mode)) {
            $conf->{'videosite'}->{'mode'} = $mode;
            write_irssi('Now using %s mode', $mode);
        } else {
            write_irssi('Invalid mode: %s', $mode);
        }
    } else {
        write_irssi('Current mode: %s', $conf->{'videosite'}->{'mode'});
    }
}


# save on unload
sub sig_command_script_unload {
    my $script = shift;
    if ($script =~ /(.*\/)?videosite(\.pl)?$/) {
        cmd_save();
    }
}

sub ploader {

    my $dir = shift;
    my $pattern = shift;
    my $type = shift;
    my @list;
    my $p;
    my $g;
    my @g = ();

    opendir(D, $dir) || return ();
    @list = grep {/$pattern/ && -f File::Spec->catfile($dir, $_) } readdir(D);
    closedir(D);

    foreach $p (@list) {
        write_debug("Trying to load $p:");
        $p =~ s/\.pm$//;
        eval qq{ require videosite::$p; };
        if ($@) {
            write_irssi("Failed to load plugin: $@");
            next;
        }

        $g = eval qq{ videosite::$p->new(); };
        if ($@) {
            write_irssi("Failed to instanciate: $@");
            delete($INC{$p});
            next;
        }

        write_debug("found $g->{'TYPE'} $g->{'NAME'}");
        if ($type eq $g->{'TYPE'}) {
            push(@g, $g);
            $g->setio(\&write_irssi);
        } else {
            write_irssi('%s has wrong type (got %s, expected %s)', $p, $g->{'TYPE'}, $type);
            delete($INC{$p});
        }
    }

    write_debug("Loaded %d plugins", $#g+1);
    
    return @g;
}

sub _load_modules($) {

    my $path = shift;

    foreach (keys(%INC)) {
        if ($INC{$_} =~ m|^$path|) {
            write_debug("Removing %s from \$INC", $_);
            delete($INC{$_});
        }
    }
    @grabbers = ploader($path, '.*Grabber\.pm$', 'grabber');
    @getters = ploader($path, '.*Getter\.pm$', 'getter');
}


sub init_videosite {

    my $bindings = shift;
    my $p;

    unless(-r $conffile && defined($conf = XML::Simple::XMLin($conffile, ForceArray => ['config', 'option'], KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'}))) {
        # No config, start with an empty one
        write_debug('No config found, using defaults');
        $conf = { 'videosite' => { }};
    }
    foreach (keys(%{$PARAMS})) {
        unless (exists($conf->{'videosite'}->{$_})) {
            $conf->{'videosite'}->{$_} = $PARAMS->{$_};
        }
    }

    _load_modules($plugindir);

    unless (defined(@grabbers) && defined(@getters)) {
        write_irssi('No grabbers or no getters found, can not proceed.');
        return;
    }

    $getter = $getters[0];
    foreach $p (@getters) {
        if ($conf->{'videosite'}->{'getter'} eq $p->{'NAME'}) {
            $getter = $p;
        }
    }
    write_debug('Selected %s as getter', $getter->{'NAME'});
    $conf->{'videosite'}->{'getter'} = $getter->{'NAME'};

    # Loop through all plugins and load the config
    foreach $p (@grabbers, @getters) {
        $conf->{'videosite'}->{'config'}->{$p->{'NAME'}} = $p->mergeconfig($conf->{'videosite'}->{'config'}->{$p->{'NAME'}});
    }

    if ($bindings) {

        Irssi::signal_add_first('command script load', 'sig_command_script_unload');
        Irssi::signal_add_first('command script unload', 'sig_command_script_unload');
        Irssi::signal_add('setup saved', 'cmd_save');


        Irssi::command_bind(_bcb('videosite' => \&cmdhandler));
    }

    write_irssi('initialized successfully');
}

sub sig_complete {
    my ($complist, $window, $word, $linestart, $want_space) = @_;
    my @matches;

    if ($linestart !~ m|^/videosite\b|) {
        return;
    }

    if ('/videosite' eq $linestart) {
        # No command enterd so far. Produce a list of possible follow-ups
        @matches = grep {/^$word/} keys (%{$videosite_commands});
    } elsif ('/videosite set' eq $linestart) {
        # 'set' command entered. Produce a list of modules
        foreach (@grabbers, @getters) {
            push(@matches, $_->{'NAME'}) if $_->{'NAME'} =~ m|^$word|;
        };
    } elsif ($linestart =~ m|^/videosite set (\w+)$|) {
        my $module = $1;

        foreach my $p (@getters, @grabbers) {
            if ($p->{'NAME'} eq $module) {
                @matches = $p->getparamlist($word);
                last;
            }
        }
    } elsif ($linestart =~ m|/videosite set (\w+) (\w+)$|) {
        my $module = $1;
        my $param = $2;

        foreach my $p (@getters, @grabbers) {
            if ($p->{'NAME'} eq $module) {
                @matches = $p->getparamvalues($param, $word);
                last;
            }
        }
    }


    push(@{$complist}, sort @matches);
    ${$want_space} = 0;

    Irssi::signal_stop();
}

sub cmdhandler {
    my $event = shift;
    my ($cmd, @params) = split(/\s+/, $event->message());

    push_output($event->ewpf);

    if (exists($videosite_commands->{$cmd})) {
        $videosite_commands->{$cmd}->(@params);
    }

    pop_output();
}

unshift(@INC, $scriptdir);
init_videosite(1);
