# (c) 2008 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for video.yahoo.com

package videosite::YahooGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use XML::Simple;
use HTML::Parser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new(
        NAME => 'yahoo',
        PATTERNS => ['(http://video\.yahoo\.com/watch/\d+/(\d+))'],
        @_,
    );

    return bless($self, $class);
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p = XML::Simple->new();
    my $t;
    my @accum;
    my $ua = $self->ua();

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    # Get the XML file containing the video metadata
    unless(defined($content = $self->simple_get(sprintf('http://cosmos.bcst.yahoo.com/up/yep/process/getPlaylistFOP.php?node_id=%s', $2), $ua))) {
        $self->error('Could not download XML metadata');
        return undef;
    }

    # There is no XML header in the data, which makes XML::Simple unhappy
    $content = '<?xml version="1.0" encoding="UTF-8"?>' . $content;

    unless(defined($t = $p->XMLin($content, KeepRoot => 1))) {
        $self->error('Could not parse XML metadata');
        return undef;
    }

    $metadata->{'DLURL'} = $t->{'DATA'}->{'SEQUENCE-ITEM'}->{'STREAM'}->{'APP'} . $t->{'DATA'}->{'SEQUENCE-ITEM'}->{'STREAM'}->{'FULLPATH'};
    $metadata->{'DLURL'} =~ s/\&amp;/\&/g;

    # The XML does not contain the title of the video, for
    # reasons possibly known to some jerk at yahoo.
    # So we'll have to parse the actual HTML, too.
    unless(defined($content = $self->simple_get($url, $ua))) {
        $self->error('Could not download HTML');
        return undef;
    }
    $p = HTML::Parser->new(api_version => 3);

    $p->handler(start => \@accum, "tagname, attr");
    $p->report_tags(qw(meta));
    $p->utf8_mode(1);
    $p->parse($content);

    # Look for the title in the meta tags
    foreach $t (@accum) {
        if ('meta' eq $t->[0]) {
            if (exists($t->[1]->{'name'}) and ('title' eq $t->[1]->{'name'})) {
                $metadata->{'TITLE'} = $t->[1]->{'content'};
                last;
            }
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not extract download URL and title');
        return undef;
    }

    return $metadata;
}

1;