# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for www.escapistmagazine.com/articles/view/editorials/zeropunctuation

package videosite::ZeroPunctuationGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use HTML::TokeParser;
use Data::Dumper;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new();

    $self->{'NAME'} = 'zeropunctuation';
    $self->{'PATTERNS'} = ['(http://www.escapistmagazine.com/articles/view/editorials/zeropunctuation/([-A-Za-z0-9]+))'];

    bless($self, $class);
    $self->_prepare_parameters();

    return $self;
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p;
    my $e;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = $self->simple_get($url))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    $p = HTML::TokeParser->new(\$content);

    # Look for the title
    if ($p->get_tag('title')) {
        $metadata->{'TITLE'} = $p->get_text();
        $metadata->{'TITLE'} =~ s/^The Escapist : Zero Punctuation: (.*)$/$1/im;
    }

    while ($e = $p->get_tag('script')) {
        my $c = $p->get_text();
        if ($c =~ m|var vars = \{file:\x27([^\x27]+)\x27|) {
            $metadata->{'DLURL'} = 'http://' . $1 . '_high.flv';
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

1;