# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for myvideo.de

package videosite::MyVideoGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use HTML::TokeParser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new(
        NAME => 'myvideo',
        _SELFTESTURL => 'http://www.myvideo.de/watch/9191174/Battle_Worlds_Kronos_Alpha_Version_ausprobiert',
        _SELFTESTTITLE => 'Battle Worlds: Kronos - Alpha-Version ausprobiert',
        PATTERNS => ['(http://(?:[-a-zA-Z0-9_.]+\.)*myvideo.de/watch/(\d+))'],
        @_,
    );

    return bless($self, $class);
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p;
    my $t;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = $self->simple_get(sprintf('http://www.myvideo.de/watch/%s', $2)))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    $p = HTML::TokeParser->new(\$content);
    while ($t = $p->get_tag('meta', 'link')) {
        if ('meta' eq $t->[0]) {
            if (exists($t->[1]->{property}) and ($t->[1]->{property} eq 'og:title')) {
                $metadata->{'TITLE'} = $t->[1]->{content};
            }
        } elsif ('link' eq $t->[0]) {
            if (exists($t->[1]->{rel}) and ($t->[1]->{rel} eq 'image_src')) {
                $metadata->{'DLURL'} = $t->[1]->{'href'};
                $metadata->{'DLURL'} =~ s,thumbs/[^/]*$,,;
                $metadata->{'DLURL'} .= $metadata->{'ID'} . ".flv";
                $self->debug("Found URL: %s", $metadata->{'DLURL'});
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

1;