# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for vimeo.com

package videosite::VimeoGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use LWP::UserAgent;
use XML::Simple;
use Digest::MD5 qw(md5_hex);
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new();

    $self->{'NAME'} = 'vimeo';
    $self->{'PATTERNS'} = ['(http://(?:[-a-zA-Z0-9_.]+\.)*vimeo.com/(\d+))'];

    bless($self, $class);
    $self->_prepare_parameters();

    return $self;
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p = XML::Simple->new();
    my $t;
    my $dlurl;
    my $hd;
    my $dlpath;
    my $timestamp;
    my $hash;
    my $ua = LWP::UserAgent->new(agent => 'Mozilla');

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    # Get the XML file containing the video metadata
    $content = $ua->get(sprintf('http://www.vimeo.com/moogaloop/load/clip:%s', $2));
    unless ($content->is_success()) {
        $self->error('Could not download XML metadata');
        return undef;
    }

    $content = $content->decoded_content();

    unless(defined($t = $p->XMLin($content, KeepRoot => 1))) {
        $self->error('Could not parse XML metadata');
        return undef;
    }

    if (exists($t->{'xml'}->{'video'}->{'isHD'}) and (0 != $t->{'xml'}->{'video'}->{'isHD'})) {
        $self->debug('Selecting HD video');
        $hd = '/?q=hd';
    } else {
        $self->debug('Selecting SD video');
        $hd = '';
    }
    $timestamp = $t->{'xml'}->{'request_signature_expires'};
    $hash = $t->{'xml'}->{'request_signature'};
    $dlurl = sprintf('http://vimeo.com/moogaloop/play/clip:%s/%s/%d%s', $metadata->{'ID'}, $hash, $timestamp, $hd);

    unless(defined($dlurl)) {
        $self->error('No dlurl found in XML');
        return undef;
    }

    # # Vimeo appends a hash to the download URL, in order to thwart people like me.
    # # Unfortunately the algorithm isn't that complicated :)
    # if ($dlurl =~ m|http://bitcast.vimeo.com(.+)|) {
    #     $dlpath = $1;
    #     $timestamp += 1800;
    #     $hash = md5_hex(sprintf('redFiretruck%s?e=%d', $dlpath, $timestamp));
    # } else {
    #     $self->error('Unknown dlurl scheme: %s', $dlurl);
    #     return undef;
    # }

    # $metadata->{'DLURL'} = sprintf('%s?e=%d&h=%s', $dlurl, $timestamp, $hash);
    $metadata->{'DLURL'} = $dlurl;
    $metadata->{'TITLE'} = $t->{'xml'}->{'video'}->{'caption'};

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not extract download URL and title');
        return undef;
    }

    return $metadata;
}

1;