videosite.pl

   1 # autodownload flash videos
   2 #
   3 # (c) 2007-2008 by Ralf Ertzinger <ralf@camperquake.de>
   4 # licensed under GNU GPL v2
   5 #
   6 # Based on youtube.pl by Christian Garbs <mitch@cgarbs.de>
   7 # which in turn is
   8 # based on trigger.pl by Wouter Coekaerts <wouter@coekaerts.be>
   9 # This is helena
  10
  11 use strict;
  12 use Irssi 20020324 qw (command_bind command_runsub signal_add_first signal_add_last);
  13 use vars qw($VERSION %IRSSI);
  14 use XML::Simple;
  15 use Data::Dumper;
  16 use File::Spec;
  17 delete($INC{'BettIrssi.pm'});
  18 use BettIrssi qw(_bcb _bcs);
  19
  20 my @grabbers;
  21 my @getters;
  22 my $getter;
  23 my $conf;
  24 my $conffile = File::Spec->catfile(Irssi::get_irssi_dir(), 'videosite.xml');
  25 my $scriptdir = File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts');
  26 my $plugindir = File::Spec->catfile($scriptdir, 'videosite');
  27 my @outputstack = (undef);
  28
  29 my $PARAMS = {
  30     'getter' => '',
  31     'mode' => 'download'
  32 };
  33
  34
  35 # activate debug here
  36 my $debug = 0;
  37
  38 # "message public", SERVER_REC, char *msg, char *nick, char *address, char *target
  39 signal_add_last(_bcs("message public" => sub {check_for_link(@_)}));
  40 # "message own_public", SERVER_REC, char *msg, char *target
  41 signal_add_last(_bcs("message own_public" => sub {check_for_link(@_)}));
  42
  43 # "message private", SERVER_REC, char *msg, char *nick, char *address
  44 signal_add_last(_bcs("message private" => sub {check_for_link(@_)}));
  45 # "message own_private", SERVER_REC, char *msg, char *target, char *orig_target
  46 signal_add_last(_bcs("message own_private" => sub {check_for_link(@_)}));
  47
  48 # "message irc action", SERVER_REC, char *msg, char *nick, char *address, char *target
  49 signal_add_last(_bcs("message irc action" => sub {check_for_link(@_)}));
  50 # "message irc own_action", SERVER_REC, char *msg, char *target
  51 signal_add_last(_bcs("message irc own_action" => sub {check_for_link(@_)}));
  52
  53 # For tab completion
  54 signal_add_first('complete word', \&sig_complete);
  55
  56 sub push_output {
  57     unshift(@outputstack, shift);
  58 }
  59
  60 sub pop_output {
  61     shift(@outputstack);
  62
  63     @outputstack = (undef) unless (@outputstack);
  64 }
  65
  66 my $videosite_commands = {
  67     'save' => sub {
  68         cmd_save();
  69     },
  70
  71     'set' => sub {
  72         cmd_set(@_);
  73     },
  74
  75     'show' => sub {
  76         cmd_show(@_);
  77     },
  78
  79     'help' => sub {
  80         cmd_help(@_);
  81     },
  82
  83     'getter' => sub {
  84         cmd_getter(@_);
  85     },
  86
  87     'enable' => sub {
  88         cmd_enable(@_);
  89     },
  90
  91     'disable' => sub {
  92         cmd_disable(@_);
  93     },
  94
  95     'reload' => sub {
  96         init_videosite(0);
  97     },
  98
  99     'mode' => sub {
 100         cmd_mode(@_);
 101     },
 102
 103     'debug' => sub {
 104         $debug = 1;
 105         foreach (@grabbers, @getters) {
 106             $_->setdebug(1);
 107         }
 108         write_irssi('Enabled debugging');
 109     },
 110
 111     'nodebug' => sub {
 112         $debug = 0;
 113         foreach (@grabbers, @getters) {
 114             $_->setdebug(0);
 115         }
 116         write_irssi('Disabled debugging');
 117     },
 118 };
 119
 120 sub write_irssi {
 121     my @text = @_;
 122     my $output = $outputstack[0];
 123
 124     my $format = "%%mvideosite: %%n" . shift(@text);
 125
 126     # escape % in parameters from irssi
 127     s/%/%%/g foreach @text;
 128
 129     if (defined $output) {
 130         $output->(sprintf($format, @text), MSGLEVEL_CLIENTCRAP);
 131     } else {
 132         Irssi::print(sprintf($format, @text));
 133     }
 134
 135 }
 136
 137 sub write_debug {
 138     if ($debug) {
 139         write_irssi(@_);
 140     }
 141 }
 142
 143 sub check_for_link {
 144     my $event = shift;
 145     my $message = $event->message();
 146     my $witem = $event->channel();
 147     my $g;
 148     my $m;
 149     my $p;
 150
 151
 152     # Look if we should ignore this line
 153     if ($message =~ m,(?:\s|^)/nosave(?:\s|$),) {
 154         return;
 155     }
 156
 157     study($message);
 158
 159     # Offer the message to all Grabbers in turn
 160     foreach $g (@grabbers) {
 161         ($m, $p) = $g->get($message);
 162         while (defined($m)) {
 163             write_debug('Metadata: %s', Dumper($m));
 164             if ('download' eq ($conf->{'videosite'}->{'mode'})) {
 165                 write_irssi('%%R>>> %%NSaving %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
 166                 unless($getter->get($m)) {
 167                     write_irssi('%%R>>> FAILED');
 168                 }
 169             } elsif ('display' eq ($conf->{'videosite'}->{'mode'})) {
 170                 write_irssi('%%M>>> %%NSaw %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
 171             } else {
 172                 write_irssi('%%R>>> Invalid operation mode');
 173             }
 174
 175             # Remove the matched part from the message and try again (there may be
 176             # more!)
 177             $message =~ s/$p//;
 178             study($message);
 179
 180             ($m, $p) = $g->get($message);
 181         }
 182     }
 183 }
 184
 185 sub cmd_save {
 186
 187     eval {
 188         open(CONF, '>'.$conffile) or die 'Could not open config file';
 189         print CONF XML::Simple::XMLout($conf, KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'});
 190         close(CONF);
 191     };
 192     if ($@) {
 193         write_irssi('Could not save config to %s: %s', ($conffile, $@));
 194     } else {
 195         write_irssi('configuration saved to %s', $conffile);
 196     }
 197 }
 198
 199 sub cmd_set {
 200     my $target = shift;
 201     my $key = shift;
 202     my $val = shift;
 203     my $p;
 204
 205     foreach $p (@getters, @grabbers) {
 206         if ($p->{'NAME'} eq $target) {
 207             $p->setval($key, $val);
 208             return;
 209         }
 210     }
 211     write_irssi('No such module');
 212 }
 213
 214
 215 sub cmd_enable {
 216     my $target = shift;
 217     my $p;
 218
 219     foreach $p (@grabbers) {
 220         if ($p->{'NAME'} eq $target) {
 221             $p->enable();
 222             return;
 223         }
 224     }
 225     write_irssi('No such module');
 226 }
 227
 228
 229 sub cmd_disable {
 230     my $target = shift;
 231     my $p;
 232
 233     foreach $p (@grabbers) {
 234         if ($p->{'NAME'} eq $target) {
 235             $p->disable();
 236             return;
 237         }
 238     }
 239     write_irssi('No such module');
 240 }
 241
 242
 243 sub cmd_show {
 244     my $target = shift;
 245     my $p;
 246     my $e;
 247
 248     if (defined($target)) {
 249         foreach $p (@getters, @grabbers) {
 250             if ($p->{'NAME'} eq $target) {
 251                 write_irssi($p->getconfstr());
 252                 return;
 253             }
 254         }
 255         write_irssi('No such module');
 256     } else {
 257         write_irssi('Loaded grabbers (* denotes enabled modules):');
 258         foreach $p (@grabbers) {
 259             $e = $p->_getval('enabled');
 260             write_irssi(' %s%s', $p->{'NAME'}, $e?'*':'');
 261         };
 262
 263         write_irssi('Loaded getters:');
 264         foreach $p (@getters) {
 265             write_irssi(' %s', $p->{'NAME'});
 266         };
 267     }
 268 }
 269
 270 sub cmd_help {
 271     my $target = shift;
 272     my $p;
 273
 274     if (defined($target)) {
 275         foreach $p (@getters, @grabbers) {
 276             if ($p->{'NAME'} eq $target) {
 277                 write_irssi($p->gethelpstr());
 278                 return;
 279             }
 280         }
 281         write_irssi('No such module');
 282     } else {
 283         write_irssi(<<'EOT');
 284 Supported commands:
 285  save: save the current configuration
 286  help [modulename]: display this help, or module specific help
 287  show [modulename]: show loaded modules, or the current parameters of a module
 288  set modulename parameter value: set a module parameter to a new value
 289  getter [modulename]: display or set the getter to use
 290  enable [modulename]: enable the usage of this module (grabbers only)
 291  disable [modulename]: disable the usage of this module (grabbers only)
 292  reload: reload all modules (this is somewhat experimental)
 293  mode [modename]: display or set the operation mode (download/display)
 294  debug: enable debugging messages
 295  nodebug: disable debugging messages
 296 EOT
 297     }
 298 }
 299
 300 sub cmd_getter {
 301     my $target = shift;
 302     my $p;
 303
 304     if (defined($target)) {
 305         foreach $p (@getters) {
 306             if ($p->{'NAME'} eq $target) {
 307                 $getter = $p;
 308                 $conf->{'videosite'}->{'getter'} = $target;
 309                 return;
 310             }
 311         }
 312         write_irssi('No such getter');
 313     } else {
 314         write_irssi('Current getter: %s', $conf->{'videosite'}->{'getter'});
 315     }
 316 }
 317
 318 sub cmd_mode {
 319     my $mode = shift;
 320
 321     if (defined($mode)) {
 322         $mode = lc($mode);
 323         if (('download' eq $mode) or ('display' eq $mode)) {
 324             $conf->{'videosite'}->{'mode'} = $mode;
 325         } else {
 326             write_irssi('Invalid mode: %s', $mode);
 327         }
 328     } else {
 329         write_irssi('Current mode: %s', $conf->{'videosite'}->{'mode'});
 330     }
 331 }
 332
 333
 334 # save on unload
 335 sub sig_command_script_unload {
 336     my $script = shift;
 337     if ($script =~ /(.*\/)?videosite(\.pl)?$/) {
 338         cmd_save();
 339     }
 340 }
 341
 342 sub ploader {
 343
 344     my $dir = shift;
 345     my $pattern = shift;
 346     my $type = shift;
 347     my @list;
 348     my $p;
 349     my $g;
 350     my @g = ();
 351
 352     opendir(D, $dir) || return ();
 353     @list = grep {/$pattern/ && -f File::Spec->catfile($dir, $_) } readdir(D);
 354     closedir(D);
 355
 356     foreach $p (@list) {
 357         write_debug("Trying to load $p:");
 358         $p =~ s/\.pm$//;
 359         eval qq{ require videosite::$p; };
 360         if ($@) {
 361             write_irssi("Failed to load plugin: $@");
 362             next;
 363         }
 364
 365         $g = eval qq{ videosite::$p->new(); };
 366         if ($@) {
 367             write_irssi("Failed to instanciate: $@");
 368             delete($INC{$p});
 369             next;
 370         }
 371
 372         write_debug("found $g->{'TYPE'} $g->{'NAME'}");
 373         if ($type eq $g->{'TYPE'}) {
 374             push(@g, $g);
 375             $g->setio(\&write_irssi);
 376         } else {
 377             write_irssi('%s has wrong type (got %s, expected %s)', $p, $g->{'TYPE'}, $type);
 378             delete($INC{$p});
 379         }
 380     }
 381
 382     write_debug("Loaded %d plugins", $#g+1);
 383
 384     return @g;
 385 }
 386
 387 sub _load_modules($) {
 388
 389     my $path = shift;
 390
 391     foreach (keys(%INC)) {
 392         if ($INC{$_} =~ m|^$path|) {
 393             write_debug("Removing %s from \$INC", $_);
 394             delete($INC{$_});
 395         }
 396     }
 397     @grabbers = ploader($path, '.*Grabber\.pm$', 'grabber');
 398     @getters = ploader($path, '.*Getter\.pm$', 'getter');
 399 }
 400
 401
 402 sub init_videosite {
 403
 404     my $bindings = shift;
 405     my $p;
 406
 407     unless(-r $conffile && defined($conf = XML::Simple::XMLin($conffile, ForceArray => ['config', 'option'], KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'}))) {
 408         # No config, start with an empty one
 409         write_debug('No config found, using defaults');
 410         $conf = { 'videosite' => { }};
 411     }
 412     foreach (keys(%{$PARAMS})) {
 413         unless (exists($conf->{'videosite'}->{$_})) {
 414             $conf->{'videosite'}->{$_} = $PARAMS->{$_};
 415         }
 416     }
 417
 418     _load_modules($plugindir);
 419
 420     unless (defined(@grabbers) && defined(@getters)) {
 421         write_irssi('No grabbers or no getters found, can not proceed.');
 422         return;
 423     }
 424
 425     $getter = $getters[0];
 426     foreach $p (@getters) {
 427         if ($conf->{'videosite'}->{'getter'} eq $p->{'NAME'}) {
 428             $getter = $p;
 429         }
 430     }
 431     write_debug('Selected %s as getter', $getter->{'NAME'});
 432     $conf->{'videosite'}->{'getter'} = $getter->{'NAME'};
 433
 434     # Loop through all plugins and load the config
 435     foreach $p (@grabbers, @getters) {
 436         $conf->{'videosite'}->{'config'}->{$p->{'NAME'}} = $p->mergeconfig($conf->{'videosite'}->{'config'}->{$p->{'NAME'}});
 437     }
 438
 439     if ($bindings) {
 440
 441         Irssi::signal_add_first('command script load', 'sig_command_script_unload');
 442         Irssi::signal_add_first('command script unload', 'sig_command_script_unload');
 443         Irssi::signal_add('setup saved', 'cmd_save');
 444
 445
 446         Irssi::command_bind(_bcb('videosite' => \&cmdhandler));
 447     }
 448
 449     write_irssi('initialized successfully');
 450 }
 451
 452 sub sig_complete {
 453     my ($complist, $window, $word, $linestart, $want_space) = @_;
 454     my @matches;
 455
 456     if ($linestart !~ m|^/videosite\b|) {
 457         return;
 458     }
 459
 460     if ('/videosite' eq $linestart) {
 461         # No command enterd so far. Produce a list of possible follow-ups
 462         @matches = grep {/^$word/} keys (%{$videosite_commands});
 463     } elsif ('/videosite set' eq $linestart) {
 464         # 'set' command entered. Produce a list of modules
 465         foreach (@grabbers, @getters) {
 466             push(@matches, $_->{'NAME'}) if $_->{'NAME'} =~ m|^$word|;
 467         };
 468     } elsif ($linestart =~ m|^/videosite set (\w+)$|) {
 469         my $module = $1;
 470
 471         foreach my $p (@getters, @grabbers) {
 472             if ($p->{'NAME'} eq $module) {
 473                 @matches = $p->getparamlist($word);
 474                 last;
 475             }
 476         }
 477     } elsif ($linestart =~ m|/videosite set (\w+) (\w+)$|) {
 478         my $module = $1;
 479         my $param = $2;
 480
 481         foreach my $p (@getters, @grabbers) {
 482             if ($p->{'NAME'} eq $module) {
 483                 @matches = $p->getparamvalues($param, $word);
 484                 last;
 485             }
 486         }
 487     }
 488
 489
 490     push(@{$complist}, sort @matches);
 491     ${$want_space} = 0;
 492
 493     Irssi::signal_stop();
 494 }
 495
 496 sub cmdhandler {
 497     my $event = shift;
 498     my ($cmd, @params) = split(/\s+/, $event->message());
 499
 500     if (exists($videosite_commands->{$cmd})) {
 501         $videosite_commands->{$cmd}->(@params);
 502     }
 503 }
 504
 505 unshift(@INC, $scriptdir);
 506 init_videosite(1);