+dnl # Default ZFS kernel configuration
+dnl #
+AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
+ ZFS_AC_KERNEL
+ ZFS_AC_SPL
+ ZFS_AC_TEST_MODULE
+ ZFS_AC_KERNEL_CONFIG
+ ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
+ ZFS_AC_KERNEL_TYPE_FMODE_T
+ ZFS_AC_KERNEL_KOBJ_NAME_LEN
+ ZFS_AC_KERNEL_3ARG_BLKDEV_GET
+ ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
+ ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
+ ZFS_AC_KERNEL_LOOKUP_BDEV
+ ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
+ ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
+ ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
+ ZFS_AC_KERNEL_BIO_FAILFAST
+ ZFS_AC_KERNEL_BIO_FAILFAST_DTD
+ ZFS_AC_KERNEL_REQ_FAILFAST_MASK
+ ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
+ ZFS_AC_KERNEL_BIO_RW_SYNC
+ ZFS_AC_KERNEL_BIO_RW_SYNCIO
+ ZFS_AC_KERNEL_REQ_SYNC
+ ZFS_AC_KERNEL_BLK_END_REQUEST
+ ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
+ ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
+ ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
+ ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
+ ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
+ ZFS_AC_KERNEL_BLK_QUEUE_NONROT
+ ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
+ ZFS_AC_KERNEL_BLK_FETCH_REQUEST
+ ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
+ ZFS_AC_KERNEL_BLK_RQ_BYTES
+ ZFS_AC_KERNEL_BLK_RQ_POS
+ ZFS_AC_KERNEL_BLK_RQ_SECTORS
+ ZFS_AC_KERNEL_GET_DISK_RO
+ ZFS_AC_KERNEL_GET_GENDISK
+ ZFS_AC_KERNEL_RQ_IS_SYNC
+ ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
+ ZFS_AC_KERNEL_DISCARD_GRANULARITY
+ ZFS_AC_KERNEL_CONST_XATTR_HANDLER
+ ZFS_AC_KERNEL_XATTR_HANDLER_GET
+ ZFS_AC_KERNEL_XATTR_HANDLER_SET
+ ZFS_AC_KERNEL_SHOW_OPTIONS
+ ZFS_AC_KERNEL_FSYNC
+ ZFS_AC_KERNEL_EVICT_INODE
+ ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
+ ZFS_AC_KERNEL_NR_CACHED_OBJECTS
+ ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
+ ZFS_AC_KERNEL_FALLOCATE
+ ZFS_AC_KERNEL_MKDIR_UMODE_T
+ ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
+ ZFS_AC_KERNEL_CREATE_NAMEIDATA
+ ZFS_AC_KERNEL_TRUNCATE_RANGE
+ ZFS_AC_KERNEL_AUTOMOUNT
+ ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
+ ZFS_AC_KERNEL_COMMIT_METADATA
+ ZFS_AC_KERNEL_CLEAR_INODE
+ ZFS_AC_KERNEL_INSERT_INODE_LOCKED
+ ZFS_AC_KERNEL_D_MAKE_ROOT
+ ZFS_AC_KERNEL_D_OBTAIN_ALIAS
+ ZFS_AC_KERNEL_D_SET_D_OP
+ ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
+ ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
+ ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
+ ZFS_AC_KERNEL_TRUNCATE_SETSIZE
+ ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
+ ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
+ ZFS_AC_KERNEL_MOUNT_NODEV
+ ZFS_AC_KERNEL_SHRINK
+ ZFS_AC_KERNEL_S_D_OP
+ ZFS_AC_KERNEL_BDI
+ ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
+ ZFS_AC_KERNEL_SET_NLINK
+ ZFS_AC_KERNEL_ELEVATOR_CHANGE
+ ZFS_AC_KERNEL_5ARG_SGET
+
+ AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
+ KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
+ ])
+ AC_SUBST(KERNELMAKE_PARAMS)
+
+
+ dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
+ dnl # compiler options are added by the kernel build system.
+ KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
+ KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
+ KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
+
+ AC_SUBST(KERNELCPPFLAGS)
+])
+
+dnl #
+dnl # Detect name used for Module.symvers file in kernel
+dnl #
+AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
+ modpost=$LINUX/scripts/Makefile.modpost
+ AC_MSG_CHECKING([kernel file name for module symbols])
+ AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
+ AS_IF([grep -q Modules.symvers $modpost], [
+ LINUX_SYMBOLS=Modules.symvers
+ ], [
+ LINUX_SYMBOLS=Module.symvers
+ ])
+
+ AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
+ AC_MSG_ERROR([
+ *** Please make sure the kernel devel package for your distribution
+ *** is installed. If you are building with a custom kernel, make sure the
+ *** kernel is configured, built, and the '--with-linux=PATH' configure
+ *** option refers to the location of the kernel source.])
+ ])
+ ], [
+ LINUX_SYMBOLS=NONE
+ ])
+ AC_MSG_RESULT($LINUX_SYMBOLS)
+ AC_SUBST(LINUX_SYMBOLS)
+])
+
+dnl #
+dnl # Detect the kernel to be built against
+dnl #
+AC_DEFUN([ZFS_AC_KERNEL], [
+ AC_ARG_WITH([linux],
+ AS_HELP_STRING([--with-linux=PATH],
+ [Path to kernel source]),
+ [kernelsrc="$withval"])
+
+ AC_ARG_WITH(linux-obj,
+ AS_HELP_STRING([--with-linux-obj=PATH],
+ [Path to kernel build objects]),
+ [kernelbuild="$withval"])
+
+ AC_MSG_CHECKING([kernel source directory])
+ AS_IF([test -z "$kernelsrc"], [
+ AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
+ headersdir="/lib/modules/$(uname -r)/source"
+ sourcelink=$(readlink -f "$headersdir")
+ ], [test -e "/lib/modules/$(uname -r)/build"], [
+ headersdir="/lib/modules/$(uname -r)/build"
+ sourcelink=$(readlink -f "$headersdir")
+ ], [
+ sourcelink=$(ls -1d /usr/src/kernels/* \
+ /usr/src/linux-* \
+ 2>/dev/null | grep -v obj | tail -1)
+ ])
+
+ AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
+ kernelsrc=`readlink -f ${sourcelink}`
+ ], [
+ kernelsrc="[Not found]"
+ ])
+ ], [
+ AS_IF([test "$kernelsrc" = "NONE"], [
+ kernsrcver=NONE
+ ])
+ ])
+
+ AC_MSG_RESULT([$kernelsrc])
+ AS_IF([test ! -d "$kernelsrc"], [
+ AC_MSG_ERROR([
+ *** Please make sure the kernel devel package for your distribution
+ *** is installed and then try again. If that fails, you can specify the
+ *** location of the kernel source with the '--with-linux=PATH' option.])
+ ])
+
+ AC_MSG_CHECKING([kernel build directory])
+ AS_IF([test -z "$kernelbuild"], [
+ AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
+ kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
+ ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
+ kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
+ ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
+ kernelbuild=${kernelsrc}-obj/${target_cpu}/default
+ ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
+ kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
+ ], [
+ kernelbuild=${kernelsrc}
+ ])
+ ])
+ AC_MSG_RESULT([$kernelbuild])
+
+ AC_MSG_CHECKING([kernel source version])
+ utsrelease1=$kernelbuild/include/linux/version.h
+ utsrelease2=$kernelbuild/include/linux/utsrelease.h
+ utsrelease3=$kernelbuild/include/generated/utsrelease.h
+ AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
+ utsrelease=linux/version.h
+ ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
+ utsrelease=linux/utsrelease.h
+ ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
+ utsrelease=generated/utsrelease.h
+ ])
+
+ AS_IF([test "$utsrelease"], [
+ kernsrcver=`(echo "#include <$utsrelease>";
+ echo "kernsrcver=UTS_RELEASE") |
+ cpp -I $kernelbuild/include |
+ grep "^kernsrcver=" | cut -d \" -f 2`
+
+ AS_IF([test -z "$kernsrcver"], [
+ AC_MSG_RESULT([Not found])
+ AC_MSG_ERROR([*** Cannot determine kernel version.])
+ ])
+ ], [
+ AC_MSG_RESULT([Not found])
+ if test "x$enable_linux_builtin" != xyes; then
+ AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
+ else
+ AC_MSG_ERROR([
+ *** Cannot find UTS_RELEASE definition.
+ *** Please run 'make prepare' inside the kernel source tree.])
+ fi
+ ])
+
+ AC_MSG_RESULT([$kernsrcver])
+
+ LINUX=${kernelsrc}
+ LINUX_OBJ=${kernelbuild}
+ LINUX_VERSION=${kernsrcver}
+
+ AC_SUBST(LINUX)
+ AC_SUBST(LINUX_OBJ)
+ AC_SUBST(LINUX_VERSION)
+
+ ZFS_AC_MODULE_SYMVERS
+])
+
+dnl #
+dnl # Detect name used for the additional SPL Module.symvers file. If one
+dnl # does not exist this is likely because the SPL has been configured
+dnl # but not built. The '--with-spl-timeout' option can be passed
+dnl # to pause here, waiting for the file to appear from a concurrently
+dnl # building SPL package. If the file does not appear in time, a good
+dnl # guess is made as to what this file will be named based on what it
+dnl # is named in the kernel build products. This file will first be
+dnl # used at link time so if the guess is wrong the build will fail
+dnl # then. This unfortunately means the ZFS package does not contain a
+dnl # reliable mechanism to detect symbols exported by the SPL at
+dnl # configure time.
+dnl #
+AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
+ AC_ARG_WITH([spl-timeout],
+ AS_HELP_STRING([--with-spl-timeout=SECS],
+ [Wait SECS for symvers file to appear @<:@default=0@:>@]),
+ [timeout="$withval"], [timeout=0])
+
+ AC_MSG_CHECKING([spl file name for module symbols])
+ SPL_SYMBOLS=NONE
+
+ while true; do
+ AS_IF([test -r $SPL_OBJ/Module.symvers], [
+ SPL_SYMBOLS=Module.symvers
+ ], [test -r $SPL_OBJ/Modules.symvers], [
+ SPL_SYMBOLS=Modules.symvers
+ ], [test -r $SPL_OBJ/module/Module.symvers], [
+ SPL_SYMBOLS=Module.symvers
+ ], [test -r $SPL_OBJ/module/Modules.symvers], [
+ SPL_SYMBOLS=Modules.symvers
+ ])
+
+ AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
+ break;
+ ], [
+ sleep 1
+ timeout=$((timeout-1))
+ ])
+ done
+
+ AS_IF([test "$SPL_SYMBOLS" = NONE], [
+ SPL_SYMBOLS=$LINUX_SYMBOLS
+ ])
+
+ AC_MSG_RESULT([$SPL_SYMBOLS])
+ AC_SUBST(SPL_SYMBOLS)
+])
+
+dnl #
+dnl # Detect the SPL module to be built against
+dnl #
+AC_DEFUN([ZFS_AC_SPL], [
+ AC_ARG_WITH([spl],
+ AS_HELP_STRING([--with-spl=PATH],
+ [Path to spl source]),
+ [splsrc="$withval"])
+
+ AC_ARG_WITH([spl-obj],
+ AS_HELP_STRING([--with-spl-obj=PATH],
+ [Path to spl build objects]),
+ [splbuild="$withval"])
+
+ dnl #
+ dnl # The existence of spl.release.in is used to identify a valid
+ dnl # source directory. In order of preference:
+ dnl #
+ splsrc0="/var/lib/dkms/spl/${VERSION}/build"
+ splsrc1="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
+ splsrc2="/usr/src/spl-${VERSION}"
+ splsrc3="../spl/"
+ splsrc4="$LINUX"
+
+ AC_MSG_CHECKING([spl source directory])
+ AS_IF([test -z "${splsrc}"], [
+ AS_IF([ test -e "${splsrc0}/spl.release.in"], [
+ splsrc=${splsrc0}
+ ], [ test -e "${splsrc1}/spl.release.in"], [
+ splsrc=${splsrc1}
+ ], [ test -e "${splsrc2}/spl.release.in"], [
+ splsrc=${splsrc2}
+ ], [ test -e "${splsrc3}/spl.release.in"], [
+ splsrc=$(readlink -f "${splsrc3}")
+ ], [ test -e "${splsrc4}/spl.release.in" ], [
+ splsrc=${splsrc4}
+ ], [
+ splsrc="[Not found]"
+ ])
+ ], [
+ AS_IF([test "$splsrc" = "NONE"], [
+ splbuild=NONE
+ splsrcver=NONE
+ ])
+ ])
+
+ AC_MSG_RESULT([$splsrc])
+ AS_IF([ test ! -e "$splsrc/spl.release.in"], [
+ AC_MSG_ERROR([
+ *** Please make sure the kmod spl devel package for your distribution
+ *** is installed then try again. If that fails you can specify the
+ *** location of the spl source with the '--with-spl=PATH' option.])
+ ])
+
+ dnl #
+ dnl # The existence of the spl_config.h is used to identify a valid
+ dnl # spl object directory. In many cases the object and source
+ dnl # directory are the same, however the objects may also reside
+ dnl # is a subdirectory named after the kernel version.
+ dnl #
+ AC_MSG_CHECKING([spl build directory])
+ AS_IF([test -z "$splbuild"], [
+ AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
+ splbuild="${splsrc}/${LINUX_VERSION}"
+ ], [ test -e "${splsrc}/spl_config.h" ], [
+ splbuild="${splsrc}"
+ ], [
+ splbuild="[Not found]"
+ ])
+ ])
+
+ AC_MSG_RESULT([$splbuild])
+ AS_IF([ ! test -e "$splbuild/spl_config.h"], [
+ AC_MSG_ERROR([
+ *** Please make sure the kmod spl devel <kernel> package for your
+ *** distribution is installed then try again. If that fails you
+ *** can specify the location of the spl objects with the
+ *** '--with-spl-obj=PATH' option.])
+ ])
+
+ AC_MSG_CHECKING([spl source version])
+ AS_IF([test -r $splbuild/spl_config.h &&
+ fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
+
+ splsrcver=`(echo "#include <spl_config.h>";
+ echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
+ cpp -I $splbuild |
+ grep "^splsrcver=" | tr -d \" | cut -d= -f2`
+ ])
+
+ AS_IF([test -z "$splsrcver"], [
+ AC_MSG_RESULT([Not found])
+ AC_MSG_ERROR([
+ *** Cannot determine the version of the spl source.
+ *** Please prepare the spl source before running this script])
+ ])
+
+ AC_MSG_RESULT([$splsrcver])
+
+ SPL=${splsrc}
+ SPL_OBJ=${splbuild}
+ SPL_VERSION=${splsrcver}
+
+ AC_SUBST(SPL)
+ AC_SUBST(SPL_OBJ)
+ AC_SUBST(SPL_VERSION)
+
+ ZFS_AC_SPL_MODULE_SYMVERS
+])
+
+dnl #
+dnl # Basic toolchain sanity check.
+dnl #
+AC_DEFUN([ZFS_AC_TEST_MODULE],
+ [AC_MSG_CHECKING([whether modules can be built])
+ ZFS_LINUX_TRY_COMPILE([],[],[
+ AC_MSG_RESULT([yes])
+ ],[
+ AC_MSG_RESULT([no])
+ if test "x$enable_linux_builtin" != xyes; then
+ AC_MSG_ERROR([*** Unable to build an empty module.])
+ else
+ AC_MSG_ERROR([
+ *** Unable to build an empty module.
+ *** Please run 'make scripts' inside the kernel source tree.])
+ fi
+ ])
+])
+
+dnl #
+dnl # Certain kernel build options are not supported. These must be
+dnl # detected at configure time and cause a build failure. Otherwise
+dnl # modules may be successfully built that behave incorrectly.