# autodisplay quotes from quotesites
#
# (c) 2007-2008 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2

use strict;
use Irssi 20020324 qw (command_bind command_runsub signal_add_first signal_add_last);
use vars qw($VERSION %IRSSI);
use XML::Simple;
use Data::Dumper;
use File::Spec;

my @grabbers;
my $conf;
my $conffile = File::Spec->catfile(Irssi::get_irssi_dir(), 'quotesite.xml');
my $plugindir = File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts', 'quotesite');

my $PARAMS = {
};


# activate debug here
my $debug = 1;

# "message public", SERVER_REC, char *msg, char *nick, char *address, char *target
signal_add_last("message public" => sub {check_for_link(\@_,1,4,2,0);});
# "message own_public", SERVER_REC, char *msg, char *target
signal_add_last("message own_public" => sub {check_for_link(\@_,1,2,-1,0);});

# "message private", SERVER_REC, char *msg, char *nick, char *address
signal_add_last("message private" => sub {check_for_link(\@_,1,-1,2,0);});
# "message own_private", SERVER_REC, char *msg, char *target, char *orig_target
signal_add_last("message own_private" => sub {check_for_link(\@_,1,2,-1,0);});

# "message irc action", SERVER_REC, char *msg, char *nick, char *address, char *target
signal_add_last("message irc action" => sub {check_for_link(\@_,1,4,2,0);});
# "message irc own_action", SERVER_REC, char *msg, char *target
signal_add_last("message irc own_action" => sub {check_for_link(\@_,1,2,-1,0);});

sub write_irssi {
    my $witem = shift;
    my @text = @_;

    $text[0] = 'quotesite: ' . $text[0];

    if (defined $witem) {
        $witem->print(sprintf(shift(@text), @text), MSGLEVEL_CLIENTCRAP);
    } else {
        Irssi::print(sprintf(shift(@text), @text));
    }

}

sub write_debug {
    if ($debug) {
        write_irssi(shift, @_);
    }
}

sub check_for_link {
    my ($signal,$parammessage,$paramchannel,$paramnick,$paramserver) = @_;
    my $server = $signal->[$paramserver];
    my $target = $signal->[$paramchannel];
    my $message = ($parammessage == -1) ? '' : $signal->[$parammessage];
    my $g;
    my $m;
    my $p;


    my $witem;
    if (defined $server) {
        $witem = $server->window_item_find($target);
    } else {
        $witem = Irssi::window_item_find($target);
    }

    # Look if we should ignore this line
    if ($message =~ m,(?:\s|^)/nosave(?:\s|$),) {
        return;
    }

    study($message);

    # Offer the message to all Grabbers in turn
    foreach $g (@grabbers) {
        ($m, $p) = $g->get($message);
        while (defined($m)) {
            write_irssi($witem, '%%R>>> %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'ID'});

            foreach (split(/[\n\r]+/, $m->{'CONTENT'})) {
                write_irssi($witem, '    %%g%s', $_);
            }

            # Remove the matched part from the message and try again (there may be
            # more!)
            $message =~ s/$p//;
            study($message);

            ($m, $p) = $g->get($message);
        }
    }
}

sub cmd_save {

    eval {
        open(CONF, '>'.$conffile) or die 'Could not open config file';
        print CONF XML::Simple::XMLout($conf, KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'});
        close(CONF);
    };
    if ($@) {
        write_irssi(undef, 'Could not save config to %s: %s', ($conffile, $@));
    } else {
        write_irssi(undef, 'configuration saved to %s', $conffile);
    }
}

sub cmd_set {
    my $target = shift;
    my $key = shift;
    my $val = shift;
    my $p;

    foreach $p (@grabbers) {
        if ($p->{'NAME'} eq $target) {
            $p->setval($key, $val);
            return;
        }
    }
    write_irssi(undef, 'No such module');
}


sub cmd_enable {
    my $target = shift;
    my $p;

    foreach $p (@grabbers) {
        if ($p->{'NAME'} eq $target) {
            $p->enable();
            return;
        }
    }
    write_irssi(undef, 'No such module');
}


sub cmd_disable {
    my $target = shift;
    my $p;

    foreach $p (@grabbers) {
        if ($p->{'NAME'} eq $target) {
            $p->disable();
            return;
        }
    }
    write_irssi(undef, 'No such module');
}


sub cmd_show {
    my $target = shift;
    my $p;
    my $e;

    if (defined($target)) {
        foreach $p (@grabbers) {
            if ($p->{'NAME'} eq $target) {
                write_irssi(undef, $p->getconfstr());
                return;
            }
        }
        write_irssi(undef, 'No such module');
    } else {
        write_irssi(undef, 'Loaded grabbers (* denotes enabled modules):');
        foreach $p (@grabbers) {
            $e = $p->_getval('enabled');
            write_irssi(undef, ' %s%s', $p->{'NAME'}, $e?'*':'');
        };
    }
}

sub cmd_help {
    my $target = shift;
    my $p;

    if (defined($target)) {
        foreach $p (@grabbers) {
            if ($p->{'NAME'} eq $target) {
                write_irssi(undef, $p->gethelpstr());
                return;
            }
        }
        write_irssi(undef, 'No such module');
    } else {
        write_irssi(undef, <<'EOT');
Supported commands:
 save: Save the current configuration
 help [modulename]: Display this help, or module specific help
 show [modulename]: Show loaded modules, or the current parameters of a module
 set modulename parameter value: set a module parameter to a new value
 enable [modulename]: enable the usage of this module (grabbers only)
 disable [modulename]: disable the usage of this module (grabbers only)
 reload: reload all modules (this is somewhat experimental)
 debug: enable debugging messages
 nodebug: disable debugging messages
EOT
    }
}

# save on unload
sub sig_command_script_unload {
    my $script = shift;
    if ($script =~ /(.*\/)?quotesite(\.pl)?$/) {
        cmd_save();
    }
}

sub ploader {

    my $dir = shift;
    my $pattern = shift;
    my $type = shift;
    my @list;
    my $p;
    my $g;
    my @g = ();

    opendir(D, $dir) || return ();
    @list = grep {/$pattern/ && -f File::Spec->catfile($dir, $_) } readdir(D);
    closedir(D);

    foreach $p (@list) {
        write_debug(undef, "Trying to load $p:");
        $p =~ s/\.pm$//;
        eval qq{ require $p; };
        if ($@) {
            write_debug(undef, "Failed to load plugin: $@");
            next;
        }

        $g = eval $p.q{->new();};
        if ($@) {
            write_debug(undef, "Failed to instanciate: $@");
            delete($INC{$p});
            next;
        }

        write_debug(undef, "found $g->{'TYPE'} $g->{'NAME'}");
        if ($type eq $g->{'TYPE'}) {
            push(@g, $g);
            $g->setio(sub {Irssi::print(shift)});
        } else {
            write_irssi(undef, '%s has wrong type (got %s, expected %s)', $p, $g->{'TYPE'}, $type);
            delete($INC{$p});
        }
    }

    write_debug(undef, "Loaded %d plugins", $#g+1);
    
    return @g;
}

sub _load_modules($) {

    my $path = shift;

    foreach (keys(%INC)) {
        if ($INC{$_} =~ m|^$path|) {
            write_debug(undef, "Removing %s from \$INC", $_);
            delete($INC{$_});
        }
    }
    @grabbers = ploader($path, '.*Grabber\.pm$', 'grabber');
}


sub init_quotesite {

    my $bindings = shift;
    my $p;

    unless(-r $conffile && defined($conf = XML::Simple::XMLin($conffile, ForceArray => ['config', 'option'], KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'}))) {
        # No config, start with an empty one
        write_debug(undef, 'No config found, using defaults');
        $conf = { 'quotesite' => { }};
    }
    foreach (keys(%{$PARAMS})) {
        unless (exists($conf->{'quotesite'}->{$_})) {
            $conf->{'quotesite'}->{$_} = $PARAMS->{$_};
        }
    }

    _load_modules($plugindir);

    unless (defined(@grabbers)) {
        write_irssi(undef, 'No grabbers found, can not proceed.');
        return;
    }


    # Loop through all plugins and load the config
    foreach $p (@grabbers) {
        $conf->{'quotesite'}->{'config'}->{$p->{'NAME'}} = $p->mergeconfig($conf->{'quotesite'}->{'config'}->{$p->{'NAME'}});
    }

    if ($bindings) {

        Irssi::signal_add_first('command script load', 'sig_command_script_unload');
        Irssi::signal_add_first('command script unload', 'sig_command_script_unload');
        Irssi::signal_add('setup saved', 'cmd_save');


        Irssi::command_bind('quotesite' => \&cmdhandler);
    }

    write_irssi(undef, 'quotesite initialized');
}

sub cmdhandler {
    my ($data, $server, $item) = @_;
    my @params = split(/\s+/, $data);

    if ($params[0] eq 'save') {
        cmd_save();
    } elsif ($params[0] eq 'set') {
        shift(@params);
        cmd_set(@params);
    } elsif ($params[0] eq 'show') {
        shift(@params);
        cmd_show(@params);
    } elsif ($params[0] eq 'help') {
        shift(@params);
        cmd_help(@params);
    } elsif ($params[0] eq 'enable') {
        shift(@params);
        cmd_enable(@params);
    } elsif ($params[0] eq 'disable') {
        shift(@params);
        cmd_disable(@params);
    } elsif ($params[0] eq 'reload') {
        init_quotesite(0);
    } elsif ($params[0] eq 'debug') {
        $debug = 1;
        foreach (@grabbers) {
            $_->setdebug(1);
        }
        write_irssi(undef, 'Enabled debugging');
    } elsif ($params[0] eq 'nodebug') {
        $debug = 0;
        foreach (@grabbers) {
            $_->setdebug(0);
        }
        write_irssi(undef, 'Disabled debugging');
    }
}

unshift(@INC, $plugindir);
init_quotesite(1);
