# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
#     2008-2009,2011-2012 by Christian Garbs <mitch@cgarbs.de>
#     2010 by Maximilian Rehkopf <otakon@gmx.net>
#
# licensed under GNU GPL v2
#
# A getter which will download the media to a local file storage
# in the background using wget
#

package videosite::AsyncWgetFileGetter;

use videosite::FileGetter;
@ISA = qw(videosite::FileGetter);

use strict;
use File::Basename;
use File::Temp qw(tempfile);
use MIME::Base64;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new(
        NAME => 'asyncwgetfilegetter',
        @_,
    );

    return bless($self, $class);
}

sub get {
    my $self = shift;
    my $video = shift;
    my $dlfile;
    my $dirname;
    my $cookie = "";
    my $useragent = "--user-agent=Mozilla/5.0";

    $dlfile = sprintf($self->_getval('FILEPATTERN'),
        $self->_encode($video->{'SOURCE'}),
        $self->_encode($video->{'ID'}),
        $self->_encode($video->{'TITLE'}),
        $self->_encode($video->{'DLURL'}),
        $self->_encode($video)->{'URL'});

    $dlfile =~ s/([\\"])/\\$1/g;

    $dirname = dirname($dlfile);
    if ($self->_diskfree($dirname) < $self->_getval('MINFREE')) {
        $self->error("Not enough free space to download");
        return 0;
    }

    $self->debug('Going to download %s to %s', $video->{'DLURL'}, $dlfile);

    my (undef, $tmpfile) = tempfile('videosite.tmp.XXXXXXXXXXXX', DIR => $dirname);

    my %saved_env;
    
    if (exists($video->{'CONNECTOR'})) {
        my $schemas = $video->{'CONNECTOR'}->{'schemas'};
        foreach my $schemakey(keys(%{$schemas})) {
            $self->debug("Setting %s_proxy to %s", $schemakey, $schemas->{$schemakey});
            my $envkey = $schemakey.'_proxy';
            $saved_env{ $envkey } = $ENV{ $envkey };
            $ENV{ $envkey } = $schemas->{$schemakey};
        }
    }
    
    $cookie = "--header=\"Cookie: $video->{'COOKIE'}\"" if (defined $video->{'COOKIE'});
    my $cmdline = "( wget -q -O\"$tmpfile\" $useragent $cookie \"$video->{'DLURL'}\" && mv \"$tmpfile\" \"$dlfile\" && chmod =rw \"$dlfile\" && touch \"$dlfile\" || rm -f \"$tmpfile\" ) &";
    $self->debug("Going to execute: %s", $cmdline);
    system($cmdline);

    # restore environment
    foreach my $envkey (keys %saved_env) {
	$self->debug("Restoring environment: %s=%s", $envkey, $saved_env{ $envkey} );
        $ENV{ $envkey } = $saved_env{ $envkey };
    }

    return 1;
}