# (c) 2009 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for wimp.com

package videosite::WimpGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use MIME::Base64;
use HTML::Parser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new(
        NAME => 'wimp',
        _SELFTESTURL => 'http://www.wimp.com/insanebuilding/',
        _SELFTESTTITLE => 'Insane building.',
        PATTERNS => ['(http://(?:[-a-zA-Z0-9_.]+\.)*wimp.com/([^/]+)/?)'],
        @_,
    );

    return bless($self, $class);
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p = HTML::Parser->new(api_version => 3);
    my @accum;
    my @text;
    my $e;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = $self->simple_get(sprintf('http://www.wimp.com/%s', $2)))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    $p->handler(start => \@accum, "tagname, attr");
    $p->handler(text => \@text, "text");
    $p->report_tags(qw(meta script));
    $p->utf8_mode(1);
    $p->parse($content);

    # Look for the title in the meta tags
    foreach $e (@accum) {
        if ('meta' eq $e->[0] and exists($e->[1]->{'name'})) {
            if ('description' eq $e->[1]->{'name'}) {
                $metadata->{'TITLE'} = $e->[1]->{'content'};
                last;
            }
        }
    }

    # Look for the download URL
    # This is obfuscated a little bit.
    foreach $e (@text) {
        if ($e->[0] =~ m|var googleCode = '([^\x27]+)'|) {
            my $c = $1;

            $self->debug("Found obfuscated code: %s", $c);
            my $d = decode_base64($c);
            $self->debug("Decoded to: %s", $d);

            if ($d =~ m|\.addVariable\("file",\s*"([^\x22]+)"\)|) {
                $metadata->{'DLURL'} = $1;
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

1;