# (c) 2009 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for veoh.com

package videosite::VeohGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use HTML::TokeParser;
use Data::Dumper;
use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new(
        NAME => 'veoh',
        _SELFTESTURL => 'http://www.veoh.com/watch/v18348952fyn2twbe',
        _SELFTESTTITLE => '518_2 kureyon shinchan',
        PATTERNS => ['(http://(?:[-a-zA-Z0-9_.]+\.)*veoh.com/+watch/(\w+)\??)'],
        @_,
    );

    return bless($self, $class);
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $ua = $self->ua();
    my $p;
    my $t;
    my @text;
    my @accum;
    my $dlurl;
    my $r;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = $self->simple_get(sprintf('http://www.veoh.com/watch/%s', $2), $ua))) {
        $self->error('Could not download');
        return undef;
    }

    $p = HTML::TokeParser->new(\$content);

    while ($t = $p->get_tag('script')) {
        if ($t->[0] eq 'script') {
            my $e = $p->get_text();
            my $jsp;

            if ($e =~ m|__watch.videoDetailsJSON = '([^\x27]+)|) {
                $self->debug("Found JSON: %s", $1);
                $jsp = videosite::JSArrayParser->new();
                $r = $jsp->parse($1);

                unless(defined($r)) {
                    $self->error("Found information hash, but could not parse");
                    return undef;
                }

                $self->debug("Parsed JSON: %s", Dumper($r));

                unless(exists($r->{previewUrl})) {
                    $self->error("previewUrl not found in information hash");
                    return undef;
                }

                $metadata->{'DLURL'} = $r->{previewUrl};
                $metadata->{'TITLE'} = $r->{title};
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not extract download URL and title');
        return undef;
    }

    return $metadata;
}

1;