From 269604a96f3edab3ed911d7a6931eef58c834560 Mon Sep 17 00:00:00 2001
From: Ralf Ertzinger <sun@ryoko-darknet.camperquake.de>
Date: Sun, 13 Dec 2009 16:45:31 +0100
Subject: [PATCH 1/1] - Add grabber for wimp.com

---
 videosite/WimpGrabber.pm | 88 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 88 insertions(+)
 create mode 100644 videosite/WimpGrabber.pm

diff --git a/videosite/WimpGrabber.pm b/videosite/WimpGrabber.pm
new file mode 100644
index 0000000..8d37766
--- /dev/null
+++ b/videosite/WimpGrabber.pm
@@ -0,0 +1,88 @@
+# (c) 2009 by Ralf Ertzinger <ralf@camperquake.de>
+# licensed under GNU GPL v2
+#
+# Grabber for wimp.com
+
+package videosite::WimpGrabber;
+
+use videosite::GrabberBase;
+@ISA = qw(videosite::GrabberBase);
+
+use LWP::Simple qw(!get);
+use HTML::Parser;
+use Data::Dumper;
+
+use strict;
+
+sub new {
+    my $class = shift;
+    my $self = $class->SUPER::new();
+
+    $self->{'NAME'} = 'wimp';
+    $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*wimp.com/([^/]+)/?)'];
+
+    bless($self, $class);
+
+    $self->_prepare_parameters();
+
+    return $self;
+}
+
+sub _parse {
+    my $self = shift;
+    my $url = shift;
+    my $pattern = shift;
+    my $content;
+    my $metadata = {};
+    my $p = HTML::Parser->new(api_version => 3);
+    my @accum;
+    my @text;
+    my $e;
+
+    $url =~ m|$pattern|;
+    $url = $1;
+
+    $metadata->{'URL'} = $url;
+    $metadata->{'ID'} = $2;
+    $metadata->{'TYPE'} = 'video';
+    $metadata->{'SOURCE'} = $self->{'NAME'};
+    $metadata->{'TITLE'} = undef;
+    $metadata->{'DLURL'} = undef;
+
+    unless(defined($content = LWP::Simple::get(sprintf('http://www.wimp.com/%s', $2)))) {
+        $self->error('Could not download %s', $url);
+        return undef;
+    }
+
+    $p->handler(start => \@accum, "tagname, attr");
+    $p->handler(text => \@text, "text");
+    $p->report_tags(qw(meta script));
+    $p->utf8_mode(1);
+    $p->parse($content);
+
+    # Look for the title in the meta tags
+    foreach $e (@accum) {
+        if ('meta' eq $e->[0]) {
+            if ('description' eq $e->[1]->{'name'}) {
+                $metadata->{'TITLE'} = $e->[1]->{'content'};
+                last;
+            }
+        }
+    }
+
+    # Look for the download URL
+    foreach $e (@text) {
+        if ($e->[0] =~ m|\.addVariable\("file",\s*"([^\x22]+)"\)|) {
+            $metadata->{'DLURL'} = $1;
+        }
+    }
+
+    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
+        $self->error('Could not determine download URL');
+        return undef;
+    }
+
+    return $metadata;
+}
+
+1;
-- 
1.8.3.1