# Talker using RPC over HTTP
#
# (c) 2008 by Ralf Ertzinger <ralf@camperquake.de>
# licensed under GNU GPL v2

package xmlrtorrent::HTTPTalker;
use xmlrtorrent::RTorrentTalkerBase;
@ISA = qw(xmlrtorrent::RTorrentTalkerBase);

use Data::Dumper;
use RPC::XML::Client;
use strict;

sub new {
    my $class = shift;
    my $self = $class->SUPER::new();

    $self->{'NAME'} = 'http';
    $self->{'DESC'} = 'talker using RPC over HTTP';
    $self->{'_PARAMS'} = {
        'XMLURL' => ['', 'URL of SCGI script'],
        'USERNAME' => ['', 'username for RPC credentials (optional)'],
        'PASSWORD' => ['', 'password for RPC credentials (optional)'],
    };
    $self->{'_LASTXMLURL'} = undef;

    bless($self, $class);

    $self->_prepare_parameters();

    return $self;
}

sub send_request {
    my $self = shift;
    my @params = @_;

    my $xmlurl = $self->_getval('XMLURL');

    unless (defined($xmlurl) and $xmlurl ne '') {
        return 'http talker: XMLURL not set';
    }

    if ($xmlurl ne $self->{'_LASTXMLURL'}) {
        $self->{'_LASTXMLURL'} = $xmlurl;
        $self->{'__RPCClient'} = RPC::XML::Client->new($xmlurl);
    }	
    
    my $username = $self->_getval('USERNAME');
    my $password = $self->_getval('PASSWORD');

    if (defined $username and defined $password and $username ne '') {
        # mitch: let me guess, the realm must be configurable, too!
        $self->{'__RPCClient'}->credentials('', $username, $password);
    }

    return $self->{'__RPCClient'}->send_request(@params);
}

1;