# Grabber for dailymotion.com
#
# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2

package videosite::DailyMotionGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use HTML::TokeParser;
use videosite::JSArrayParser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new(
        NAME => 'dailymotion',
        _SELFTESTURL => 'http://www.dailymotion.com/video/xylv6u_moon-duo-sleepwalker_music',
        _SELFTESTTITLE => 'Moon Duo - Sleepwalker',
        PATTERNS => ['(http://(?:[-a-zA-Z0-9_.]+\.)*dailymotion.com/(?:[^/]+/)*video/([-a-zA-Z0-9_]+))'],
        @_,
    );

    return bless($self, $class);
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p;
    my @accum;
    my @text;
    my $e;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = $self->simple_get(sprintf('http://www.dailymotion.com/video/%s', $2)))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    $p = HTML::TokeParser->new(\$content);

    # Look for the title in the meta tags
    while ($e = $p->get_tag('meta', 'script')) {
        if ('meta' eq $e->[0]) {
            if (exists($e->[1]->{'property'}) && ('og:title' eq $e->[1]->{'property'})) {
                $metadata->{'TITLE'} = $e->[1]->{'content'};
            }
        } elsif ('script' eq $e->[0]) {
            my $c = $p->get_text();

            $self->debug("Found script: %s", $c);

            if ($c =~ m|flashvars = (.+);$|m) {
                my $flashvars = $1;
                my $jsp = videosite::JSArrayParser->new();
                my $l;
                my $s;
                my $sequence;

                $self->debug("Found flashvars: %s", $flashvars);

                $self->debug("Using %s to parse", ref($jsp));
                $flashvars = $jsp->parse($flashvars);
                $self->debug("Parsed flashvars: %s", Dumper($flashvars));

                $sequence = $flashvars->{'sequence'};
                $sequence =~ s/%(..)/chr(hex($1))/ge;

                $self->debug("Decoded sequence: %s", $sequence);
                $sequence =  $jsp->parse($sequence);

                unless(defined($sequence)) {
                    $self->error("Found sequence, but could not parse");
                    return undef;
                } else {
                    $self->debug("Parsed sequence: %s", Dumper($sequence));

                    $l = $self->_fetch_layer($sequence->{'sequence'}, "root/layerList", "background/sequenceList", "main/layerList", "video/param");
                    unless(defined($l)) {
                        $self->error("Could not find video layer");
                        return undef;
                    }

                    # Found video section
                    if (exists($l->{'hd1080URL'})) {
                        $metadata->{'DLURL'} = $l->{'hd1080URL'};
                    } elsif (exists($l->{'hd720URL'})) {
                        $metadata->{'DLURL'} = $l->{'hd720URL'};
                    } elsif (exists($l->{'hqURL'})) {
                        $metadata->{'DLURL'} = $l->{'hqURL'};
                    } elsif (exists($l->{'sdURL'})) {
                        $metadata->{'DLURL'} = $l->{'sdURL'};
                    } elsif (exists($l->{'ldURL'})) {
                        $metadata->{'DLURL'} = $l->{'ldURL'};
                    } else {
                        $self->error("Video section found, but no URLs");
                        return undef;
                    }
                }
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

sub _fetch_layer {
    my $self = shift;
    my $sequence = shift;
    my $point = shift;
    my $next;
    my @points = @_;
    my $l;

    $self->debug("Looking for %s in %s", $point, Dumper($sequence));

    unless(defined($point)) {
        $self->debug("Reached last point");
        return $sequence;
    }
    ($point, $next) = split(/\//, $point, 2);

    foreach (@{$sequence}) {
        if (exists($_->{'name'}) and ($_->{'name'} eq $point)) {
            if (exists($_->{$next})) {
                $self->debug("Using %s in %s", $next, $point);
                return $self->_fetch_layer($_->{$next}, @points);
            } else {
                $self->debug("%s found, but no %s", $point, $next);
                return undef;
            }

        }
    }

    $self->debug("Could not find entry named %s", $point);
    return undef;
}

1;