videosite.pl

   1 # autodownload flash videos
   2 #
   3 # (c) 2007-2008 by Ralf Ertzinger <ralf@camperquake.de>
   4 # licensed under GNU GPL v2
   5 #
   6 # Based on youtube.pl by Christian Garbs <mitch@cgarbs.de>
   7 # which in turn is
   8 # based on trigger.pl by Wouter Coekaerts <wouter@coekaerts.be>
   9
  10
  11 BEGIN {
  12     # Get rid of a (possibly old) version of BettIrssi
  13     # This is a hack to prevent having to reload irssi just
  14     # because BettIrssi.pm changed
  15
  16     delete($INC{'BettIrssi.pm'});
  17 }
  18
  19 use strict;
  20 use Irssi 20020324 qw (command_bind command_runsub signal_add_first signal_add_last);
  21 use vars qw($VERSION %IRSSI);
  22 use XML::Simple;
  23 use Data::Dumper;
  24 use File::Spec;
  25 use BettIrssi 101 qw(_bcb _bcs);
  26 use LWP::UserAgent;
  27
  28 my @grabbers;
  29 my @getters;
  30 my $getter;
  31 my $conf;
  32 my $conffile = File::Spec->catfile(Irssi::get_irssi_dir(), 'videosite.xml');
  33 my $scriptdir = File::Spec->catfile(Irssi::get_irssi_dir(), 'scripts');
  34 my $plugindir = File::Spec->catfile($scriptdir, 'videosite');
  35 my @outputstack = (undef);
  36
  37 my $PARAMS = {
  38     'getter' => '',
  39     'mode' => 'download'
  40 };
  41
  42
  43 # activate debug here
  44 my $debug = 0;
  45
  46 # "message public", SERVER_REC, char *msg, char *nick, char *address, char *target
  47 signal_add_last(_bcs("message public" => sub {check_for_link(@_)}));
  48 # "message own_public", SERVER_REC, char *msg, char *target
  49 signal_add_last(_bcs("message own_public" => sub {check_for_link(@_)}));
  50
  51 # "message private", SERVER_REC, char *msg, char *nick, char *address
  52 signal_add_last(_bcs("message private" => sub {check_for_link(@_)}));
  53 # "message own_private", SERVER_REC, char *msg, char *target, char *orig_target
  54 signal_add_last(_bcs("message own_private" => sub {check_for_link(@_)}));
  55
  56 # "message irc action", SERVER_REC, char *msg, char *nick, char *address, char *target
  57 signal_add_last(_bcs("message irc action" => sub {check_for_link(@_)}));
  58 # "message irc own_action", SERVER_REC, char *msg, char *target
  59 signal_add_last(_bcs("message irc own_action" => sub {check_for_link(@_)}));
  60
  61 # For tab completion
  62 # This does not use BettIrssi (yet)
  63 signal_add_first('complete word', \&sig_complete);
  64
  65 sub push_output {
  66     unshift(@outputstack, shift);
  67 }
  68
  69 sub pop_output {
  70     shift(@outputstack);
  71
  72     @outputstack = (undef) unless (@outputstack);
  73 }
  74
  75 my $videosite_commands = {
  76     'save' => sub {
  77         cmd_save();
  78     },
  79
  80     'set' => sub {
  81         cmd_set(@_);
  82     },
  83
  84     'show' => sub {
  85         cmd_show(@_);
  86     },
  87
  88     'help' => sub {
  89         cmd_help(@_);
  90     },
  91
  92     'getter' => sub {
  93         cmd_getter(@_);
  94     },
  95
  96     'enable' => sub {
  97         cmd_enable(@_);
  98     },
  99
 100     'disable' => sub {
 101         cmd_disable(@_);
 102     },
 103
 104     'reload' => sub {
 105         init_videosite(0);
 106     },
 107
 108     'mode' => sub {
 109         cmd_mode(@_);
 110     },
 111
 112     'debug' => sub {
 113         $debug = 1;
 114         foreach (@grabbers, @getters) {
 115             $_->setdebug(1);
 116         }
 117         write_irssi('Enabled debugging');
 118     },
 119
 120     'nodebug' => sub {
 121         $debug = 0;
 122         foreach (@grabbers, @getters) {
 123             $_->setdebug(0);
 124         }
 125         write_irssi('Disabled debugging');
 126     },
 127 };
 128
 129 sub write_irssi {
 130     my @text = @_;
 131     my $output = $outputstack[0];
 132
 133     my $format = "%%mvideosite: %%n" . shift(@text);
 134
 135     # escape % in parameters from irssi
 136     s/%/%%/g foreach @text;
 137
 138     if (defined $output) {
 139         $output->(sprintf($format, @text), MSGLEVEL_CLIENTCRAP);
 140     } else {
 141         Irssi::print(sprintf($format, @text));
 142     }
 143
 144 }
 145
 146 sub write_debug {
 147     if ($debug) {
 148         write_irssi(@_);
 149     }
 150 }
 151
 152 sub expand_url_shortener {
 153     my $s = shift;
 154     my $os = '';
 155     my @urlshortener = (
 156         'j\.mp/[[:alnum:]]+',
 157         'bit\.ly/[[:alnum:]]+',
 158         'tinyurl\.com/[[:alnum:]]+',
 159         );
 160     my $ua = LWP::UserAgent->new(agent => 'Mozilla', max_redirect => 0);
 161     my $i = 100;
 162
 163     OUTER: while (($os ne $s) and ($i > 0)) {
 164         $os = $s;
 165         $i--;
 166
 167         foreach my $pattern (@urlshortener) {
 168             my $p = "https?:\/\/" . $pattern;
 169
 170             write_debug("Matching %s against %s", $p, $s);
 171             if ($s =~ m|($p)|) {
 172                 my $matched = $1;
 173                 my $res;
 174
 175                 write_debug("Found %s", $matched);
 176                 $res = $ua->head($matched);
 177                 if ($res->is_redirect()) {
 178                     my $new = $res->headers()->header("Location");
 179
 180                     write_debug("Replacing %s with %s", $matched, $new);
 181                     $s =~ s/$matched/$new/;
 182                     next OUTER;
 183                 } else {
 184                     write_debug("Error resolving %s", $matched);
 185                 }
 186             }
 187         }
 188     }
 189
 190     if ($i == 0) {
 191         write_debug("Loop terminated by counter");
 192     }
 193
 194     write_debug("Final string: %s", $s);
 195
 196     return $s;
 197 }
 198
 199
 200 sub check_for_link {
 201     my $event = shift;
 202     my $message = $event->message();
 203     my $witem = $event->channel();
 204     my $g;
 205     my $m;
 206     my $p;
 207
 208
 209     # Look if we should ignore this line
 210     if ($message =~ m,(?:\s|^)/nosave(?:\s|$),) {
 211         return;
 212     }
 213
 214     push_output($event->ewpf);
 215     $message = expand_url_shortener($message);
 216
 217     study($message);
 218
 219     # Offer the message to all Grabbers in turn
 220     GRABBER: foreach $g (@grabbers) {
 221         ($m, $p) = $g->get($message);
 222         while (defined($m)) {
 223             write_debug('Metadata: %s', Dumper($m));
 224             if ('download' eq ($conf->{'videosite'}->{'mode'})) {
 225                 write_irssi('%%R>>> %%NSaving %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
 226                 unless($getter->get($m)) {
 227                     write_irssi('%%R>>> FAILED');
 228                 }
 229             } elsif ('display' eq ($conf->{'videosite'}->{'mode'})) {
 230                 write_irssi('%%M>>> %%NSaw %%Y%s%%N %%G%s', $m->{'SOURCE'}, $m->{'TITLE'});
 231             } else {
 232                 write_irssi('%%R>>> Invalid operation mode');
 233             }
 234
 235             # Remove the matched part from the message and try again (there may be
 236             # more!)
 237             $message =~ s/$p//;
 238             study($message);
 239             last GRABBER if ($message =~ /^\s*$/);
 240
 241             ($m, $p) = $g->get($message);
 242         }
 243     }
 244
 245     pop_output();
 246 }
 247
 248 sub cmd_save {
 249
 250     eval {
 251         open(CONF, '>'.$conffile) or die 'Could not open config file';
 252         print CONF XML::Simple::XMLout($conf, KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'});
 253         close(CONF);
 254     };
 255     if ($@) {
 256         write_irssi('Could not save config to %s: %s', ($conffile, $@));
 257     } else {
 258         write_irssi('configuration saved to %s', $conffile);
 259     }
 260 }
 261
 262 sub cmd_set {
 263     my $target = shift;
 264     my $key = shift;
 265     my $val = shift;
 266     my $p;
 267
 268     foreach $p (@getters, @grabbers) {
 269         if ($p->{'NAME'} eq $target) {
 270             $p->setval($key, $val);
 271             return;
 272         }
 273     }
 274     write_irssi('No such module');
 275 }
 276
 277
 278 sub cmd_enable {
 279     my $target = shift;
 280     my $p;
 281
 282     foreach $p (@grabbers) {
 283         if ($p->{'NAME'} eq $target) {
 284             $p->enable();
 285             return;
 286         }
 287     }
 288     write_irssi('No such module');
 289 }
 290
 291
 292 sub cmd_disable {
 293     my $target = shift;
 294     my $p;
 295
 296     foreach $p (@grabbers) {
 297         if ($p->{'NAME'} eq $target) {
 298             $p->disable();
 299             return;
 300         }
 301     }
 302     write_irssi('No such module');
 303 }
 304
 305
 306 sub cmd_show {
 307     my $target = shift;
 308     my $p;
 309     my $e;
 310
 311     if (defined($target)) {
 312         foreach $p (@getters, @grabbers) {
 313             if ($p->{'NAME'} eq $target) {
 314                 write_irssi($p->getconfstr());
 315                 return;
 316             }
 317         }
 318         write_irssi('No such module');
 319     } else {
 320         write_irssi('Loaded grabbers (* denotes enabled modules):');
 321         foreach $p (@grabbers) {
 322             $e = $p->_getval('enabled');
 323             write_irssi(' %s%s', $p->{'NAME'}, $e?'*':'');
 324         };
 325
 326         write_irssi('Loaded getters:');
 327         foreach $p (@getters) {
 328             write_irssi(' %s', $p->{'NAME'});
 329         };
 330     }
 331 }
 332
 333 sub cmd_help {
 334     my $target = shift;
 335     my $p;
 336
 337     if (defined($target)) {
 338         foreach $p (@getters, @grabbers) {
 339             if ($p->{'NAME'} eq $target) {
 340                 write_irssi($p->gethelpstr());
 341                 return;
 342             }
 343         }
 344         write_irssi('No such module');
 345     } else {
 346         write_irssi(<<'EOT');
 347 Supported commands:
 348  save: save the current configuration
 349  help [modulename]: display this help, or module specific help
 350  show [modulename]: show loaded modules, or the current parameters of a module
 351  set modulename parameter value: set a module parameter to a new value
 352  getter [modulename]: display or set the getter to use
 353  enable [modulename]: enable the usage of this module (grabbers only)
 354  disable [modulename]: disable the usage of this module (grabbers only)
 355  reload: reload all modules (this is somewhat experimental)
 356  mode [modename]: display or set the operation mode (download/display)
 357  debug: enable debugging messages
 358  nodebug: disable debugging messages
 359 EOT
 360     }
 361 }
 362
 363 sub cmd_getter {
 364     my $target = shift;
 365     my $p;
 366
 367     if (defined($target)) {
 368         foreach $p (@getters) {
 369             if ($p->{'NAME'} eq $target) {
 370                 $getter = $p;
 371                 $conf->{'videosite'}->{'getter'} = $target;
 372                 write_irssi("Getter changed to %s", $target);
 373                 return;
 374             }
 375         }
 376         write_irssi('No such getter');
 377     } else {
 378         write_irssi('Current getter: %s', $conf->{'videosite'}->{'getter'});
 379     }
 380 }
 381
 382 sub cmd_mode {
 383     my $mode = shift;
 384
 385     if (defined($mode)) {
 386         $mode = lc($mode);
 387         if (('download' eq $mode) or ('display' eq $mode)) {
 388             $conf->{'videosite'}->{'mode'} = $mode;
 389             write_irssi('Now using %s mode', $mode);
 390         } else {
 391             write_irssi('Invalid mode: %s', $mode);
 392         }
 393     } else {
 394         write_irssi('Current mode: %s', $conf->{'videosite'}->{'mode'});
 395     }
 396 }
 397
 398
 399 # save on unload
 400 sub sig_command_script_unload {
 401     my $script = shift;
 402     if ($script =~ /(.*\/)?videosite(\.pl)?$/) {
 403         cmd_save();
 404     }
 405 }
 406
 407 sub ploader {
 408
 409     my $dir = shift;
 410     my $pattern = shift;
 411     my $type = shift;
 412     my @list;
 413     my $p;
 414     my $g;
 415     my @g = ();
 416
 417     opendir(D, $dir) || return ();
 418     @list = grep {/$pattern/ && -f File::Spec->catfile($dir, $_) } readdir(D);
 419     closedir(D);
 420
 421     foreach $p (@list) {
 422         write_debug("Trying to load $p:");
 423         $p =~ s/\.pm$//;
 424         eval qq{ require videosite::$p; };
 425         if ($@) {
 426             write_irssi("Failed to load plugin: $@");
 427             next;
 428         }
 429
 430         $g = eval qq{ videosite::$p->new(); };
 431         if ($@) {
 432             write_irssi("Failed to instanciate: $@");
 433             delete($INC{$p});
 434             next;
 435         }
 436
 437         write_debug("found $g->{'TYPE'} $g->{'NAME'}");
 438         if ($type eq $g->{'TYPE'}) {
 439             push(@g, $g);
 440             $g->setio(\&write_irssi);
 441         } else {
 442             write_irssi('%s has wrong type (got %s, expected %s)', $p, $g->{'TYPE'}, $type);
 443             delete($INC{$p});
 444         }
 445     }
 446
 447     write_debug("Loaded %d plugins", $#g+1);
 448
 449     return @g;
 450 }
 451
 452 sub _load_modules($) {
 453
 454     my $path = shift;
 455
 456     foreach (keys(%INC)) {
 457         if ($INC{$_} =~ m|^$path|) {
 458             write_debug("Removing %s from \$INC", $_);
 459             delete($INC{$_});
 460         }
 461     }
 462     @grabbers = ploader($path, '.*Grabber\.pm$', 'grabber');
 463     @getters = ploader($path, '.*Getter\.pm$', 'getter');
 464 }
 465
 466
 467 sub init_videosite {
 468
 469     my $bindings = shift;
 470     my $p;
 471
 472     unless(-r $conffile && defined($conf = XML::Simple::XMLin($conffile, ForceArray => ['config', 'option'], KeepRoot => 1, KeyAttr => {'config' => 'module', 'option' => 'key'}))) {
 473         # No config, start with an empty one
 474         write_debug('No config found, using defaults');
 475         $conf = { 'videosite' => { }};
 476     }
 477     foreach (keys(%{$PARAMS})) {
 478         unless (exists($conf->{'videosite'}->{$_})) {
 479             $conf->{'videosite'}->{$_} = $PARAMS->{$_};
 480         }
 481     }
 482
 483     _load_modules($plugindir);
 484
 485     unless (defined(@grabbers) && defined(@getters)) {
 486         write_irssi('No grabbers or no getters found, can not proceed.');
 487         return;
 488     }
 489
 490     $getter = $getters[0];
 491     foreach $p (@getters) {
 492         if ($conf->{'videosite'}->{'getter'} eq $p->{'NAME'}) {
 493             $getter = $p;
 494         }
 495     }
 496     write_debug('Selected %s as getter', $getter->{'NAME'});
 497     $conf->{'videosite'}->{'getter'} = $getter->{'NAME'};
 498
 499     # Loop through all plugins and load the config
 500     foreach $p (@grabbers, @getters) {
 501         $conf->{'videosite'}->{'config'}->{$p->{'NAME'}} = $p->mergeconfig($conf->{'videosite'}->{'config'}->{$p->{'NAME'}});
 502     }
 503
 504     if ($bindings) {
 505
 506         Irssi::signal_add_first('command script load', 'sig_command_script_unload');
 507         Irssi::signal_add_first('command script unload', 'sig_command_script_unload');
 508         Irssi::signal_add('setup saved', 'cmd_save');
 509
 510
 511         Irssi::command_bind(_bcb('videosite' => \&cmdhandler));
 512     }
 513
 514     write_irssi('initialized successfully');
 515 }
 516
 517 sub sig_complete {
 518     my ($complist, $window, $word, $linestart, $want_space) = @_;
 519     my @matches;
 520
 521     if ($linestart !~ m|^/videosite\b|) {
 522         return;
 523     }
 524
 525     if ('/videosite' eq $linestart) {
 526         # No command enterd so far. Produce a list of possible follow-ups
 527         @matches = grep {/^$word/} keys (%{$videosite_commands});
 528     } elsif ('/videosite set' eq $linestart) {
 529         # 'set' command entered. Produce a list of modules
 530         foreach (@grabbers, @getters) {
 531             push(@matches, $_->{'NAME'}) if $_->{'NAME'} =~ m|^$word|;
 532         };
 533     } elsif ($linestart =~ m|^/videosite set (\w+)$|) {
 534         my $module = $1;
 535
 536         foreach my $p (@getters, @grabbers) {
 537             if ($p->{'NAME'} eq $module) {
 538                 @matches = $p->getparamlist($word);
 539                 last;
 540             }
 541         }
 542     } elsif ($linestart =~ m|/videosite set (\w+) (\w+)$|) {
 543         my $module = $1;
 544         my $param = $2;
 545
 546         foreach my $p (@getters, @grabbers) {
 547             if ($p->{'NAME'} eq $module) {
 548                 @matches = $p->getparamvalues($param, $word);
 549                 last;
 550             }
 551         }
 552     }
 553
 554
 555     push(@{$complist}, sort @matches);
 556     ${$want_space} = 0;
 557
 558     Irssi::signal_stop();
 559 }
 560
 561 sub cmdhandler {
 562     my $event = shift;
 563     my ($cmd, @params) = split(/\s+/, $event->message());
 564
 565     push_output($event->ewpf);
 566
 567     if (exists($videosite_commands->{$cmd})) {
 568         $videosite_commands->{$cmd}->(@params);
 569     }
 570
 571     pop_output();
 572 }
 573
 574 unshift(@INC, $scriptdir);
 575 init_videosite(1);