From: Prakash Surya <surya1@llnl.gov>
Date: Fri, 25 Nov 2011 00:37:27 +0000 (-0800)
Subject: In autoconf v2.68, AC_LANG_PROGRAM must be quoted
X-Git-Url: https://git.camperquake.de/gitweb.cgi?a=commitdiff_plain;h=e89236fd28cbe8585146b8b5d0ced1f8d4aa8431;p=zfs.git

In autoconf v2.68, AC_LANG_PROGRAM must be quoted

This change updates the AC_LANG_PROGRAM autoconf macro invocations to be
wrapped in quotes. As of autoconf version 2.68, the quotes are necessary
to prevent warnings from appearing. Specifically, the autoconf v2.68
Forward Porting Notes specifies:

    It is important to note that you need to ensure that the call to
    AC_LANG_SOURCE is quoted and not expanded, otherwise that will
    cause the warning to appear nonetheless.

Finally, because of the additional quoting we can drop the extra
quotas used by the ZFS_AC_CONFIG_USER_STACK_GUARD autoconf check.

Signed-off-by: Brian Behlendorf <behlendorf1@llnl.gov>
Closes #464
---

diff --git a/config/always-no-unused-but-set-variable.m4 b/config/always-no-unused-but-set-variable.m4
index 0e2634d..4a3ceb6 100644
--- a/config/always-no-unused-but-set-variable.m4
+++ b/config/always-no-unused-but-set-variable.m4
@@ -12,7 +12,7 @@ AC_DEFUN([ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE], [
 	saved_flags="$CFLAGS"
 	CFLAGS="$CFLAGS -Wunused-but-set-variable"
 
-	AC_RUN_IFELSE(AC_LANG_PROGRAM( [], []),
+	AC_RUN_IFELSE([AC_LANG_PROGRAM([], [])],
 	[
 		NO_UNUSED_BUT_SET_VARIABLE=-Wno-unused-but-set-variable
 		AC_MSG_RESULT([yes])
diff --git a/config/user-frame-larger-than.m4 b/config/user-frame-larger-than.m4
index 3384f50..7ad8622 100644
--- a/config/user-frame-larger-than.m4
+++ b/config/user-frame-larger-than.m4
@@ -7,7 +7,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_FRAME_LARGER_THAN], [
 	saved_flags="$CFLAGS"
 	CFLAGS="$CFLAGS -Wframe-larger-than=1024"
 
-	AC_RUN_IFELSE(AC_LANG_PROGRAM( [], []),
+	AC_RUN_IFELSE([AC_LANG_PROGRAM([], [])],
 	[
 		FRAME_LARGER_THAN=-Wframe-larger-than=1024
 		AC_MSG_RESULT([yes])
diff --git a/config/user-libblkid.m4 b/config/user-libblkid.m4
index 8934d0a..276587f 100644
--- a/config/user-libblkid.m4
+++ b/config/user-libblkid.m4
@@ -39,7 +39,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_LIBBLKID], [
 			saved_LDFLAGS="$LDFLAGS"
 			LDFLAGS="-lblkid"
 
-			AC_RUN_IFELSE(AC_LANG_PROGRAM(
+			AC_RUN_IFELSE([AC_LANG_PROGRAM(
 			[
 				#include <stdio.h>
 				#include <blkid/blkid.h>
@@ -66,7 +66,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_LIBBLKID], [
 
 				free(value);
 				blkid_put_cache(cache);
-			]),
+			])],
 			[
 				rm -f $ZFS_DEV
 				AC_MSG_RESULT([yes])
diff --git a/config/user-nptl_guard_within_stack.m4 b/config/user-nptl_guard_within_stack.m4
index d094da7..421eb1c 100644
--- a/config/user-nptl_guard_within_stack.m4
+++ b/config/user-nptl_guard_within_stack.m4
@@ -12,7 +12,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_STACK_GUARD], [
 	saved_LDFLAGS="$LDFLAGS"
 	LDFLAGS="-lpthread"
 
-	AC_RUN_IFELSE(AC_LANG_PROGRAM(
+	AC_RUN_IFELSE([AC_LANG_PROGRAM(
 	[
 		#include <pthread.h>
 		#include <sys/resource.h>
@@ -25,7 +25,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_STACK_GUARD], [
 
 		void * func(void *arg)
 		{
-			char buf[[[BUFSIZE]]];
+			char buf[[BUFSIZE]];
 		}
 	],
 	[
@@ -41,7 +41,7 @@ AC_DEFUN([ZFS_AC_CONFIG_USER_STACK_GUARD], [
 		pthread_attr_setguardsize(&attr, PAGESIZE);
 		pthread_create(&tid, &attr, func, NULL);
 		pthread_join(tid, NULL);
-	]),
+	])],
 	[
 		AC_MSG_RESULT([no])
 	],