# Grabber for collegehumor.com
#
# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2

package videosite::CollegeHumorGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use videosite::HTMLHelper;
use XML::Simple;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new(
        NAME => 'collegehumor',
        _SELFTESTURL => 'http://www.collegehumor.com/video/5635400/pixar-intro-parody',
        _SELFTESTTITLE => 'Pixar Intro Parody',
        PATTERNS => ['(http://www.collegehumor.com/video:(\d+))',
                     '(http://www.collegehumor.com/video/(\d+))'],
        @_,
    );

    return bless($self, $class);
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p = XML::Simple->new();
    my @accum;
    my $t;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    # Get the XML file containing the video metadata
    unless(defined($content = $self->simple_get(sprintf('http://www.collegehumor.com/moogaloop/video/%s', $2)))) {
        $self->error('Could not download XML metadata');
        return undef;
    }

    unless(defined($t = $p->XMLin($content))) {
        $self->error('Could not parse XML metadata');
        return undef;
    }

    $metadata->{'DLURL'} = $t->{'video'}->{'file'};
    $metadata->{'TITLE'} = $t->{'video'}->{'caption'};

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not extract download URL and title');
        return undef;
    }

    return $metadata;
}

1;