videosite.pl

   1 # autodownload flash videos
   2 #
   3 # (c) 2007-2008 by Ralf Ertzinger <ralf@camperquake.de>
   4 # licensed under GNU GPL v2
   5 #
   6 # Based on youtube.pl by Christian Garbs <mitch@cgarbs.de>
   7 # which in turn is
   8 # based on trigger.pl by Wouter Coekaerts <wouter@coekaerts.be>
   9
  10
  11 BEGIN {
  12     # Get rid of a (possibly old) version of BettIrssi
  13     # This is a hack to prevent having to reload irssi just
  14     # because BettIrssi.pm changed
  15
  16     delete($INC{'BettIrssi.pm'});
  17 }
  18
  19 use strict;
  20 use Irssi 20020324 qw (command_bind command_runsub signal_add_first signal_add_last);
  21 use vars qw($VERSION %IRSSI);
  22 use XML::Simple;
  23 use Data::Dumper;
  24 use File::Spec;
  25 use BettIrssi 101 qw(_bcb _bcs);
  26 use LWP::UserAgent;
  27
  28 my @grabbers;
  29 my @getters;
  30 my $getter;
  31 my $conf;
  32 my $conffile = File::Spec->catfile(Irssi::get_irssi_dir(), 'videosite.xml');
  33 my $scriptdir = File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts');
  34 my $plugindir = File::Spec->catfile($scriptdir, 'videosite');
  35 my @outputstack = (undef);
  36
  37 my $PARAMS = {
  38     'getter' => '',
  39     'mode' => 'download'
  40 };
  41
  42
  43 # activate debug here
  44 my $debug = 0;
  45
  46 # "message public", SERVER_REC, char *msg, char *nick, char *address, char *target
  47 signal_add_last(_bcs("message public" => sub {check_for_link(@_)}));
  48 # "message own_public", SERVER_REC, char *msg, char *target
  49 signal_add_last(_bcs("message own_public" => sub {check_for_link(@_)}));
  50
  51 # "message private", SERVER_REC, char *msg, char *nick, char *address
  52 signal_add_last(_bcs("message private" => sub {check_for_link(@_)}));
  53 # "message own_private", SERVER_REC, char *msg, char *target, char *orig_target
  54 signal_add_last(_bcs("message own_private" => sub {check_for_link(@_)}));
  55
  56 # "message irc action", SERVER_REC, char *msg, char *nick, char *address, char *target
  57 signal_add_last(_bcs("message irc action" => sub {check_for_link(@_)}));
  58 # "message irc own_action", SERVER_REC, char *msg, char *target
  59 signal_add_last(_bcs("message irc own_action" => sub {check_for_link(@_)}));
  60
  61 # For tab completion
  62 # This does not use BettIrssi (yet)
  63 signal_add_first('complete word', \&sig_complete);
  64
  65 sub push_output {
  66     unshift(@outputstack, shift);
  67 }
  68
  69 sub pop_output {
  70     shift(@outputstack);
  71
  72     @outputstack = (undef) unless (@outputstack);
  73 }
  74
  75 my $videosite_commands = {
  76     'save' => sub {
  77         cmd_save();
  78     },
  79
  80     'set' => sub {
  81         cmd_set(@_);
  82     },
  83
  84     'show' => sub {
  85         cmd_show(@_);
  86     },
  87
  88     'help' => sub {
  89         cmd_help(@_);
  90     },
  91
  92     'getter' => sub {
  93         cmd_getter(@_);
  94     },
  95
  96     'enable' => sub {
  97         cmd_enable(@_);
  98     },
  99
 100     'disable' => sub {
 101         cmd_disable(@_);
 102     },
 103
 104     'reload' => sub {
 105         init_videosite(0);
 106     },
 107
 108     'mode' => sub {
 109         cmd_mode(@_);
 110     },
 111
 112     'debug' => sub {
 113         $debug = 1;
 114         foreach (@grabbers, @getters) {
 115             $_->setdebug(1);
 116         }
 117         write_irssi('Enabled debugging');
 118     },
 119
 120     'nodebug' => sub {
 121         $debug = 0;
 122         foreach (@grabbers, @getters) {
 123             $_->setdebug(0);
 124         }
 125         write_irssi('Disabled debugging');
 126     },
 127 };
 128
 129 sub write_irssi {
 130     my @text = @_;
 131     my $output = $outputstack[0];
 132
 133     my $format = "%%mvideosite: %%n" . shift(@text);
 134
 135     # escape % in parameters from irssi
 136     s/%/%%/g foreach @text;
 137
 138     if (defined $output) {
 139         $output->(sprintf($format, @text), MSGLEVEL_CLIENTCRAP);
 140     } else {
 141         Irssi::print(sprintf($format, @text));
 142     }
 143
 144 }
 145
 146 sub write_debug {
 147     if ($debug) {
 148         write_irssi(@_);
 149     }
 150 }
 151
 152 sub expand_url_shortener {
 153     my $s = shift;
 154     my $os = '';
 155     my @urlshortener = (
 156         'is\.gd/[[:alnum:]]+',
 157         'otf\.me/[[:alnum:]]+',
 158         'hel\.me/[[:alnum:]]+',
 159         '7ax\.de/[[:alnum:]]+',
 160         'ow\.ly/[[:alnum:]]+',
 161         'j\.mp/[[:alnum:]]+',
 162         'bit\.ly/[[:alnum:]]+',
 163         'tinyurl\.com/[[:alnum:]]+',
 164         'pop\.is/[[:alnum:]]+',
 165         'post\.ly/[[:alnum:]]+',
 166         );
 167     my $ua = LWP::UserAgent->new(agent => 'Mozilla', max_redirect => 0);
 168     my $i = 10;
 169
 170     OUTER: while (($os ne $s) and ($i > 0)) {
 171         $os = $s;
 172         $i--;
 173
 174         foreach my $pattern (@urlshortener) {
 175             my $p = "https?:\/\/" . $pattern;
 176
 177             write_debug("Matching %s against %s", $p, $s);
 178             if ($s =~ m|($p)|) {
 179                 my $matched = $1;
 180                 my $res;
 181
 182                 write_debug("Found %s", $matched);
 183                 $res = $ua->head($matched);
 184                 if ($res->is_redirect()) {
 185                     my $new = $res->headers()->header("Location");
 186
 187                     write_debug("Replacing %s with %s", $matched, $new);
 188                     $s =~ s/$matched/$new/;
 189                     next OUTER;
 190                 } else {
 191                     write_debug("Error resolving %s", $matched);
 192                 }
 193             }
 194         }
 195     }
 196
 197     if ($i == 0) {
 198         write_debug("Loop terminated by counter");
 199     }
 200
 201     write_debug("Final string: %s", $s);
 202
 203     return $s;
 204 }
 205
 206
 207 sub check_for_link {
 208     my $event = shift;
 209     my $message = $event->message();
 210     my $witem = $event->channel();
 211     my $g;
 212     my $m;
 213     my $p;
 214
 215
 216     # Look if we should ignore this line
 217     if ($message =~ m,(?:\s|^)/nosave(?:\s|$),) {
 218         return;
 219     }
 220
 221     push_output($event->ewpf);
 222     $message = expand_url_shortener($message);
 223
 224     study($message);
 225
 226     # Offer the message to all Grabbers in turn
 227     GRABBER: foreach $g (@grabbers) {
 228         ($m, $p) = $g->get($message);
 229         while (defined($m)) {
 230             write_debug('Metadata: %s', Dumper($m));
 231             if ('download' eq ($conf->{'videosite'}->{'mode'})) {
 232                 write_irssi('%%R>>> %%NSaving %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
 233                 unless($getter->get($m)) {
 234                     write_irssi('%%R>>> FAILED');
 235                 }
 236             } elsif ('display' eq ($conf->{'videosite'}->{'mode'})) {
 237                 write_irssi('%%M>>> %%NSaw %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
 238             } else {
 239                 write_irssi('%%R>>> Invalid operation mode');
 240             }
 241
 242             # Remove the matched part from the message and try again (there may be
 243             # more!)
 244             $message =~ s/$p//;
 245             study($message);
 246             last GRABBER if ($message =~ /^\s*$/);
 247
 248             ($m, $p) = $g->get($message);
 249         }
 250     }
 251
 252     pop_output();
 253 }
 254
 255 sub cmd_save {
 256
 257     eval {
 258         open(CONF, '>'.$conffile) or die 'Could not open config file';
 259         print CONF XML::Simple::XMLout($conf, KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'});
 260         close(CONF);
 261     };
 262     if ($@) {
 263         write_irssi('Could not save config to %s: %s', ($conffile, $@));
 264     } else {
 265         write_irssi('configuration saved to %s', $conffile);
 266     }
 267 }
 268
 269 sub cmd_set {
 270     my $target = shift;
 271     my $key = shift;
 272     my $val = shift;
 273     my $p;
 274
 275     foreach $p (@getters, @grabbers) {
 276         if ($p->{'NAME'} eq $target) {
 277             $p->setval($key, $val);
 278             return;
 279         }
 280     }
 281     write_irssi('No such module');
 282 }
 283
 284
 285 sub cmd_enable {
 286     my $target = shift;
 287     my $p;
 288
 289     foreach $p (@grabbers) {
 290         if ($p->{'NAME'} eq $target) {
 291             $p->enable();
 292             return;
 293         }
 294     }
 295     write_irssi('No such module');
 296 }
 297
 298
 299 sub cmd_disable {
 300     my $target = shift;
 301     my $p;
 302
 303     foreach $p (@grabbers) {
 304         if ($p->{'NAME'} eq $target) {
 305             $p->disable();
 306             return;
 307         }
 308     }
 309     write_irssi('No such module');
 310 }
 311
 312
 313 sub cmd_show {
 314     my $target = shift;
 315     my $p;
 316     my $e;
 317
 318     if (defined($target)) {
 319         foreach $p (@getters, @grabbers) {
 320             if ($p->{'NAME'} eq $target) {
 321                 write_irssi($p->getconfstr());
 322                 return;
 323             }
 324         }
 325         write_irssi('No such module');
 326     } else {
 327         write_irssi('Loaded grabbers (* denotes enabled modules):');
 328         foreach $p (@grabbers) {
 329             $e = $p->_getval('enabled');
 330             write_irssi(' %s%s', $p->{'NAME'}, $e?'*':'');
 331         };
 332
 333         write_irssi('Loaded getters:');
 334         foreach $p (@getters) {
 335             write_irssi(' %s', $p->{'NAME'});
 336         };
 337     }
 338 }
 339
 340 sub cmd_help {
 341     my $target = shift;
 342     my $p;
 343
 344     if (defined($target)) {
 345         foreach $p (@getters, @grabbers) {
 346             if ($p->{'NAME'} eq $target) {
 347                 write_irssi($p->gethelpstr());
 348                 return;
 349             }
 350         }
 351         write_irssi('No such module');
 352     } else {
 353         write_irssi(<<'EOT');
 354 Supported commands:
 355  save: save the current configuration
 356  help [modulename]: display this help, or module specific help
 357  show [modulename]: show loaded modules, or the current parameters of a module
 358  set modulename parameter value: set a module parameter to a new value
 359  getter [modulename]: display or set the getter to use
 360  enable [modulename]: enable the usage of this module (grabbers only)
 361  disable [modulename]: disable the usage of this module (grabbers only)
 362  reload: reload all modules (this is somewhat experimental)
 363  mode [modename]: display or set the operation mode (download/display)
 364  debug: enable debugging messages
 365  nodebug: disable debugging messages
 366 EOT
 367     }
 368 }
 369
 370 sub cmd_getter {
 371     my $target = shift;
 372     my $p;
 373
 374     if (defined($target)) {
 375         foreach $p (@getters) {
 376             if ($p->{'NAME'} eq $target) {
 377                 $getter = $p;
 378                 $conf->{'videosite'}->{'getter'} = $target;
 379                 write_irssi("Getter changed to %s", $target);
 380                 return;
 381             }
 382         }
 383         write_irssi('No such getter');
 384     } else {
 385         write_irssi('Current getter: %s', $conf->{'videosite'}->{'getter'});
 386     }
 387 }
 388
 389 sub cmd_mode {
 390     my $mode = shift;
 391
 392     if (defined($mode)) {
 393         $mode = lc($mode);
 394         if (('download' eq $mode) or ('display' eq $mode)) {
 395             $conf->{'videosite'}->{'mode'} = $mode;
 396             write_irssi('Now using %s mode', $mode);
 397         } else {
 398             write_irssi('Invalid mode: %s', $mode);
 399         }
 400     } else {
 401         write_irssi('Current mode: %s', $conf->{'videosite'}->{'mode'});
 402     }
 403 }
 404
 405
 406 # save on unload
 407 sub sig_command_script_unload {
 408     my $script = shift;
 409     if ($script =~ /(.*\/)?videosite(\.pl)?$/) {
 410         cmd_save();
 411     }
 412 }
 413
 414 sub ploader {
 415
 416     my $dir = shift;
 417     my $pattern = shift;
 418     my $type = shift;
 419     my @list;
 420     my $p;
 421     my $g;
 422     my @g = ();
 423
 424     opendir(D, $dir) || return ();
 425     @list = grep {/$pattern/ && -f File::Spec->catfile($dir, $_) } readdir(D);
 426     closedir(D);
 427
 428     foreach $p (@list) {
 429         write_debug("Trying to load $p:");
 430         $p =~ s/\.pm$//;
 431         eval qq{ require videosite::$p; };
 432         if ($@) {
 433             write_irssi("Failed to load plugin: $@");
 434             next;
 435         }
 436
 437         $g = eval qq{ videosite::$p->new(); };
 438         if ($@) {
 439             write_irssi("Failed to instanciate: $@");
 440             delete($INC{$p});
 441             next;
 442         }
 443
 444         write_debug("found $g->{'TYPE'} $g->{'NAME'}");
 445         if ($type eq $g->{'TYPE'}) {
 446             push(@g, $g);
 447             $g->setio(\&write_irssi);
 448         } else {
 449             write_irssi('%s has wrong type (got %s, expected %s)', $p, $g->{'TYPE'}, $type);
 450             delete($INC{$p});
 451         }
 452     }
 453
 454     write_debug("Loaded %d plugins", $#g+1);
 455
 456     return @g;
 457 }
 458
 459 sub _load_modules($) {
 460
 461     my $path = shift;
 462
 463     foreach (keys(%INC)) {
 464         if ($INC{$_} =~ m|^$path|) {
 465             write_debug("Removing %s from \$INC", $_);
 466             delete($INC{$_});
 467         }
 468     }
 469     @grabbers = ploader($path, '.*Grabber\.pm$', 'grabber');
 470     @getters = ploader($path, '.*Getter\.pm$', 'getter');
 471 }
 472
 473
 474 sub init_videosite {
 475
 476     my $bindings = shift;
 477     my $p;
 478
 479     unless(-r $conffile && defined($conf = XML::Simple::XMLin($conffile, ForceArray => ['config', 'option'], KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'}))) {
 480         # No config, start with an empty one
 481         write_debug('No config found, using defaults');
 482         $conf = { 'videosite' => { }};
 483     }
 484     foreach (keys(%{$PARAMS})) {
 485         unless (exists($conf->{'videosite'}->{$_})) {
 486             $conf->{'videosite'}->{$_} = $PARAMS->{$_};
 487         }
 488     }
 489
 490     _load_modules($plugindir);
 491
 492     unless (defined(@grabbers) && defined(@getters)) {
 493         write_irssi('No grabbers or no getters found, can not proceed.');
 494         return;
 495     }
 496
 497     $getter = $getters[0];
 498     foreach $p (@getters) {
 499         if ($conf->{'videosite'}->{'getter'} eq $p->{'NAME'}) {
 500             $getter = $p;
 501         }
 502     }
 503     write_debug('Selected %s as getter', $getter->{'NAME'});
 504     $conf->{'videosite'}->{'getter'} = $getter->{'NAME'};
 505
 506     # Loop through all plugins and load the config
 507     foreach $p (@grabbers, @getters) {
 508         $conf->{'videosite'}->{'config'}->{$p->{'NAME'}} = $p->mergeconfig($conf->{'videosite'}->{'config'}->{$p->{'NAME'}});
 509     }
 510
 511     if ($bindings) {
 512
 513         Irssi::signal_add_first('command script load', 'sig_command_script_unload');
 514         Irssi::signal_add_first('command script unload', 'sig_command_script_unload');
 515         Irssi::signal_add('setup saved', 'cmd_save');
 516
 517
 518         Irssi::command_bind(_bcb('videosite' => \&cmdhandler));
 519     }
 520
 521     write_irssi('initialized successfully');
 522 }
 523
 524 sub sig_complete {
 525     my ($complist, $window, $word, $linestart, $want_space) = @_;
 526     my @matches;
 527
 528     if ($linestart !~ m|^/videosite\b|) {
 529         return;
 530     }
 531
 532     if ('/videosite' eq $linestart) {
 533         # No command enterd so far. Produce a list of possible follow-ups
 534         @matches = grep {/^$word/} keys (%{$videosite_commands});
 535     } elsif ('/videosite set' eq $linestart) {
 536         # 'set' command entered. Produce a list of modules
 537         foreach (@grabbers, @getters) {
 538             push(@matches, $_->{'NAME'}) if $_->{'NAME'} =~ m|^$word|;
 539         };
 540     } elsif ($linestart =~ m|^/videosite set (\w+)$|) {
 541         my $module = $1;
 542
 543         foreach my $p (@getters, @grabbers) {
 544             if ($p->{'NAME'} eq $module) {
 545                 @matches = $p->getparamlist($word);
 546                 last;
 547             }
 548         }
 549     } elsif ($linestart =~ m|/videosite set (\w+) (\w+)$|) {
 550         my $module = $1;
 551         my $param = $2;
 552
 553         foreach my $p (@getters, @grabbers) {
 554             if ($p->{'NAME'} eq $module) {
 555                 @matches = $p->getparamvalues($param, $word);
 556                 last;
 557             }
 558         }
 559     }
 560
 561
 562     push(@{$complist}, sort @matches);
 563     ${$want_space} = 0;
 564
 565     Irssi::signal_stop();
 566 }
 567
 568 sub cmdhandler {
 569     my $event = shift;
 570     my ($cmd, @params) = split(/\s+/, $event->message());
 571
 572     push_output($event->ewpf);
 573
 574     if (exists($videosite_commands->{$cmd})) {
 575         $videosite_commands->{$cmd}->(@params);
 576     }
 577
 578     pop_output();
 579 }
 580
 581 unshift(@INC, $scriptdir);
 582 init_videosite(1);