# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for myvideo.de

package videosite::MyVideoGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use HTML::Parser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new(
        NAME => 'myvideo',
        PATTERNS => ['(http://(?:[-a-zA-Z0-9_.]+\.)*myvideo.de/watch/(\d+))'],
        @_,
    );

    return bless($self, $class);
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p = HTML::Parser->new(api_version => 3);
    my @accum;
    my @text;
    my $e;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = $self->simple_get(sprintf('http://www.myvideo.de/watch/%s', $2)))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    $p->handler(start => \@accum, "tagname, attr");
    $p->report_tags(qw(meta link));
    $p->utf8_mode(1);
    $p->parse($content);

    # Look for the title in the meta tags
    foreach $e (@accum) {
        if ('meta' eq $e->[0]) {
            if ('title' eq $e->[1]->{'name'}) {
                $metadata->{'TITLE'} = $e->[1]->{'content'};
                $metadata->{'TITLE'} =~ s/\s+Video\s+-\s+\S+\s+-\s+MyVideo$//;
                $self->debug("Found title: %s", $metadata->{'TITLE'});
                last;
            }
        }
    }

    # Look for the download URL
    foreach $e (@accum) {
        if ('link' eq $e->[0]) {
            if (exists($e->[1]->{'rel'}) and ('image_src' eq $e->[1]->{'rel'})) {
                $metadata->{'DLURL'} = $e->[1]->{'href'};
                $metadata->{'DLURL'} =~ s,thumbs/[^/]*$,,;
                $metadata->{'DLURL'} .= $metadata->{'ID'} . ".flv";
                $self->debug("Found URL: %s", $metadata->{'DLURL'});
                last;
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

1;