# Grabber for dailymotion.com
#
# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2

package videosite::DailyMotionGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use HTML::Parser;
use videosite::JSArrayParser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new();

    $self->{'NAME'} = 'dailymotion';
    $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*dailymotion.com/(?:[^/]+/)*video/([-a-zA-Z0-9_]+))'];

    bless($self, $class);

    $self->_prepare_parameters();

    return $self;
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p = HTML::Parser->new(api_version => 3);
    my @accum;
    my @text;
    my $e;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = $self->simple_get(sprintf('http://www.dailymotion.com/video/%s', $2)))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    $p->handler(start => \@accum, "tagname, attr");
    $p->handler(text => \@text, "text");
    $p->report_tags(qw(meta script));
    $p->utf8_mode(1);
    $p->parse($content);

    # Look for the title in the meta tags
    foreach $e (@accum) {
        if ('meta' eq $e->[0]) {
            if ('title' eq $e->[1]->{'name'}) {
                $metadata->{'TITLE'} = $e->[1]->{'content'};
                $metadata->{'TITLE'} =~ s/^Dailymotion\s+-\s+//;
                $metadata->{'TITLE'} =~ s/(?:\s+-\s+.*)?$//;
            }
        }
    }

    # Look for the download URL
    foreach $e (@text) {
        if ($e->[0] =~ m|\.addVariable\("sequence",\s*"([^\"]+)"|) {
            my $sequence = $1;
            my $jsp = videosite::JSArrayParser->new();
            my $l;
            my $s;

            $sequence =~ s/%(..)/chr(hex($1))/ge;
            $self->debug("Found sequence: %s", $sequence);

            $self->debug("Using %s to parse", ref($jsp));
            $sequence = $jsp->parse($sequence);
            $self->debug(Dumper($sequence));

            unless(defined($sequence)) {
                $self->error("Found sequence, but could not parse");
                return undef;
            } else {
                $self->debug("Parsed sequence: %s", Dumper($sequence));

                $l = $self->_fetch_layer($sequence, "root/layerList", "background/sequenceList", "main/layerList", "video/param");
                unless(defined($l)) {
                    $self->error("Could not find video layer");
                    return undef;
                }

                # Found video section
                if (exists($l->{'videoPluginParameters'}->{'hdURL'})) {
                    $metadata->{'DLURL'} = $l->{'videoPluginParameters'}->{'hdURL'};
                } elsif (exists($l->{'videoPluginParameters'}->{'hqURL'})) {
                    $metadata->{'DLURL'} = $l->{'videoPluginParameters'}->{'hqURL'};
                } elsif (exists($l->{'videoPluginParameters'}->{'hqURL'})) {
                    $metadata->{'DLURL'} = $l->{'videoPluginParameters'}->{'sdURL'};
                } else {
                    $self->error("Video section found, but no URLs");
                    return undef;
                }
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

sub _fetch_layer {
    my $self = shift;
    my $sequence = shift;
    my $point = shift;
    my $next;
    my @points = @_;
    my $l;

    $self->debug("Looking for %s in %s", $point, Dumper($sequence));

    unless(defined($point)) {
        $self->debug("Reached last point");
        return $sequence;
    }
    ($point, $next) = split(/\//, $point, 2);

    foreach (@{$sequence}) {
        if (exists($_->{'name'}) and ($_->{'name'} eq $point)) {
            if (exists($_->{$next})) {
                $self->debug("Using %s in %s", $next, $point);
                return $self->_fetch_layer($_->{$next}, @points);
            } else {
                $self->debug("%s found, but no %s", $point, $next);
                return undef;
            }

        }
    }

    $self->debug("Could not find entry named %s", $point);
    return undef;
}

1;