# (c) 2007 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2
#
# Grabber for www.escapistmagazine.com/articles/view/editorials/zeropunctuation

package videosite::ZeroPunctuationGrabber;

use videosite::GrabberBase;
@ISA = qw(videosite::GrabberBase);

use HTML::TokeParser;
use Data::Dumper;
use videosite::JSArrayParser;

use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new(
        NAME => 'zeropunctuation',
        _SELFTESTURL => 'http://www.escapistmagazine.com/videos/view/zero-punctuation/5346-Amy',
        _SELFTESTTITLE =>'Amy',
        PATTERNS => ['(http://www.escapistmagazine.com/videos/view/zero-punctuation/([-A-Za-z0-9]+))'],
        @_,
    );

    return bless($self, $class);
}

sub _parse {
    my $self = shift;
    my $url = shift;
    my $pattern = shift;
    my $content;
    my $metadata = {};
    my $p;
    my $e;
    my $j;
    my $jsp;
    my $r;

    $url =~ m|$pattern|;
    $url = $1;

    $metadata->{'URL'} = $url;
    $metadata->{'ID'} = $2;
    $metadata->{'TYPE'} = 'video';
    $metadata->{'SOURCE'} = $self->{'NAME'};
    $metadata->{'TITLE'} = undef;
    $metadata->{'DLURL'} = undef;

    unless(defined($content = $self->simple_get($url))) {
        $self->error('Could not download %s', $url);
        return undef;
    }

    $p = HTML::TokeParser->new(\$content);

    while ($e = $p->get_tag('div', 'param')) {
        if (($e->[0] eq 'param') and exists($e->[1]->{name}) and ($e->[1]->{name} eq 'flashvars')) {
            my %r = map { $self->decode_hexurl($_) } split(/[&=]/, $e->[1]->{value});

            unless(exists($r{config})) {
                $self->error("config URL not found in flashvars");
                return undef;
            }

            $j = $r{config};
        } elsif (($e->[0] eq 'div') and exists($e->[1]->{itemprop}) and ($e->[1]->{itemprop} eq 'name')) {
            $metadata->{'TITLE'} = $p->get_phrase();
        }
    }

    unless(defined($content = $self->simple_get($j))) {
        $self->error("Could not download %s", $j);
        return undef;
    }

    $jsp = videosite::JSArrayParser->new();
    $r = $jsp->parse($content);

    foreach (@{$r->{playlist}}) {
        if ($_->{eventCategory} eq 'Video') {
            $metadata->{'DLURL'} = $_->{url};
            last;
        }
    }

    unless(defined($metadata->{'DLURL'}) && defined($metadata->{'TITLE'})) {
        $self->error('Could not determine download URL');
        return undef;
    }

    return $metadata;
}

1;