videosite.pl

   1 # autodownload flash videos
   2 #
   3 # (c) 2007-2008 by Ralf Ertzinger <ralf@camperquake.de>
   4 # licensed under GNU GPL v2
   5 #
   6 # Based on youtube.pl by Christian Garbs <mitch@cgarbs.de>
   7 # which in turn is
   8 # based on trigger.pl by Wouter Coekaerts <wouter@coekaerts.be>
   9
  10 use strict;
  11 use Irssi 20020324 qw (command_bind command_runsub signal_add_first signal_add_last);
  12 use vars qw($VERSION %IRSSI);
  13 use XML::Simple;
  14 use Data::Dumper;
  15 use File::Spec;
  16
  17 my @grabbers;
  18 my @getters;
  19 my $getter;
  20 my $conf;
  21 my $conffile = File::Spec->catfile(Irssi::get_irssi_dir(), 'videosite.xml');
  22 my $plugindir = File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts', 'videosite');
  23
  24 # activate debug here
  25 my $debug = 0;
  26
  27 # "message public", SERVER_REC, char *msg, char *nick, char *address, char *target
  28 signal_add_last("message public" => sub {check_for_link(\@_,1,4,2,0);});
  29 # "message own_public", SERVER_REC, char *msg, char *target
  30 signal_add_last("message own_public" => sub {check_for_link(\@_,1,2,-1,0);});
  31
  32 # "message private", SERVER_REC, char *msg, char *nick, char *address
  33 signal_add_last("message private" => sub {check_for_link(\@_,1,-1,2,0);});
  34 # "message own_private", SERVER_REC, char *msg, char *target, char *orig_target
  35 signal_add_last("message own_private" => sub {check_for_link(\@_,1,2,-1,0);});
  36
  37 # "message irc action", SERVER_REC, char *msg, char *nick, char *address, char *target
  38 signal_add_last("message irc action" => sub {check_for_link(\@_,1,4,2,0);});
  39 # "message irc own_action", SERVER_REC, char *msg, char *target
  40 signal_add_last("message irc own_action" => sub {check_for_link(\@_,1,2,-1,0);});
  41
  42 sub write_irssi {
  43     my $witem = shift;
  44     my @text = @_;
  45
  46     $text[0] = 'videosite: ' . $text[0];
  47
  48     if (defined $witem) {
  49         $witem->print(sprintf(shift(@text), @text), MSGLEVEL_CLIENTCRAP);
  50     } else {
  51         Irssi::print(sprintf(shift(@text), @text));
  52     }
  53
  54 }
  55
  56 sub write_debug {
  57     if ($debug) {
  58         write_irssi(shift, @_);
  59     }
  60 }
  61
  62 sub check_for_link {
  63     my ($signal,$parammessage,$paramchannel,$paramnick,$paramserver) = @_;
  64     my $server = $signal->[$paramserver];
  65     my $target = $signal->[$paramchannel];
  66     my $message = ($parammessage == -1) ? '' : $signal->[$parammessage];
  67     my $g;
  68     my $m;
  69
  70
  71     my $witem;
  72     if (defined $server) {
  73         $witem = $server->window_item_find($target);
  74     } else {
  75         $witem = Irssi::window_item_find($target);
  76     }
  77
  78     # Look if we should ignore this line
  79     if ($message =~ m,(?:\s|^)/nosave(?:\s|$),) {
  80         return;
  81     }
  82
  83     # Offer the message to all Grabbers in turn
  84     foreach $g (@grabbers) {
  85         if (defined($m = $g->get($message))) {
  86             write_debug($witem, 'Metadata: %s', Dumper($m));
  87             write_irssi($witem, '%%R>>> %%NSaving %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
  88             unless($getter->get($m)) {
  89                 write_irssi($witem, '%%R>>> FAILED');
  90             }
  91         }
  92     }
  93 }
  94
  95 sub cmd_save {
  96
  97     eval {
  98         open(CONF, '>'.$conffile) or die 'Could not open config file';
  99         print CONF XML::Simple::XMLout($conf, KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'});
 100         close(CONF);
 101     };
 102     if ($@) {
 103         write_irssi(undef, 'Could not save config to %s: %s', ($conffile, $@));
 104     } else {
 105         write_irssi(undef, 'configuration saved to %s', $conffile);
 106     }
 107 }
 108
 109 sub cmd_set {
 110     my $target = shift;
 111     my $key = shift;
 112     my $val = shift;
 113     my $p;
 114
 115     foreach $p (@getters, @grabbers) {
 116         if ($p->{'NAME'} eq $target) {
 117             $p->setval($key, $val);
 118             return;
 119         }
 120     }
 121     write_irssi(undef, 'No such module');
 122 }
 123
 124
 125 sub cmd_enable {
 126     my $target = shift;
 127     my $p;
 128
 129     foreach $p (@grabbers) {
 130         if ($p->{'NAME'} eq $target) {
 131             $p->enable();
 132             return;
 133         }
 134     }
 135     write_irssi(undef, 'No such module');
 136 }
 137
 138
 139 sub cmd_disable {
 140     my $target = shift;
 141     my $p;
 142
 143     foreach $p (@grabbers) {
 144         if ($p->{'NAME'} eq $target) {
 145             $p->disable();
 146             return;
 147         }
 148     }
 149     write_irssi(undef, 'No such module');
 150 }
 151
 152
 153 sub cmd_show {
 154     my $target = shift;
 155     my $p;
 156     my $e;
 157
 158     if (defined($target)) {
 159         foreach $p (@getters, @grabbers) {
 160             if ($p->{'NAME'} eq $target) {
 161                 write_irssi(undef, $p->getconfstr());
 162                 return;
 163             }
 164         }
 165         write_irssi(undef, 'No such module');
 166     } else {
 167         write_irssi(undef, 'Loaded grabbers (* denotes enabled modules):');
 168         foreach $p (@grabbers) {
 169             $e = $p->_getval('enabled');
 170             write_irssi(undef, ' %s%s', $p->{'NAME'}, $e?'*':'');
 171         };
 172
 173         write_irssi(undef, 'Loaded getters:');
 174         foreach $p (@getters) {
 175             write_irssi(undef, ' %s', $p->{'NAME'});
 176         };
 177     }
 178 }
 179
 180 sub cmd_help {
 181     my $target = shift;
 182     my $p;
 183
 184     if (defined($target)) {
 185         foreach $p (@getters, @grabbers) {
 186             if ($p->{'NAME'} eq $target) {
 187                 write_irssi(undef, $p->gethelpstr());
 188                 return;
 189             }
 190         }
 191         write_irssi(undef, 'No such module');
 192     } else {
 193         write_irssi(undef, <<'EOT');
 194 Supported commands:
 195  save: Save the current configuration
 196  help [modulename]: Display this help, or module specific help
 197  show [modulename]: Show loaded modules, or the current parameters of a module
 198  set modulename parameter value: set a module parameter to a new value
 199  getter [modulename]: display or set the getter to use
 200  enable [modulename]: enable the usage of this module (grabbers only)
 201  disable [modulename]: disable the usage of this module (grabbers only)
 202  reload: reload all modules (this is somewhat experimental)
 203  debug: enable debugging messages
 204  nodebug: disable debugging messages
 205 EOT
 206     }
 207 }
 208
 209 sub cmd_getter {
 210     my $target = shift;
 211     my $p;
 212
 213     if (defined($target)) {
 214         foreach $p (@getters, @grabbers) {
 215             if (($p->{'NAME'} eq $target) && ($p->{'TYPE'} eq 'getter')) {
 216                 $getter = $p;
 217                 $conf->{'videosite'}->{'getter'} = $target;
 218                 return;
 219             }
 220         }
 221         write_irssi(undef, 'No such getter');
 222     } else {
 223         write_irssi(undef, 'Current getter: %s', $conf->{'videosite'}->{'getter'});
 224     }
 225 }
 226
 227
 228 # save on unload
 229 sub sig_command_script_unload {
 230     my $script = shift;
 231     if ($script =~ /(.*\/)?videosite(\.pl)?$/) {
 232         cmd_save();
 233     }
 234 }
 235
 236 sub ploader {
 237
 238     my $dir = shift;
 239     my $pattern = shift;
 240     my $type = shift;
 241     my @list;
 242     my $p;
 243     my $g;
 244     my @g = ();
 245
 246     opendir(D, $dir) || return ();
 247     @list = grep {/$pattern/ && -f File::Spec->catfile($dir, $_) } readdir(D);
 248     closedir(D);
 249
 250     foreach $p (@list) {
 251         write_debug(undef, "Trying to load $p:");
 252         $p =~ s/\.pm$//;
 253         eval qq{ require $p; };
 254         if ($@) {
 255             write_debug(undef, "Failed to load plugin: $@");
 256             next;
 257         }
 258
 259         $g = eval $p.q{->new();};
 260         if ($@) {
 261             write_debug(undef, "Failed to instanciate: $@");
 262             delete($INC{$p});
 263             next;
 264         }
 265
 266         write_debug(undef, "found $g->{'TYPE'} $g->{'NAME'}");
 267         if ($type eq $g->{'TYPE'}) {
 268             push(@g, $g);
 269         } else {
 270             write_irssi(undef, '%s has wrong type (got %s, expected %s)', $p, $g->{'TYPE'}, $type);
 271             delete($INC{$p});
 272         }
 273     }
 274
 275     write_debug(undef, "Loaded %d plugins", $#g+1);
 276
 277     return @g;
 278 }
 279
 280 sub _load_modules($) {
 281
 282     my $path = shift;
 283
 284     foreach (keys(%INC)) {
 285         if ($INC{$_} =~ m|^$path|) {
 286             write_debug(undef, "Removing %s from \$INC", $_);
 287             delete($INC{$_});
 288         }
 289     }
 290     @grabbers = ploader($path, '.*Grabber\.pm$', 'grabber');
 291     @getters = ploader($path, '.*Getter\.pm$', 'getter');
 292 }
 293
 294
 295 sub init_videosite {
 296
 297     my $bindings = shift;
 298     my $p;
 299
 300     unless(-r $conffile && defined($conf = XML::Simple::XMLin($conffile, ForceArray => ['config', 'option'], KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'}))) {
 301         # No config, start with an empty one
 302         write_debug(undef, 'No config found, using defaults');
 303         $conf = { 'videosite' => { 'getter' => '' }};
 304     }
 305
 306     _load_modules($plugindir);
 307
 308     unless (defined(@grabbers) && defined(@getters)) {
 309         write_irssi(undef, 'No grabbers or no getters found, can not proceed.');
 310         return;
 311     }
 312
 313     $getter = $getters[0];
 314     foreach $p (@getters) {
 315         if ($conf->{'videosite'}->{'getter'} eq $p->{'NAME'}) {
 316             $getter = $p;
 317         }
 318     }
 319     write_debug(undef, 'Selected %s as getter', $getter->{'NAME'});
 320     $conf->{'videosite'}->{'getter'} = $getter->{'NAME'};
 321
 322     # Loop through all plugins and load the config
 323     foreach $p (@grabbers, @getters) {
 324         $conf->{'videosite'}->{'config'}->{$p->{'NAME'}} = $p->mergeconfig($conf->{'videosite'}->{'config'}->{$p->{'NAME'}});
 325     }
 326
 327     if ($bindings) {
 328
 329         Irssi::signal_add_first('command script load', 'sig_command_script_unload');
 330         Irssi::signal_add_first('command script unload', 'sig_command_script_unload');
 331         Irssi::signal_add('setup saved', 'cmd_save');
 332
 333
 334         Irssi::command_bind('videosite' => \&cmdhandler);
 335     }
 336
 337     write_irssi(undef, 'videosite initialized');
 338 }
 339
 340 sub cmdhandler {
 341     my ($data, $server, $item) = @_;
 342     my @params = split(/\s+/, $data);
 343
 344     if ($params[0] eq 'save') {
 345         cmd_save();
 346     } elsif ($params[0] eq 'set') {
 347         shift(@params);
 348         cmd_set(@params);
 349     } elsif ($params[0] eq 'show') {
 350         shift(@params);
 351         cmd_show(@params);
 352     } elsif ($params[0] eq 'help') {
 353         shift(@params);
 354         cmd_help(@params);
 355     } elsif ($params[0] eq 'getter') {
 356         shift(@params);
 357         cmd_getter(@params);
 358     } elsif ($params[0] eq 'enable') {
 359         shift(@params);
 360         cmd_enable(@params);
 361     } elsif ($params[0] eq 'disable') {
 362         shift(@params);
 363         cmd_disable(@params);
 364     } elsif ($params[0] eq 'reload') {
 365         init_videosite(0);
 366     } elsif ($params[0] eq 'debug') {
 367         $debug = 1;
 368         foreach (@grabbers, @getters) {
 369             $_->setdebug(1);
 370         }
 371         write_irssi(undef, 'Enabled debugging');
 372     } elsif ($params[0] eq 'nodebug') {
 373         $debug = 0;
 374         foreach (@grabbers, @getters) {
 375             $_->setdebug(0);
 376         }
 377         write_irssi(undef, 'Disabled debugging');
 378     }
 379 }
 380
 381 unshift(@INC, $plugindir);
 382 init_videosite(1);