# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for vimeo.com

package videosite::VimeoGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use HTML::TokeParser;
use videosite::JSArrayParser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new(
        NAME => 'vimeo',
        _SELFTESTURL => 'http://vimeo.com/35055590',
        _SELFTESTTITLE => 'Hello',
        PATTERNS => ['(http://(?:[-a-zA-Z0-9_.]+\.)*vimeo.com/(?:m/)?(\d+))'],
        @_,
    );

    return bless($self, $class);
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p;
    my $e;
    my $dlurl;
    my $hd;
    my $dlpath;
    my $timestamp;
    my $hash;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    # Get the XML file containing the video metadata
    unless(defined($content = $self->simple_get(sprintf('http://vimeo.com/%s', $2)))) {
        $self->error('Could not download site');
        return undef;
    }

    $p = HTML::TokeParser->new(\$content);

    while ($e = $p->get_tag('script')) {
        if ($e->[0] eq 'script') {
            my $t = $p->get_text();

            if ($t =~ m|clip\d+_\d+ = (.*\});Player|s) {
                my $jsp = videosite::JSArrayParser->new();
                my $r;

                $self->debug("Found raw config: %s", $1);
                $r = $jsp->parse($1);

                unless(defined($r)) {
                    $self->error("Found information hash, but could not parse");
                    return undef;
                }

                $self->debug("Found parsed config: %s", Dumper($r));

                unless(exists($r->{'config'}->{'request'})) {
                    $self->error("Required information not found in hash");
                    return undef;
                }

                $metadata->{'TITLE'} = $r->{'config'}->{'video'}->{'title'};
                $hd = grep { $_ eq 'hd' } @{$r->{'config'}->{'video'}->{'files'}->{'h264'}};
                $self->debug("HD: %d", $hd);
                $r = $r->{'config'}->{'request'};

                $metadata->{'DLURL'} = sprintf("http://%s/play_redirect?clip_id=%d&sig=%s&time=%d&quality=%s&codecs=H264,VP8,VP6",
                        $r->{'player_url'},
                        $metadata->{'ID'},
                        $r->{'signature'},
                        $r->{'timestamp'},
                        $hd?'hd':'sd',
                        );
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not extract download URL and title');
        return undef;
    }

    return $metadata;
}

1;